WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

ARCHProcess[κ,{α1,…,αq}]

標準ホワイトノイズに駆動される q 次ARCH（自己回帰条件付き分散不均一）過程を表す．

ARCHProcess[κ,{α1,…,αq},init]

初期データが init であるARCH過程を表す．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
基本的な用法  
過程スライス特性  
特性と関係  
関連項目
関連するガイド
履歴
引用書式

ARCHProcess

ARCHProcess[κ,{α1,…,αq}]

標準ホワイトノイズに駆動される q 次ARCH（自己回帰条件付き分散不均一）過程を表す．

ARCHProcess[κ,{α1,…,αq},init]

初期データが init であるARCH過程を表す．

詳細

  • ARCHProcessは，離散時間・連続状態のランダム過程である．
  • 条件付き平均Expectation[x[t] {x[t-1], …}]=0およびExpectation [x[t]2{x[t-1], …}]で与えられる条件付き分散 が方程式 を満足するのであれば，過程 x[t] はARCH過程である．
  • 初期データ init は，リスト{...,y(-2),y(-1)}として，あるいはタイムスタンプが{...,-2,-1}であると了解される単一路TemporalDataオブジェクトとして与えることができる．
  • スカラーARCH過程は非負の係数 αiおよび正の係数 κ を持つことができる．
  • ARCHProcess[q]は，EstimatedProcessおよび関連関数で使われる q 次ARCH過程を表す．
  • ARCHProcessは，RandomFunction，CovarianceFunction，TimeSeriesForecast等の関数で使うことができる．

例題

すべて開く すべて閉じる

例  (3)

ARCHProcessのシミュレーションを行う：

Wolfram Language code: RandomFunction[ARCHProcess[2, {.3}], {0, 10}]
Wolfram Language code: %["Path"]
Wolfram Language code: ListPlot[RandomFunction[ARCHProcess[2, {.3}], {0, 100}], Filling -> Axis]

弱定常過程の無条件平均値関数および無条件分散関数：

Wolfram Language code: Mean[ARCHProcess[κ, {Subscript[α, 1], Subscript[α, 2]}][t]]
Wolfram Language code: Variance[ARCHProcess[κ, {Subscript[α, 1], Subscript[α, 2]}][t]]

固定した初期値で：

Wolfram Language code: Mean[ARCHProcess[1, {1 / 3}, {Subscript[x, -1]}][t]]
Wolfram Language code: Variance[ARCHProcess[1, {1 / 3}, {Subscript[x, -1]}][t]]

観測は無相関であるが依存する：

Wolfram Language code: data = RandomFunction[ARCHProcess[1, {.3, .2}], {10 ^ 3}]; corr = CorrelationFunction[data, {20}];
Wolfram Language code: ListPlot[corr, Filling -> Axis, PlotRange -> All]

データの平方値には相関関係がある：

Wolfram Language code: corr2 = CorrelationFunction[data ^ 2, {20}];
Wolfram Language code: ListPlot[corr2, Filling -> Axis, PlotRange -> All]

スコープ  (13)

基本的な用法  (8)

経路の集合のシミュレーションを行う：

Wolfram Language code: data = RandomFunction[ARCHProcess[.3, {.5}], {0, 30}, 4]
Wolfram Language code: ListLinePlot[data, Filling -> Axis]

任意精度でシミュレーションを行う：

Wolfram Language code: RandomFunction[ARCHProcess[1 / 3, {1 / 10}], {5}, WorkingPrecision -> 20]["Path"]

指定された初期値で弱定常過程のシミュレーションを行う：

Wolfram Language code: sproc[x_] := ARCHProcess[.03, {.6, .3}, {x}];
Wolfram Language code: pts = {-1, 0, 2};
Wolfram Language code: samples = Table[SeedRandom[4];RandomFunction[sproc[x], {20}], {x, pts}];
Wolfram Language code: ListLinePlot[samples, DataRange -> {0, 12}, PlotLegends -> (StringJoin["x = ", ToString[#]]& /@ pts)]

非弱定常過程の場合：

Wolfram Language code: tproc[x_] := ARCHProcess[.03, {1.5, 1.2}, {x}];
Wolfram Language code: tsamples = Table[SeedRandom[4];RandomFunction[tproc[x], {20}], {x, pts}];
Wolfram Language code: ListLinePlot[tsamples, DataRange -> {0, 12}, PlotLegends -> (StringJoin["x = ", ToString[#]]& /@ pts)]

和分ARCHProcess：

Wolfram Language code: α = .3; proc = ARCHProcess[1, {α, 1 - α}, {}];
Wolfram Language code: ListPlot[RandomFunction[proc, {0, 100}], Filling -> Axis]

爆発ARCHProcess：

Wolfram Language code: proc = ARCHProcess[2, {.3, .7, .4}, {}];
Wolfram Language code: ListPlot[RandomFunction[proc, {0, 100}], Filling -> Axis]

そのような過程は二次定常ではない：

Wolfram Language code: WeakStationarity[proc]

ARCHProcessが共分散定常になるための条件：

Wolfram Language code: WeakStationarity[ARCHProcess[κ, {Subscript[α, 1], Subscript[α, 2], Subscript[α, 3]}]]

ARCHProcess[2]の二次定常性の範囲：

Wolfram Language code: cond = WeakStationarity[ARCHProcess[κ, {Subscript[α, 1], Subscript[α, 2]}]]
Wolfram Language code: RegionPlot[cond, {Subscript[α, 1], 0, 1}, {Subscript[α, 2], 0, 1}, FrameLabel -> Automatic]

ARCHProcessを推定する：

Wolfram Language code: SeedRandom["J23"]; data = RandomFunction[ARCHProcess[1.3, {.2, .3}], {10 ^ 4}];
Wolfram Language code: tsm = TimeSeriesModelFit[data, {"ARCH", 2}]
Wolfram Language code: tsm["Process"]

条件付き最尤推定を使う：

Wolfram Language code: EstimatedProcess[data, ARCHProcess[2], ProcessEstimator -> "MaximumConditionalLikelihood"]

予測する：

Wolfram Language code: proc = ARCHProcess[.3, {.5, .4}]; data = RandomFunction[proc, {10 ^ 2}];

20ステップ先の予測を求める：

Wolfram Language code: forecast = TimeSeriesForecast[proc, data, {20}];
Wolfram Language code: forecast["Path"]

予測の平均二乗誤差を求める：

Wolfram Language code: errors = forecast["MeanSquaredErrors"]

予測状態は0に等しい．したがって，予測される標準偏差境界は以下の通りである：

Wolfram Language code: ubound = TimeSeriesMap[Sqrt, errors]; lbound = TimeSeriesMap[-Sqrt[#]&, errors];

平均二乗誤差とともにこの値をプロットする：

Wolfram Language code: ListLinePlot[{data, forecast, lbound, ubound}, PlotStyle -> {Automatic, Automatic, Red, Red}, Filling -> {3 -> {4}}]

過程スライス特性  (5)

次数1の弱定常ARCHのモーメント：

Wolfram Language code: proc = ARCHProcess[k, {α}];
Wolfram Language code: Moment[proc[t], 4]
Wolfram Language code: Cumulant[proc[2], 4]

指定された初期条件によるARCH過程のモーメント：

Wolfram Language code: DiscretePlot[Moment[ARCHProcess[1, {.3, .4}, {}][t], 4], {t, 0, 8}]
Wolfram Language code: Moment[ARCHProcess[κ, {Subscript[α, 1], Subscript[α, 2]}, {x}][2], 4]

歪度：

Wolfram Language code: Skewness[ARCHProcess[κ, {α}][t]]
Wolfram Language code: Skewness[ARCHProcess[κ, {α}, {x}][t]]

尖度：

Wolfram Language code: Kurtosis[ARCHProcess[κ, {Subscript[α, 1], Subscript[α, 2]}][t]]

尖度が定義されている領域：

Wolfram Language code: RegionPlot[Subsuperscript[α, 1, 2] + Subsuperscript[α, 2, 2] < (1/3), {Subscript[α, 1], 0, 1}, {Subscript[α, 2], 0, 1}, FrameLabel -> Automatic]
Wolfram Language code: Kurtosis[ARCHProcess[κ, {α}, {x}][3]]

スライス分布のシミュレーションを行う：

Wolfram Language code: proc[α_] := ARCHProcess[.3, {α}]; sample[α_] := RandomVariate[proc[α][3], 10 ^ 4];

サンプルの確率密度関数：

Wolfram Language code: r = {.1, .3, .6, .8}; Histogram[sample[#], Automatic, "PDF", PlotLabel -> StringJoin["α = ", ToString[#]]]& /@ r

モンテカルロ法を使い，スライス分布についてのNProbabilityを計算する：

Wolfram Language code: proc = ARCHProcess[.3, {.4}];
Wolfram Language code: NProbability[x[1] > .3, xproc, Method -> {"MonteCarlo", "SamplingIncrement" -> 10 ^ 4}]

NExpectationを計算する：

Wolfram Language code: NExpectation[x[2] ^ 2, xproc, Method -> {"MonteCarlo", "SamplingIncrement" -> 10 ^ 4}]

二次Momentと比較する：

Wolfram Language code: Moment[proc[2], 2]

特性と関係  (3)

ARCHProcessの値は無相関である：

Wolfram Language code: Correlation[ARCHProcess[2, {.3, .2}][{1, 2, 3}]]//MatrixForm

対応するARProcess：

Wolfram Language code: ARProcess[ARCHProcess[2, {.3}]]

初期値が指定された過程について：

Wolfram Language code: ARProcess[ARCHProcess[2, {.3}, {3, 2}]]

ARCHProcessの値を平方したものはARProcessに従う：

Wolfram Language code: proc = ARCHProcess[1, {.2, .3}];
Wolfram Language code: data = RandomFunction[proc, {10 ^ 4}];

平方値のCorrelationFunctionおよびPartialCorrelationFunction：

Wolfram Language code: dataSQ = data ^ 2; ListPlot[#[dataSQ, {30}], Filling -> Axis, PlotRange -> {-.2, 1}, PlotLabel -> #]& /@ {CorrelationFunction, PartialCorrelationFunction}

対応する自己回帰過程：

Wolfram Language code: ar = ARProcess[proc]

自己回帰過程のCorrelationFunctionおよびPartialCorrelationFunction：

Wolfram Language code: ListPlot[#[ar, {30}], Filling -> Axis, PlotRange -> {-.2, 1}, PlotLabel -> #]& /@ {CorrelationFunction, PartialCorrelationFunction}
Wolfram Research (2014), ARCHProcess, Wolfram言語関数， https://reference.wolfram.com/language/ref/ARCHProcess.html.

テキスト

Wolfram Research (2014), ARCHProcess, Wolfram言語関数， https://reference.wolfram.com/language/ref/ARCHProcess.html.

CMS

Wolfram Language. 2014. "ARCHProcess." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/ARCHProcess.html.

APA

Wolfram Language. (2014). ARCHProcess. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/ARCHProcess.html

BibTeX

@misc{reference.wolfram_2026_archprocess, author="Wolfram Research", title="{ARCHProcess}", year="2014", howpublished="\url{https://reference.wolfram.com/language/ref/ARCHProcess.html}", note=[Accessed: 10-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_archprocess, organization={Wolfram Research}, title={ARCHProcess}, year={2014}, url={https://reference.wolfram.com/language/ref/ARCHProcess.html}, note=[Accessed: 10-August-2026]}