WOLFRAM

Wolfram 语言与系统参考资料中心

ARCHProcess[κ,{α1,…,αq}]

表示通过标准白噪声驱动的 q 阶自回归条件异方差过程.

ARCHProcess[κ,{α1,…,αq},init]

表示初始数据为 init 的 ARCH 过程.

更多信息
Details and Options Details and Options
范例  
基本范例  
范围  
基本用法  
过程切片性质  
属性和关系  
参见
相关指南
历史
按以下格式引用：

ARCHProcess

ARCHProcess[κ,{α1,…,αq}]

表示通过标准白噪声驱动的 q 阶自回归条件异方差过程.

ARCHProcess[κ,{α1,…,αq},init]

表示初始数据为 init 的 ARCH 过程.

更多信息

范例

打开所有单元 关闭所有单元

基本范例  (3)

模拟 ARCHProcess：

Wolfram Language code: RandomFunction[ARCHProcess[2, {.3}], {0, 10}]
Wolfram Language code: %["Path"]
Wolfram Language code: ListPlot[RandomFunction[ARCHProcess[2, {.3}], {0, 100}], Filling -> Axis]

弱平稳过程的无条件均值和方差：

Wolfram Language code: Mean[ARCHProcess[κ, {Subscript[α, 1], Subscript[α, 2]}][t]]
Wolfram Language code: Variance[ARCHProcess[κ, {Subscript[α, 1], Subscript[α, 2]}][t]]

在初始值固定时：

Wolfram Language code: Mean[ARCHProcess[1, {1 / 3}, {Subscript[x, -1]}][t]]
Wolfram Language code: Variance[ARCHProcess[1, {1 / 3}, {Subscript[x, -1]}][t]]

观测结果是不相关的，但相互依赖：

Wolfram Language code: data = RandomFunction[ARCHProcess[1, {.3, .2}], {10 ^ 3}]; corr = CorrelationFunction[data, {20}];
Wolfram Language code: ListPlot[corr, Filling -> Axis, PlotRange -> All]

数据的平方值是相关的：

Wolfram Language code: corr2 = CorrelationFunction[data ^ 2, {20}];
Wolfram Language code: ListPlot[corr2, Filling -> Axis, PlotRange -> All]

范围  (13)

基本用法  (8)

模拟一组路径：

Wolfram Language code: data = RandomFunction[ARCHProcess[.3, {.5}], {0, 30}, 4]
Wolfram Language code: ListLinePlot[data, Filling -> Axis]

使用任意精度模拟：

Wolfram Language code: RandomFunction[ARCHProcess[1 / 3, {1 / 10}], {5}, WorkingPrecision -> 20]["Path"]

模拟具有给定初始值的弱平稳过程：

Wolfram Language code: sproc[x_] := ARCHProcess[.03, {.6, .3}, {x}];
Wolfram Language code: pts = {-1, 0, 2};
Wolfram Language code: samples = Table[SeedRandom[4];RandomFunction[sproc[x], {20}], {x, pts}];
Wolfram Language code: ListLinePlot[samples, DataRange -> {0, 12}, PlotLegends -> (StringJoin["x = ", ToString[#]]& /@ pts)]

非弱平稳过程：

Wolfram Language code: tproc[x_] := ARCHProcess[.03, {1.5, 1.2}, {x}];
Wolfram Language code: tsamples = Table[SeedRandom[4];RandomFunction[tproc[x], {20}], {x, pts}];
Wolfram Language code: ListLinePlot[tsamples, DataRange -> {0, 12}, PlotLegends -> (StringJoin["x = ", ToString[#]]& /@ pts)]

一个集成的 ARCHProcess：

Wolfram Language code: α = .3; proc = ARCHProcess[1, {α, 1 - α}, {}];
Wolfram Language code: ListPlot[RandomFunction[proc, {0, 100}], Filling -> Axis]

一个发散的 ARCHProcess：

Wolfram Language code: proc = ARCHProcess[2, {.3, .7, .4}, {}];
Wolfram Language code: ListPlot[RandomFunction[proc, {0, 100}], Filling -> Axis]

这样的过程不是二阶平稳过程：

Wolfram Language code: WeakStationarity[proc]

ARCHProcess 成为协方差平稳过程的条件：

Wolfram Language code: WeakStationarity[ARCHProcess[κ, {Subscript[α, 1], Subscript[α, 2], Subscript[α, 3]}]]

ARCHProcess[2] 具有二阶平稳性的区域：:

Wolfram Language code: cond = WeakStationarity[ARCHProcess[κ, {Subscript[α, 1], Subscript[α, 2]}]]
Wolfram Language code: RegionPlot[cond, {Subscript[α, 1], 0, 1}, {Subscript[α, 2], 0, 1}, FrameLabel -> Automatic]

估计 ARCHProcess：

Wolfram Language code: SeedRandom["J23"]; data = RandomFunction[ARCHProcess[1.3, {.2, .3}], {10 ^ 4}];
Wolfram Language code: tsm = TimeSeriesModelFit[data, {"ARCH", 2}]
Wolfram Language code: tsm["Process"]

使用最大条件似然估计：

Wolfram Language code: EstimatedProcess[data, ARCHProcess[2], ProcessEstimator -> "MaximumConditionalLikelihood"]

预测：

Wolfram Language code: proc = ARCHProcess[.3, {.5, .4}]; data = RandomFunction[proc, {10 ^ 2}];

预测接下来的20步：

Wolfram Language code: forecast = TimeSeriesForecast[proc, data, {20}];
Wolfram Language code: forecast["Path"]

求预测的均方误差：

Wolfram Language code: errors = forecast["MeanSquaredErrors"]

所预测的状态都等于零，因此预测标准偏差范围如下：

Wolfram Language code: ubound = TimeSeriesMap[Sqrt, errors]; lbound = TimeSeriesMap[-Sqrt[#]&, errors];

绘制值与均方误差：

Wolfram Language code: ListLinePlot[{data, forecast, lbound, ubound}, PlotStyle -> {Automatic, Automatic, Red, Red}, Filling -> {3 -> {4}}]

过程切片性质  (5)

阶数为 1 的弱平稳 ARCH 的矩：

Wolfram Language code: proc = ARCHProcess[k, {α}];
Wolfram Language code: Moment[proc[t], 4]
Wolfram Language code: Cumulant[proc[2], 4]

初始条件已知的 ARCH 过程的矩：

Wolfram Language code: DiscretePlot[Moment[ARCHProcess[1, {.3, .4}, {}][t], 4], {t, 0, 8}]
Wolfram Language code: Moment[ARCHProcess[κ, {Subscript[α, 1], Subscript[α, 2]}, {x}][2], 4]

偏度：

Wolfram Language code: Skewness[ARCHProcess[κ, {α}][t]]
Wolfram Language code: Skewness[ARCHProcess[κ, {α}, {x}][t]]

峰度：

Wolfram Language code: Kurtosis[ARCHProcess[κ, {Subscript[α, 1], Subscript[α, 2]}][t]]

峰度具有定义的区域：

Wolfram Language code: RegionPlot[Subsuperscript[α, 1, 2] + Subsuperscript[α, 2, 2] < (1/3), {Subscript[α, 1], 0, 1}, {Subscript[α, 2], 0, 1}, FrameLabel -> Automatic]
Wolfram Language code: Kurtosis[ARCHProcess[κ, {α}, {x}][3]]

模拟切片分布：

Wolfram Language code: proc[α_] := ARCHProcess[.3, {α}]; sample[α_] := RandomVariate[proc[α][3], 10 ^ 4];

样本概率密度函数：

Wolfram Language code: r = {.1, .3, .6, .8}; Histogram[sample[#], Automatic, "PDF", PlotLabel -> StringJoin["α = ", ToString[#]]]& /@ r

用蒙特卡罗方法计算切片分布的 NProbability：

Wolfram Language code: proc = ARCHProcess[.3, {.4}];
Wolfram Language code: NProbability[x[1] > .3, xproc, Method -> {"MonteCarlo", "SamplingIncrement" -> 10 ^ 4}]

计算 NExpectation：

Wolfram Language code: NExpectation[x[2] ^ 2, xproc, Method -> {"MonteCarlo", "SamplingIncrement" -> 10 ^ 4}]

与二阶 Moment 比较：

Wolfram Language code: Moment[proc[2], 2]

属性和关系  (3)

ARCHProcess 的值是互不相关的：

Wolfram Language code: Correlation[ARCHProcess[2, {.3, .2}][{1, 2, 3}]]//MatrixForm

对应的 ARProcess：

Wolfram Language code: ARProcess[ARCHProcess[2, {.3}]]

对于初始值已知的过程：

Wolfram Language code: ARProcess[ARCHProcess[2, {.3}, {3, 2}]]

ARCHProcess 的平方值服从 ARProcess：

Wolfram Language code: proc = ARCHProcess[1, {.2, .3}];
Wolfram Language code: data = RandomFunction[proc, {10 ^ 4}];

平方值的 CorrelationFunction 和 PartialCorrelationFunction：

Wolfram Language code: dataSQ = data ^ 2; ListPlot[#[dataSQ, {30}], Filling -> Axis, PlotRange -> {-.2, 1}, PlotLabel -> #]& /@ {CorrelationFunction, PartialCorrelationFunction}

相应的自回归过程：

Wolfram Language code: ar = ARProcess[proc]

自回归过程的 CorrelationFunction 和 PartialCorrelationFunction：

Wolfram Language code: ListPlot[#[ar, {30}], Filling -> Axis, PlotRange -> {-.2, 1}, PlotLabel -> #]& /@ {CorrelationFunction, PartialCorrelationFunction}
Wolfram Research (2014)，ARCHProcess，Wolfram 语言函数，https://reference.wolfram.com/language/ref/ARCHProcess.html.

文本

Wolfram Research (2014)，ARCHProcess，Wolfram 语言函数，https://reference.wolfram.com/language/ref/ARCHProcess.html.

CMS

Wolfram 语言. 2014. "ARCHProcess." Wolfram 语言与系统参考资料中心. Wolfram Research. https://reference.wolfram.com/language/ref/ARCHProcess.html.

APA

Wolfram 语言. (2014). ARCHProcess. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/ARCHProcess.html 年

BibTeX

@misc{reference.wolfram_2026_archprocess, author="Wolfram Research", title="{ARCHProcess}", year="2014", howpublished="\url{https://reference.wolfram.com/language/ref/ARCHProcess.html}", note=[Accessed: 17-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_archprocess, organization={Wolfram Research}, title={ARCHProcess}, year={2014}, url={https://reference.wolfram.com/language/ref/ARCHProcess.html}, note=[Accessed: 17-August-2026]}