WOLFRAM

Wolfram 语言与系统参考资料中心

AcousticNormalVelocityValue[pred,vars,pars]

代表偏微分方程的时域或频域法向速度边界条件，其中谓词 pred 指示其适用位置，模型变量为 vars，且全局参数为 pars.

AcousticNormalVelocityValue[pred,vars,pars,lkey]

表示时域或频域边界条件，其中局部参数在 pars[lkey] 中指定.

更多信息
Details and Options Details and Options
范例  
基本范例  
范围  
参见
技术笔记
相关指南
历史
按以下格式引用：

AcousticNormalVelocityValue

AcousticNormalVelocityValue[pred,vars,pars]

代表偏微分方程的时域或频域法向速度边界条件，其中谓词 pred 指示其适用位置，模型变量为 vars，且全局参数为 pars.

AcousticNormalVelocityValue[pred,vars,pars,lkey]

表示时域或频域边界条件，其中局部参数在 pars[lkey] 中指定.

更多信息

范例

打开所有单元 关闭所有单元

基本范例  (2)

设置时域声学法向速度边界：

Wolfram Language code: AcousticNormalVelocityValue[x ≥ 0, {p[t, x, y], t, {x, y}}, <|"AcousticSoundParticleVelocity" -> v[t]|>]

设置频域声学法向速度边界：

Wolfram Language code: AcousticNormalVelocityValue[x ≥ 0, {p[x, y, z], ω, {x, y, z}}, <|"AcousticSoundParticleVelocity" -> v|>]

范围  (4)

定义瞬态声压场的模型变量 vars，模型参数 pars 和特定的边界条件参数；

Wolfram Language code: vars = {p[t, x, y], t, {x, y}}; pars = <|"SoundSpeed" -> 343, "MassDensity" -> 12 / 10, "BoundaryCondition1" -> <|"AcousticSoundParticleVelocity" -> v[t]|>|>; AcousticNormalVelocityValue[x == 1, vars, pars, "BoundaryCondition1"]

定义瞬态声压场的模型变量 vars，模型参数 pars 和多个特定参数边界条件：

Wolfram Language code: vars = {p[t, x, y], t, {x, y}}; pars = <|"SoundSpeed" -> 343, "MassDensity" -> 12 / 10, "BoundaryCondition1" -> <|"AcousticSoundParticleVelocity" -> v1[t]|>, "BoundaryCondition2" -> <|"AcousticSoundParticleVelocity" -> v2[t]|>|>;
Wolfram Language code: AcousticNormalVelocityValue[x == 0, vars, pars, "BoundaryCondition1"]
Wolfram Language code: AcousticNormalVelocityValue[x == 1, vars, pars, "BoundaryCondition2"]

定义瞬态声压场的模型变量 vars 和模型参数 pars ：

Wolfram Language code: vars = {p[t, x], t, {x}}; pars = <|"SoundSpeed" -> 343, "MassDensity" -> 1.2|>;

定义无声初始条件 ics：

Wolfram Language code: ics = {p[0, x] == 0, Derivative[1, 0][p][0, x] == 0};

建立一个方程，左端为声法线速度边界，声粒子速度 v 为 ：

Wolfram Language code: eqn = AcousticPDEComponent[vars, pars] == AcousticNormalVelocityValue[x == 0, vars, pars, <|"AcousticSoundParticleVelocity" -> Sin[800π t]|>];

在细化网格上求解偏微分方程：

Wolfram Language code: pfun = NDSolveValue[{eqn, ics}, p, {t, 0, 0.0025}, x∈Line[{{0}, {1}}], Method -> {"PDEDiscretization" -> {"MethodOfLines", "SpatialDiscretization" -> {"FiniteElement", "MeshOptions" -> {"MaxCellMeasure" -> 0.01}}}}];

解的可视化：

Wolfram Language code: Manipulate[Plot[pfun[t, x], {x, 0, 1}, ...], {{t, 0.0012}, 0, 0.0025, 10 ^ -4}, Rule[...]]

定义频域声压场的模型变量 vars 和模型参数 pars：

Wolfram Language code: vars = {p[x], ω, {x}}; pars = <|"SoundSpeed" -> 343, "MassDensity" -> 1.2|>;

建立方程式，声学法向速度边界在左端，声粒子速度 为 ，吸声边界在右端：

Wolfram Language code: eqn = AcousticPDEComponent[vars, pars] == AcousticNormalVelocityValue[x == 0, vars, pars, <|"AcousticSoundParticleVelocity" -> 0.01|>] + AcousticAbsorbingValue[x == 1, vars, pars];

求解偏微分方程：

Wolfram Language code: pfun = ParametricNDSolveValue[eqn, p, x∈Line[{{0}, {1}}], {ω}];

在不同频率 的频域中可视化解：

Wolfram Language code: Plot[Table[Legended[Abs[pfun[ω][x]], ω], {ω, {1000π, 1500π, 2000π}}]//Evaluate, {x, 0, 1}, ...]

将解转换到时域：

Wolfram Language code: Plot[Table[Legended[Re[pfun[ω][x] * Exp[I ω t]], ω], {t, {0.01}}, {ω, {1000π, 1500π, 2000π}}]//Evaluate, {x, 0, 1}, ...]
Wolfram Research (2020)，AcousticNormalVelocityValue，Wolfram 语言函数，https://reference.wolfram.com/language/ref/AcousticNormalVelocityValue.html.

文本

Wolfram Research (2020)，AcousticNormalVelocityValue，Wolfram 语言函数，https://reference.wolfram.com/language/ref/AcousticNormalVelocityValue.html.

CMS

Wolfram 语言. 2020. "AcousticNormalVelocityValue." Wolfram 语言与系统参考资料中心. Wolfram Research. https://reference.wolfram.com/language/ref/AcousticNormalVelocityValue.html.

APA

Wolfram 语言. (2020). AcousticNormalVelocityValue. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/AcousticNormalVelocityValue.html 年

BibTeX

@misc{reference.wolfram_2026_acousticnormalvelocityvalue, author="Wolfram Research", title="{AcousticNormalVelocityValue}", year="2020", howpublished="\url{https://reference.wolfram.com/language/ref/AcousticNormalVelocityValue.html}", note=[Accessed: 15-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_acousticnormalvelocityvalue, organization={Wolfram Research}, title={AcousticNormalVelocityValue}, year={2020}, url={https://reference.wolfram.com/language/ref/AcousticNormalVelocityValue.html}, note=[Accessed: 15-August-2026]}