WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

AcousticPressureCondition[pred,vars,pars]

偏微分方程式についての時間領域あるいは周波数領域の圧力境界条件を，適用場所を示す述語 pred，モデル変数 vars，大域パラメータ pars で表す．

AcousticPressureCondition[pred,vars,pars,lkey]

時間領域あるいは周波数領域の境界条件を，pars[lkey]で指定される局所パラメータで表す．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
関連項目
テクニカルノート
関連するガイド
履歴
引用書式

AcousticPressureCondition

AcousticPressureCondition[pred,vars,pars]

偏微分方程式についての時間領域あるいは周波数領域の圧力境界条件を，適用場所を示す述語 pred，モデル変数 vars，大域パラメータ pars で表す．

AcousticPressureCondition[pred,vars,pars,lkey]

時間領域あるいは周波数領域の境界条件を，pars[lkey]で指定される局所パラメータで表す．

詳細

例題

すべて開く すべて閉じる

例  (4)

時間領域音圧境界を設定する：

Wolfram Language code: AcousticPressureCondition[x ≥ 0, {p[t, x, y], t, {x, y}}, <|"AcousticPressure" -> Sin[t]|>]

周波数領域音圧境界を設定する：

Wolfram Language code: AcousticPressureCondition[x ≥ 0, {p[x, y], ω, {x, y}}, <|"AcousticPressure" -> 1|>]

過渡音圧場のためのモデル変数 vars をモデルパラメータ pars で定義する：

Wolfram Language code: vars = {p[t, x], t, {x}}; pars = <|"SoundSpeed" -> 343, "MassDensity" -> 1.2|>;

無音の初期条件 ics を定義する：

Wolfram Language code: ics = {p[0, x] == 0, Derivative[1, 0][p][0, x] == 0};

左端の場の端の音圧境界と の圧力源 で方程式を設定する：

Wolfram Language code: eqn = {AcousticPDEComponent[vars, pars] == 0, AcousticPressureCondition[x == 0, vars, pars, <|"AcousticPressure" -> Sin[800π t]|>]};

細分化メッシュ上で偏微分方程式を解く：

Wolfram Language code: pfun = NDSolveValue[{eqn, ics}, p, {t, 0, 0.0025}, x∈Line[{{0}, {1}}], Method -> {"PDEDiscretization" -> {"MethodOfLines", "SpatialDiscretization" -> {"FiniteElement", "MeshOptions" -> {"MaxCellMeasure" -> 0.015}}}}];

解を可視化する：

Wolfram Language code: Manipulate[Plot[pfun[t, x], {x, 0, 1}, ...], {{t, 0.001}, 0, 0.0025, 10 ^ -4}, Rule[...]]

周波数領域の音圧場のためのモデル変数 vars をモデルパラメータ pars で定義する：

Wolfram Language code: vars = {p[x], ω, {x}}; pars = <|"SoundSpeed" -> 343, "MassDensity" -> 1.2|>;

左の音圧境界， の圧力源 ，右の音響吸収境界で方程式を設定する：

Wolfram Language code: eqn = AcousticPDEComponent[vars, pars] == AcousticPressureCondition[x == 0, vars, pars, <|"AcousticPressure" -> 1|>] + AcousticAbsorbingValue[x == 1, vars, pars];

偏微分方程式を解く：

Wolfram Language code: pfun = ParametricNDSolveValue[eqn, p, x∈Line[{{0}, {1}}], {ω}];

周波数領域のさまざまな周波数 f で解を可視化する：

Wolfram Language code: Manipulate[Plot[Abs[pfun[ω][x]], {x, 0, 1}, ...], {{ω, 1000π, "f"}, {1000π, 1500π, 2000π}}, Rule[...]]

解を時間領域に変換する：

Wolfram Language code: Manipulate[Plot[Re[pfun[ω][x] * Exp[I ω t]], {x, 0, 1}, ...], {{t, 0, "t"}, 0, 0.01}, {{ω, 1000π, "f"}, {1000π, 1500π, 2000π}}, Rule[...]]

スコープ  (2)

過渡音圧場のためのモデル変数 vars をモデルパラメータ pars と特定の境界条件パラメータで定義する：

Wolfram Language code: vars = {p[t, x, y], t, {x, y}}; pars = <|"SoundSpeed" -> 343, "MassDensity" -> 12 / 10, "BoundaryCondition1" -> <|"AcousticPressure" -> p1|>|>; AcousticPressureCondition[x == 1, vars, pars, "BoundaryCondition1"]

過渡音圧場のためのモデル変数 vars をモデルパラメータ pars と複数の特定の境界条件パラメータで定義する：

Wolfram Language code: vars = {p[t, x, y], t, {x, y}}; pars = <|"SoundSpeed" -> 343, "MassDensity" -> 12 / 10, "BoundaryCondition1" -> <|"AcousticPressure" -> p1|>, "BoundaryCondition2" -> <|"AcousticPressure" -> p2|>|>;
Wolfram Language code: AcousticPressureCondition[x == 0, vars, pars, "BoundaryCondition1"]
Wolfram Language code: AcousticPressureCondition[x == 1, vars, pars, "BoundaryCondition2"]
Wolfram Research (2020), AcousticPressureCondition, Wolfram言語関数， https://reference.wolfram.com/language/ref/AcousticPressureCondition.html.

テキスト

Wolfram Research (2020), AcousticPressureCondition, Wolfram言語関数， https://reference.wolfram.com/language/ref/AcousticPressureCondition.html.

CMS

Wolfram Language. 2020. "AcousticPressureCondition." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/AcousticPressureCondition.html.

APA

Wolfram Language. (2020). AcousticPressureCondition. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/AcousticPressureCondition.html

BibTeX

@misc{reference.wolfram_2026_acousticpressurecondition, author="Wolfram Research", title="{AcousticPressureCondition}", year="2020", howpublished="\url{https://reference.wolfram.com/language/ref/AcousticPressureCondition.html}", note=[Accessed: 09-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_acousticpressurecondition, organization={Wolfram Research}, title={AcousticPressureCondition}, year={2020}, url={https://reference.wolfram.com/language/ref/AcousticPressureCondition.html}, note=[Accessed: 09-September-2026]}