WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

AlgebraicIntegerQ[a]

a が代数的整数であればTrueを，それ以外の場合はFalseを返す．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
アプリケーション  
基本的なアプリケーション  
特殊数列  
整数論  
特性と関係  
考えられる問題  
関連項目
テクニカルノート
関連するガイド
履歴
引用書式

AlgebraicIntegerQ

AlgebraicIntegerQ[a]

a が代数的整数であればTrueを，それ以外の場合はFalseを返す．

詳細

  • AlgebraicIntegerQは，ある数が代数的整数かどうかを調べるために使われる．
  • 代数的整数は，整数係数を持ち主係数が1の多項式の根である数である．
  • AlgebraicIntegerQ[a]は，a が明らかに代数的整数でなければFalseを返す．

例題

すべて開く すべて閉じる

例  (2)

ある数が代数的整数かどうかをテストする：

Wolfram Language code: AlgebraicIntegerQ[Sqrt[2]]

数 は代数的整数ではない：

Wolfram Language code: AlgebraicIntegerQ[Pi]

スコープ  (4)

AlgebraicIntegerQは整数に使うことができる：

Wolfram Language code: AlgebraicIntegerQ[5]

実数に使う：

Wolfram Language code: AlgebraicIntegerQ[1.2]

複素数に使う：

Wolfram Language code: AlgebraicIntegerQ[(1 + I) / Sqrt[2]]

超越数に使う：

Wolfram Language code: AlgebraicIntegerQ[Pi]

無理式に使う：

Wolfram Language code: AlgebraicIntegerQ[2 ^ (1 / 3) + 4 ^ (1 / 5) + 17]

Rootオブジェクトに使う：

Wolfram Language code: AlgebraicIntegerQ[Root[2#1 ^ 2 - 2 #1 + 7&, 1]]

AlgebraicNumberオブジェクトに使う：

Wolfram Language code: AlgebraicIntegerQ[AlgebraicNumber[Sqrt[2], {2, 1}]]

AlgebraicIntegerQはリストに縫い込まれる：

Wolfram Language code: AlgebraicIntegerQ[{E, Sqrt[-2], 1 / Sqrt[2]}]

アプリケーション  (10)

基本的なアプリケーション  (2)

ランダムな代数的整数を生成する：

Wolfram Language code: randomAlgebraicInteger[n_, m_ : 1] := Table[Root[Dot[RandomInteger[20, n], # ^ Range[0, n - 1]] + # ^ n, RandomInteger[{1, n}]], {m}];
Wolfram Language code: randomAlgebraicInteger[8, 10]
Wolfram Language code: AlgebraicIntegerQ[%]

代数的整数をプロットする：

Wolfram Language code: ComplexListPlot[randomAlgebraicInteger[20, 1000]]

最高で 次の代数的整数体を複素平面上でプロットする：

Wolfram Language code: data = Flatten[Table[Root[# ^ 3 + a * # ^ 2 + b * # + c, m], {a, -10, 10}, {b, -10, 10}, {c, -10, 10}, {m, 3}]];
Wolfram Language code: ComplexListPlot[data, PlotRange -> {{-3, 3}, {-3, 3}}, AspectRatio -> 1]

特殊数列  (3)

ガウス整数は （a と b は整数）の形式の複素数である：

Wolfram Language code: g = Flatten[Table[a + b I, {a, -40, 40}, {b, -40, 40}]];

ガウス整数は代数的整数である：

Wolfram Language code: AllTrue[g, AlgebraicIntegerQ]

ガウス素数をプロットする：

Wolfram Language code: p = Select[g, PrimeQ[#, GaussianIntegers -> True]&];
Wolfram Language code: ComplexListPlot[p, PlotRange -> All, PlotMarkers -> {{●, 1}}, Axes -> False, AspectRatio -> 1]

アイゼンシュタイン(Eisenstein)整数は （a と b は整数で ω は1の立方根 ）の形式の複素数である：

Wolfram Language code: ω = Exp[2π I / 3];
Wolfram Language code: e = Select[Flatten[Table[a + b ω, {a, -30, 30}, {b, -30, 30}], 1], Abs[#] < 20&];

アイゼンシュタイン整数は代数的整数である：

Wolfram Language code: AllTrue[e, AlgebraicIntegerQ]

アイゼンシュタイン整数が素数かどうかをチェックする：

Wolfram Language code: primeQ[a_] := Or[PrimeQ[AlgebraicNumberNorm[a]], (PrimeQ[Abs[a]] && Mod[Abs[a], 3] == 2)]
Wolfram Language code: primeQ[ω]
Wolfram Language code: primeQ[5]

アイゼンシュタイン素数をプロットする：

Wolfram Language code: primes = Select[e, primeQ];
Wolfram Language code: ComplexListPlot[primes, PlotRange -> All, PlotMarkers -> Automatic, Axes -> False, AspectRatio -> 1]

Pisot数は1より大きい正の代数的整数で，そのすべての共役元の絶対値は1より小さい [詳細]：

Wolfram Language code: pisotNumberQ[a_] := AlgebraicIntegerQ[a] && Element[a, Reals] && (a > 1) && (Count[List @@ (Last /@ Roots[MinimalPolynomial[a, x] == 0, x]), _ ? (Abs[#] > 1 &)] == 1)
Wolfram Language code: pisotNumberQ[GoldenRatio]
Wolfram Language code: pisotNumberQ[Root[-1 - #1 + #1 ^ 3 &, 1]]

整数論  (5)

すべての有理数 q について が代数的整数になる非零の整数 n が存在する：

Wolfram Language code: AlgebraicNumberDenominator[1 / 6]
Wolfram Language code: AlgebraicIntegerQ[6 * (1 / 6)]

1のベキ根はすべて代数的整数である：

Wolfram Language code: Exp[(2Pi Range[0, 6]I) / 6]
Wolfram Language code: AlgebraicIntegerQ[%]

二次体の整数は次数2の代数的整数である：

Wolfram Language code: x /. Solve[x^2 + 2x + 3 == 0, x]
Wolfram Language code: AlgebraicIntegerQ[%]

代数的整数であり代数的単数でもある唯一の整数はとである：

Wolfram Language code: x /. Solve[x * y == 1, {x, y}, Integers]
Wolfram Language code: {AlgebraicIntegerQ[1], AlgebraicIntegerQ[-1]}
Wolfram Language code: {AlgebraicUnitQ[1], AlgebraicUnitQ[-1]}

1のベキ根を使ってCyclotomic多項式を求める：

Wolfram Language code: roots = Exp[2 Pi I / Range[5]]
Wolfram Language code: MinimalPolynomial[roots, x]
Wolfram Language code: Cyclotomic[Range[5], x]

特性と関係  (8)

2つの代数的整数の和と積は代数的整数である：

Wolfram Language code: {a, b} = {Sqrt[7], Exp[I Pi / 2]};
Wolfram Language code: {AlgebraicIntegerQ[a + b], AlgebraicIntegerQ[a * b]}

代数的整数の有理数乗は代数的整数である：

Wolfram Language code: AlgebraicIntegerQ[Sqrt[2] ^ (4 / 3)]

Algebraicsは代数的整数を含むすべての代数的数の領域を表す：

Wolfram Language code: Element[Sqrt[2] ^ 5 + 3 ^ (4 / 7), Algebraics]

代数的単数はその数とその逆数の両方が代数的整数である数である：

Wolfram Language code: a = 1 - 6 6 ^ (1 / 3) + 3 36 ^ (1 / 3);
Wolfram Language code: AlgebraicIntegerQ [{a, 1 / a}]
Wolfram Language code: AlgebraicUnitQ [a]

整数係数を持つモニック多項式の根は代数的整数である：

Wolfram Language code: AlgebraicIntegerQ[Root[# ^ 2 - 3 # - 1&, 1]]
Wolfram Language code: AlgebraicIntegerQ[Root[# ^ 2 - 3 # - 1&, 2]]

MinimalPolynomialを使って代数的整数の最小多項式を求める：

Wolfram Language code: MinimalPolynomial[Sqrt[2], x]

その根はすべて代数的整数である：

Wolfram Language code: x /. Solve[% == 0, x]
Wolfram Language code: AlgebraicIntegerQ /@ %

NumberFieldIntegralBasisを使って数体の整基底を得る：

Wolfram Language code: a = NumberFieldIntegralBasis[3 ^ (1 / 3)]

任意の整数の線形結合は代数的整数である：

Wolfram Language code: AlgebraicIntegerQ[a.{1, 2, 3}]

数体の基本単数は代数的整数である：

Wolfram Language code: a = Root[-2 + 5# ^ 4&, 1]; units = NumberFieldFundamentalUnits[a];
Wolfram Language code: AlgebraicIntegerQ[units]

考えられる問題  (1)

場合によっては，ある数が代数的整数かどうか分からないこともある：

Wolfram Language code: AlgebraicIntegerQ[E + Pi]
Wolfram Research (2007), AlgebraicIntegerQ, Wolfram言語関数， https://reference.wolfram.com/language/ref/AlgebraicIntegerQ.html.

テキスト

Wolfram Research (2007), AlgebraicIntegerQ, Wolfram言語関数， https://reference.wolfram.com/language/ref/AlgebraicIntegerQ.html.

CMS

Wolfram Language. 2007. "AlgebraicIntegerQ." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/AlgebraicIntegerQ.html.

APA

Wolfram Language. (2007). AlgebraicIntegerQ. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/AlgebraicIntegerQ.html

BibTeX

@misc{reference.wolfram_2026_algebraicintegerq, author="Wolfram Research", title="{AlgebraicIntegerQ}", year="2007", howpublished="\url{https://reference.wolfram.com/language/ref/AlgebraicIntegerQ.html}", note=[Accessed: 18-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_algebraicintegerq, organization={Wolfram Research}, title={AlgebraicIntegerQ}, year={2007}, url={https://reference.wolfram.com/language/ref/AlgebraicIntegerQ.html}, note=[Accessed: 18-August-2026]}