WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

AlphabeticSort[list]

list の要素をアルファベット順に並べる．

AlphabeticSort[list,lang]

言語 lang に適した並べ順を使ってソートする．

詳細とオプション
Details and Options Details and Options
例題  
例  
スコープ  
オプション  
CaseOrdering  
IgnoreCase  
IgnoreDiacritics  
IgnorePunctuation  
特性と関係  
考えられる問題  
おもしろい例題  
関連項目
関連するガイド
履歴
引用書式

AlphabeticSort

AlphabeticSort[list]

list の要素をアルファベット順に並べる．

AlphabeticSort[list,lang]

言語 lang に適した並べ順を使ってソートする．

詳細とオプション

  • 言語は，LanguageDataで使われるような言語の標準名，あるいは言語実体で指定することができる．Alphabetで使われるようなアファベット（字母）指定も使うことができる．
  • デフォルトの言語は$Languageである．
  • 使用可能なオプション
  • CaseOrdering Automatic大文字小文字のソート方法
    IgnoreCase Falseソートの際に大文字小文字の違いを無視するかどうか
    IgnoreDiacritics Falseソートの際に付加記号を無視するかどうか
    IgnorePunctuation Falseソートの際に句読記号を無視するかどうか
    Language$Language仮定する言語あるいはアルファベット（字母）
  • AlphabeticSort[…,lang]で言語が明示的に指定された場合は，その言語がLanguage オプションの設定に優先する．

例題

すべて開く すべて閉じる

例  (2)

デフォルトの$Languageで単語をソートする：

Wolfram Language code: words = RandomChoice[WordList[], 20]
Wolfram Language code: AlphabeticSort[words]

特定の言語についての順序規則を使う：

Wolfram Language code: words = RandomChoice[WordList["Language" -> ["swedish"]], 20]
Wolfram Language code: AlphabeticSort[words, "Swedish"]

スコープ  (1)

言語を引数として指定する：

Wolfram Language code: AlphabeticSort[{"Encyclopædia", "Encyclopedia", "Encyclopaedia"}, "Swedish"]

言語をオプションとして指定する：

Wolfram Language code: AlphabeticSort[{"アメリカ合衆国", "日本", "イギリス", "ペルー", "スウェーデン"}, Language -> Entity["Language", "Japanese"]]

オプション  (5)

CaseOrdering  (2)

CaseOrdering->"LowerFirst"は，ほとんどの言語におけるデフォルト値である：

Wolfram Language code: AlphabeticSort[{"A", "a", "æ", "Æ", "i", "I"}, "English", CaseOrdering -> "LowerFirst"]
Wolfram Language code: % === AlphabeticSort[{"A", "a", "æ", "Æ", "i", "I"}, "English"]

CaseOrdering->"UpperFirst"がデフォルト値の言語もある：

Wolfram Language code: AlphabeticSort[{"A", "a", "æ", "Æ", "i", "I"}, "Danish", CaseOrdering -> "UpperFirst"]
Wolfram Language code: % === AlphabeticSort[{"A", "a", "æ", "Æ", "i", "I"}, "Danish"]

IgnoreCase  (1)

IgnoreCase->Trueは大文字小文字を等しいものとして扱う：

Wolfram Language code: AlphabeticSort[{"Ñ", "ij", "ñ", "Ş", "IJ", "ş"}, "Dutch", IgnoreCase -> True]

IgnoreDiacritics  (1)

IgnoreDiacritics->Trueは指定された言語の付加記号を無視する：

Wolfram Language code: AlphabeticSort[{"sonar", "cañón", "soñar", "cuña", "canon", "papá", "cuna", "papa"}, "Spanish", IgnoreDiacritics -> True]

異なる言語における等しい単語は付加記号を無視すると順序が変わることがある：

Wolfram Language code: AlphabeticSort[{"sonar", "cañón", "soñar", "cuña", "canon", "papá", "cuna", "papa"}, "English", IgnoreDiacritics -> True]

IgnorePunctuation  (1)

IgnorePunctuation->Trueはすべての句読記号と空白文字を除いた後でソートする：

Wolfram Language code: AlphabeticSort[{"File-2", "File 1", "File4", "File 3"}, IgnorePunctuation -> True]

IgnorePunctuationのデフォルト値はFalseである：

Wolfram Language code: AlphabeticSort[{"File-2", "File 1", "File4", "File 3"}, IgnorePunctuation -> False]

特性と関係  (1)

AlphabeticSortは，SortとAlphabeticOrderを順序関数として使うことに等しい：

Wolfram Language code: stopWords = WordList["Stopwords", Language -> "English"];
Wolfram Language code: AlphabeticSort[stopWords, CaseOrdering -> "UpperFirst"] === Sort[stopWords, AlphabeticOrder[CaseOrdering -> "UpperFirst"][##] ≥ 0&]

考えられる問題  (2)

"Turkish"言語では，"i"の大文字小文字の等価性は他の言語におけるそれと異なる：

Wolfram Language code: AlphabeticSort[{"A", "a", "i", "I", "ı", "İ"}, "Turkish", CaseOrdering -> "UpperFirst"]

IgnoreCaseオプションは，CaseOrderingが持つ任意の値を無効にする：

Wolfram Language code: AlphabeticSort[{"A", "a", "i", "I", "ı", "İ"}, "Turkish", CaseOrdering -> "UpperFirst", IgnoreCase -> True]

おもしろい例題  (1)

AlphabeticSortを使って2000個のランダムな単語のソートしたリストを得る：

Wolfram Language code: russianWords = AlphabeticSort[RandomSample[WordList[Language -> "Russian"], 2000], "Russian"];

ソートされた単語の木を作る：

Wolfram Language code: buildOpenerViewerLevelN[words_, n_] := Column[If[Length[#] === 1, #[[1]], Replace[OpenerView[{Row[{Style[StringTake[#[[1]], n], Gray], " (", Length[#], ")"}], buildOpenerViewerLevelN[#, n + 1]}], OpenerView[{_, Column[{x_}]}] :> x]]& /@ SplitBy[words, StringTake[#, UpTo[n]]&]]
Wolfram Language code: buildOpenerViewerLevelN[russianWords, 1]
Wolfram Research (2015), AlphabeticSort, Wolfram言語関数， https://reference.wolfram.com/language/ref/AlphabeticSort.html.

テキスト

Wolfram Research (2015), AlphabeticSort, Wolfram言語関数， https://reference.wolfram.com/language/ref/AlphabeticSort.html.

CMS

Wolfram Language. 2015. "AlphabeticSort." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/AlphabeticSort.html.

APA

Wolfram Language. (2015). AlphabeticSort. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/AlphabeticSort.html

BibTeX

@misc{reference.wolfram_2026_alphabeticsort, author="Wolfram Research", title="{AlphabeticSort}", year="2015", howpublished="\url{https://reference.wolfram.com/language/ref/AlphabeticSort.html}", note=[Accessed: 18-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_alphabeticsort, organization={Wolfram Research}, title={AlphabeticSort}, year={2015}, url={https://reference.wolfram.com/language/ref/AlphabeticSort.html}, note=[Accessed: 18-August-2026]}