WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

AnatomyForm[g]

AnatomyPlot3Dで使われるグラフィックス指示子で，解剖学的実体に基づいたグラフィックスオブジェクトをグラフィックス指示子または指示子 g の連想を使ってどのように描画するかを指定する．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
おもしろい例題  
関連項目
履歴
引用書式

AnatomyForm

AnatomyFormはバージョン12.0でAnatomyStylingに置き換えられた．

AnatomyForm[g]

AnatomyPlot3Dで使われるグラフィックス指示子で，解剖学的実体に基づいたグラフィックスオブジェクトをグラフィックス指示子または指示子 g の連想を使ってどのように描画するかを指定する．

詳細

  • AnatomyFormの使用にはインターネット接続が必要なことがある．
  • AnatomyForm[]は顔は描かない．
  • AnatomyForm["Natural"]は，解剖学的実体に基づいたグラフィックスオブジェクトを初期段階の指示子を無視して初期状態で保存する．
  • AnatomyFormには，解剖学的実体に対応するキーと指示子に対応する値を持つAssociationを使うことができる．
  • AnatomyFormは，他のプリミティブの一部ではないAnatomyPlot3D内の解剖学的実体にのみ適用される．

例題

すべて開く すべて閉じる

例  (1)

腕の中の上腕二頭筋を緑で彩色する：

Wolfram Language code: AnatomyPlot3D[{AnatomyForm[<|Entity["AnatomicalStructure", "BicepsBrachii"] -> Green|>], Entity["AnatomicalStructure", "LeftArm"]}]

左腎を緑で彩色する：

Wolfram Language code: AnatomyPlot3D[{AnatomyForm[<|Entity["AnatomicalStructure", "LeftKidney"] -> Green|>], Entity["AnatomicalStructure", "Kidney"]}]

左脚にカスタムの照明を適用する：

Wolfram Language code: AnatomyPlot3D[{AnatomyForm[<|Entity["AnatomicalStructure", "LeftLeg"] -> (Lighting -> {{"Ambient", GrayLevel[.3]}, {"Directional", Blue, ImageScaled[{1, 1, 1}]}})|>], Entity["AnatomicalStructure", "Leg"]}]

スコープ  (5)

ある実体についてのEdgeFormを変更する．これは，すべてのオブジェクトに影響するスタンドアロンのEdgeForm指示子を使って行うことができる：

Wolfram Language code: AnatomyPlot3D[{EdgeForm[{Thick, Blue}], Entity["AnatomicalStructure", "LeftFemur"], Cuboid[{200, -44, 550}, {222, 44, 575}]}]

解剖学的実体のみに適用されるAnatomyFormを使うこともできる：

Wolfram Language code: AnatomyPlot3D[{AnatomyForm[EdgeForm[{Thick, Blue}]], Entity["AnatomicalStructure", "LeftFemur"], Cuboid[{200, -44, 550}, {222, 44, 575}]}]

AnatomyFormは，引数なしで使うとFaceForm[]のように振る舞う：

Wolfram Language code: AnatomyPlot3D[{AnatomyForm[], EdgeForm[Blue], Entity["AnatomicalStructure", "SeventhCervicalVertebra"]}]

AnatomyForm["Natural"]は，初期の指示子を無視してもとの状態のスタイルを復元する：

Wolfram Language code: AnatomyPlot3D[{Red, Entity["AnatomicalStructure", "SeventhCervicalVertebra"], AnatomyForm["Natural"], Entity["AnatomicalStructure", "FirstThoracicVertebra"]}]

次は，上腕二頭筋のような「中間」構造は，小さい原子的な成分から作られたものであっても扱うことができることを示している：

Wolfram Language code: AnatomyPlot3D[{AnatomyForm[<|Entity["AnatomicalStructure", "BicepsBrachii"] -> Green|>], Entity["AnatomicalStructure", "LeftArm"]}]

次の例は，より下位レベルの原子的な構造に別々にアクセスできることを示している：

Wolfram Language code: AnatomyPlot3D[{AnatomyForm[<|Entity["AnatomicalStructure", "LongHeadOfLeftBicepsBrachii"] -> Green, Entity["AnatomicalStructure", "ShortHeadOfLeftBicepsBrachii"] -> Blue|>], Entity["AnatomicalStructure", "LeftArm"]}]

次の例は，筋肉（あるいは任意の他の実体）をある特定の色に塗り，それ除いた他のすべてのオブジェクトを別の1色で塗れることを示している：

Wolfram Language code: AnatomyPlot3D[{AnatomyForm[<|_ -> Red, Entity["AnatomicalStructure", "Muscle"] -> Blue|>], Entity["AnatomicalStructure", "LeftArm"]}]

選択した筋肉に切取り平面を適用する：

Wolfram Language code: GraphicsRow[{AnatomyPlot3D[{AnatomyForm[<|Entity["AnatomicalStructure", "BicepsBrachii"] -> Directive[Green]|>], Entity["AnatomicalStructure", "LeftArm"]}], AnatomyPlot3D[{AnatomyForm[<|Entity["AnatomicalStructure", "BicepsBrachii"] -> Directive[Green, ClipPlanes -> {InfinitePlane[{{183, -57, 1156}, {175, -69, 1139}, {179, -65, 1153}}]}]|>], Entity["AnatomicalStructure", "LeftArm"]}]}]

おもしろい例題  (1)

「逆光」/X線効果を組み合せたシミュレーションを行う：

Wolfram Language code: reverselights = Join[{{"Ambient", Black}}, Table[{"Directional", Hue[.58, .5, 1], ImageScaled[{Sin[x], Cos[x], -.5}]}, {x, 0, 2 Pi - 2 Pi / 8, 2 Pi / 8}]];
Wolfram Language code: AnatomyPlot3D[{AnatomyForm[<|_ -> Directive[Specularity[White, 50], Hue[.58, 0, 1, .1], Lighting -> reverselights], Entity["AnatomicalStructure", "LeftHumerus"] -> Red|>], Entity["AnatomicalStructure", "LeftArm"]}, Background -> Hue[.58, 1, .3], SphericalRegion -> True]
Wolfram Research (2016), AnatomyForm, Wolfram言語関数， https://reference.wolfram.com/language/ref/AnatomyForm.html.

テキスト

Wolfram Research (2016), AnatomyForm, Wolfram言語関数， https://reference.wolfram.com/language/ref/AnatomyForm.html.

CMS

Wolfram Language. 2016. "AnatomyForm." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/AnatomyForm.html.

APA

Wolfram Language. (2016). AnatomyForm. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/AnatomyForm.html

BibTeX

@misc{reference.wolfram_2026_anatomyform, author="Wolfram Research", title="{AnatomyForm}", year="2016", howpublished="\url{https://reference.wolfram.com/language/ref/AnatomyForm.html}", note=[Accessed: 16-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_anatomyform, organization={Wolfram Research}, title={AnatomyForm}, year={2016}, url={https://reference.wolfram.com/language/ref/AnatomyForm.html}, note=[Accessed: 16-August-2026]}