WOLFRAM

Wolfram 语言与系统参考资料中心

AnatomyForm[g]

是在 AnatomyPlot3D 使用的一种图像指令，可以使用图像指令或关联指令 g　来指定解剖学条目为基础的图像对象如何绘制.

更多信息
Details and Options Details and Options
范例  
基本范例  
范围  
巧妙范例  
参见
历史
按以下格式引用：

AnatomyForm

在版本 12，AnatomyForm 已被 AnatomyStyling 替代.

AnatomyForm[g]

是在 AnatomyPlot3D 使用的一种图像指令，可以使用图像指令或关联指令 g　来指定解剖学条目为基础的图像对象如何绘制.

更多信息

  • 有些情况下，AnatomyForm 会要求网络连接.
  • AnatomyForm[] 不绘制面部.
  • AnatomyForm["Natural"] 会忽略较早的指令，而将解剖学条目为基础的图像对象以其初始状态储存.
  • AnatomyForm 接受带有与解剖学条目相当的键和与指令相当的值的关联关系 Association.
  • AnatomyForm 只应用于 AnatomyPlot3D 中的且不包含于其他基元的解剖学条目.

范例

打开所有单元 关闭所有单元

基本范例  (1)

将手臂上的肱二头肌涂成绿色：

Wolfram Language code: AnatomyPlot3D[{AnatomyForm[<|Entity["AnatomicalStructure", "BicepsBrachii"] -> Green|>], Entity["AnatomicalStructure", "LeftArm"]}]

将左肾涂成绿色：

Wolfram Language code: AnatomyPlot3D[{AnatomyForm[<|Entity["AnatomicalStructure", "LeftKidney"] -> Green|>], Entity["AnatomicalStructure", "Kidney"]}]

对左腿使用自定义光照：

Wolfram Language code: AnatomyPlot3D[{AnatomyForm[<|Entity["AnatomicalStructure", "LeftLeg"] -> (Lighting -> {{"Ambient", GrayLevel[.3]}, {"Directional", Blue, ImageScaled[{1, 1, 1}]}})|>], Entity["AnatomicalStructure", "Leg"]}]

范围  (5)

想要为某条目修改 EdgeForm. 可以使用 EdgeForm 指令来达到这一目的，该操作会影响所有对象：

Wolfram Language code: AnatomyPlot3D[{EdgeForm[{Thick, Blue}], Entity["AnatomicalStructure", "LeftFemur"], Cuboid[{200, -44, 550}, {222, 44, 575}]}]

也可使用 AnatomyForm　来实现这一目的，但只应用于解剖学条目：

Wolfram Language code: AnatomyPlot3D[{AnatomyForm[EdgeForm[{Thick, Blue}]], Entity["AnatomicalStructure", "LeftFemur"], Cuboid[{200, -44, 550}, {222, 44, 575}]}]

若　AnatomyForm 无参数，则类似于 FaceForm[]：

Wolfram Language code: AnatomyPlot3D[{AnatomyForm[], EdgeForm[Blue], Entity["AnatomicalStructure", "SeventhCervicalVertebra"]}]

AnatomyForm["Natural"] 会忽略较早的指令，将样式储存为其初始状态：

Wolfram Language code: AnatomyPlot3D[{Red, Entity["AnatomicalStructure", "SeventhCervicalVertebra"], AnatomyForm["Natural"], Entity["AnatomicalStructure", "FirstThoracicVertebra"]}]

下列范例说明，也可以对像肱二头肌这种“中间”结构进行操作，尽管这些结构由更微小的部分组成：

Wolfram Language code: AnatomyPlot3D[{AnatomyForm[<|Entity["AnatomicalStructure", "BicepsBrachii"] -> Green|>], Entity["AnatomicalStructure", "LeftArm"]}]

下例说明，你可以分别访问等级更低的微结构：

Wolfram Language code: AnatomyPlot3D[{AnatomyForm[<|Entity["AnatomicalStructure", "LongHeadOfLeftBicepsBrachii"] -> Green, Entity["AnatomicalStructure", "ShortHeadOfLeftBicepsBrachii"] -> Blue|>], Entity["AnatomicalStructure", "LeftArm"]}]

下例说明，除了肌肉（或其他条目）会是不同颜色外，你可以给所有对象都上同一个颜色：

Wolfram Language code: AnatomyPlot3D[{AnatomyForm[<|_ -> Red, Entity["AnatomicalStructure", "Muscle"] -> Blue|>], Entity["AnatomicalStructure", "LeftArm"]}]

将裁剪平面 (clipping plane) 应用于选中的肌肉：

Wolfram Language code: GraphicsRow[{AnatomyPlot3D[{AnatomyForm[<|Entity["AnatomicalStructure", "BicepsBrachii"] -> Directive[Green]|>], Entity["AnatomicalStructure", "LeftArm"]}], AnatomyPlot3D[{AnatomyForm[<|Entity["AnatomicalStructure", "BicepsBrachii"] -> Directive[Green, ClipPlanes -> {InfinitePlane[{{183, -57, 1156}, {175, -69, 1139}, {179, -65, 1153}}]}]|>], Entity["AnatomicalStructure", "LeftArm"]}]}]

巧妙范例  (1)

模拟一个“逆光”　ｘ　射线效果的组合：

Wolfram Language code: reverselights = Join[{{"Ambient", Black}}, Table[{"Directional", Hue[.58, .5, 1], ImageScaled[{Sin[x], Cos[x], -.5}]}, {x, 0, 2 Pi - 2 Pi / 8, 2 Pi / 8}]];
Wolfram Language code: AnatomyPlot3D[{AnatomyForm[<|_ -> Directive[Specularity[White, 50], Hue[.58, 0, 1, .1], Lighting -> reverselights], Entity["AnatomicalStructure", "LeftHumerus"] -> Red|>], Entity["AnatomicalStructure", "LeftArm"]}, Background -> Hue[.58, 1, .3], SphericalRegion -> True]
Wolfram Research (2016)，AnatomyForm，Wolfram 语言函数，https://reference.wolfram.com/language/ref/AnatomyForm.html.

文本

Wolfram Research (2016)，AnatomyForm，Wolfram 语言函数，https://reference.wolfram.com/language/ref/AnatomyForm.html.

CMS

Wolfram 语言. 2016. "AnatomyForm." Wolfram 语言与系统参考资料中心. Wolfram Research. https://reference.wolfram.com/language/ref/AnatomyForm.html.

APA

Wolfram 语言. (2016). AnatomyForm. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/AnatomyForm.html 年

BibTeX

@misc{reference.wolfram_2026_anatomyform, author="Wolfram Research", title="{AnatomyForm}", year="2016", howpublished="\url{https://reference.wolfram.com/language/ref/AnatomyForm.html}", note=[Accessed: 17-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_anatomyform, organization={Wolfram Research}, title={AnatomyForm}, year={2016}, url={https://reference.wolfram.com/language/ref/AnatomyForm.html}, note=[Accessed: 17-August-2026]}