WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

AnimationVideo[fexpr,{u,umin,umax}]

u が uminから umaxまで変化する fexpr の動画を生成する．

AnimationVideo[fexpr,{u,umin,umax,du}]

u がステップ du で変化すると解釈する．

AnimationVideo[fexpr,{u,{u1,u2,…}}]

u が値 u1, u2, …を取るようにする．

詳細とオプション
Details and Options Details and Options
例題  
例  
スコープ  
オプション  
DefaultDuration  
FrameRate  
アプリケーション  
基本的なアプリケーション  
補間によるアニメーション  
進化によるアニメーション  
時間の経過に伴うアニメーション  
テキストのアニメーション  
関連項目
関連するガイド
履歴
引用書式

AnimationVideo

AnimationVideo[fexpr,{u,umin,umax}]

u が uminから umaxまで変化する fexpr の動画を生成する．

AnimationVideo[fexpr,{u,umin,umax,du}]

u がステップ du で変化すると解釈する．

AnimationVideo[fexpr,{u,{u1,u2,…}}]

u が値 u1, u2, …を取るようにする．

詳細とオプション

例題

すべて開く すべて閉じる

例  (2)

変化するプロットの動画を生成する：

Wolfram Language code: AnimationVideo[Plot[Sin[t x], {x, 0, 10}], {t, 0, 15}]

回転する3Dグラフィックスから動画を生成する：

Wolfram Language code: AnimationVideo[Graphics3D[GeometricTransformation[Icosahedron[], RotationTransform[rot, {0, 0, 1}]], SphericalRegion -> True], {rot, 0, 2π, .05}]

スコープ  (3)

反復子の現在値をラスタライズすることで動画を生成する：

Wolfram Language code: v = AnimationVideo[Rasterize[N@i, RasterSize -> {50, 50}], {i, 0, 6}]; VideoFrameList[v, 6]

反覆子の開始値，終了値，刻み幅を指定する：

Wolfram Language code: v = AnimationVideo[Rasterize[i, RasterSize -> {50, 50}], {i, 10, 60, 2}]; VideoFrameList[v, 6]

反復子に特定の値のリストを指定する：

Wolfram Language code: v = AnimationVideo[Rasterize[i, RasterSize -> {50, 50}], {i, {35, 13, 60, 48, 25, 46}}]; VideoFrameList[v, All]

オプション  (4)

DefaultDuration  (2)

生成された動画のデフォルトの継続時間は5秒間である：

Wolfram Language code: v = AnimationVideo[Rasterize[N@i, RasterSize -> {50, 50}], {i, 0, 6}]; Duration[v]

別の継続時間を指定する：

Wolfram Language code: v = AnimationVideo[Rasterize[N@i, RasterSize -> {50, 50}], {i, 0, 6}, DefaultDuration -> 1]; Duration[v]

ステップレートとフレームレートの両方が指定されている場合は，DefaultDurationオプションは無視される：

Wolfram Language code: v = AnimationVideo[Rasterize[N@i, RasterSize -> {50, 50}], {i, 0, 6, .1}, DefaultDuration -> 1, FrameRate -> 10]; Duration[v]

FrameRate  (2)

ステップが指定されているとき，フレームレートは生成されたフレーム数と要求される継続時間から計算される：

Wolfram Language code: v = AnimationVideo[Rasterize[N@i, RasterSize -> {50, 50}], {i, 0, 6, .1}]; Information[v, "VideoTracks"]

ステップが指定されていないときは，生成された動画のフレームレートは30フレーム／秒になる：

Wolfram Language code: v = AnimationVideo[Rasterize[N@i, RasterSize -> {50, 50}], {i, 0, 6}]; Information[v, "VideoTracks"]

別のフレームレートを指定する：

Wolfram Language code: v = AnimationVideo[Rasterize[N@i, RasterSize -> {50, 50}], {i, 0, 6}, FrameRate -> 10]; Information[v, "VideoTracks"]

アプリケーション  (9)

基本的なアプリケーション  (4)

色相が進化するフレームで動画を生成する：

Wolfram Language code: AnimationVideo[ConstantImage[Hue[t]], {t, 0, 1}]

回転する画像から動画を作成する：

Wolfram Language code: AnimationVideo[ImageRotate[[image], rot, Full, Masking -> Full, Padding -> "Fixed"], {rot, 0, 2π}]

繰返しの画像効果を作成する：

Wolfram Language code: AnimationVideo[ImageTransformation[[image], FractionalPart[s#]&], {s, 1, 5}]

現在位置からズームアウトする：

Wolfram Language code: Parallelize@AnimationVideo[GeoGraphics[GeoMarker[], GeoRange -> Quantity[i, "Miles"]], {i, .1, 200}]

補間によるアニメーション  (1)

1000個のビー玉の軌跡を生成し，それらが箱の中で跳ねる様子を可視化する．

軌跡の方程式と追加的な変数を定義する：

Wolfram Language code: δ := RandomChoice[{1, -1}]; n = 1000; dur = 20; colors = RandomColor[n];
Wolfram Language code: eqns := {z''[t] == -9.81, z[0] == 10 * RandomReal[{0.5, 1}], z'[0] == 20δ RandomReal[], x'[t] == 5δ RandomReal[], x[0] == 5δ RandomReal[], y'[t] == 3 δ RandomReal[], y[0] == 5δ RandomReal[], WhenEvent[z[t] == 0, z'[t] -> -0.95z'[t]]};

軌跡を計算する：

Wolfram Language code: trajectories = Table[First@NDSolve[eqns, {x[t], y[t], z[t]}, {t, 0, dur}], n]; newtrajectories = Table[Function[t, Evaluate@tr], {tr, trajectories[[All, All, -1]]}];

動きの軌跡の動画を作成する：

Wolfram Language code: Parallelize@AnimationVideo[Graphics3D[Table[{colors[[i]], Sphere[newtrajectories[[i]][t], 1]}, {i, n}], PlotRange -> {{-100, 100}, {-50, 50}, {0, 40}}, ImageSize -> 400, Lighting -> "ThreePoint"], {t, 1, dur}, RasterSize -> 480]

進化によるアニメーション  (2)

進化するセルオートマトンを生成する：

Wolfram Language code: n = 128; AnimationVideo[ ImageCrop[ Image[CellularAutomaton[30, {{1}, 0}, Floor[i]]], {2n - 1, n}, Top ], {i, 1, n, 1} ]

球状の牛を作成する：

Wolfram Language code: mesh = ExampleData[{"Geometry3D", "Cow"}]

同等の球の半径を計算する：

Wolfram Language code: radiusCow = (3 / (4 Pi)NIntegrate[1, {x, y, z}∈MeshRegion[mesh[[1, 2, 1]], mesh[[1, 2, 2]]]] ) ^ (1 / 3);

点を球の境界に移動する：

Wolfram Language code: fattenArray[array_, coeff_] := Table[(item * ((Norm[item] / radiusCow) ^ -coeff)), {item, array}]

動画を生成する：

Wolfram Language code: Parallelize@AnimationVideo[Show[mesh /. GraphicsComplex[array_, rest___] :> GraphicsComplex[fattenArray[array, coeff], rest]], {coeff, 0, 1}]

時間の経過に伴うアニメーション  (1)

夜空の変化を観察する：

Wolfram Language code: AnimationVideo[AstroGraphics[AstroReferenceFrame -> {"Horizon", DateObject[{2023, 12, 27, 0, 0, 0}, "Instant", "Gregorian", 2.] + Quantity[i, "Hours"]}, AstroBackground -> "GalacticSky"], {i, 0, 24}]

テキストのアニメーション  (1)

テキストの文字を一度に1字ずつ作成する動画を生成する：

Wolfram Language code: str = "Wolfram "; AnimationVideo[Graphics[{Haloing[White], Text[Style[StringTake[str, i], 45, Red]]}, Background -> Black], {i, 1, StringLength[str], 1}, DefaultDuration -> 2]
Wolfram Research (2021), AnimationVideo, Wolfram言語関数， https://reference.wolfram.com/language/ref/AnimationVideo.html.

テキスト

Wolfram Research (2021), AnimationVideo, Wolfram言語関数， https://reference.wolfram.com/language/ref/AnimationVideo.html.

CMS

Wolfram Language. 2021. "AnimationVideo." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/AnimationVideo.html.

APA

Wolfram Language. (2021). AnimationVideo. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/AnimationVideo.html

BibTeX

@misc{reference.wolfram_2026_animationvideo, author="Wolfram Research", title="{AnimationVideo}", year="2021", howpublished="\url{https://reference.wolfram.com/language/ref/AnimationVideo.html}", note=[Accessed: 11-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_animationvideo, organization={Wolfram Research}, title={AnimationVideo}, year={2021}, url={https://reference.wolfram.com/language/ref/AnimationVideo.html}, note=[Accessed: 11-September-2026]}