WOLFRAM

Wolfram 语言与系统参考资料中心

AnimationVideo[fexpr,{u,umin,umax}]

生成 fexpr 的视频，其中 u 的值从 umin 到 umax 变化.

AnimationVideo[fexpr,{u,umin,umax,du}]

让 u 在步骤 du 中变化.

AnimationVideo[fexpr,{u,{u1,u2,…}}]

让 u 取值 u1, u2, ….

更多信息和选项
Details and Options Details and Options
范例  
基本范例  
范围  
选项  
DefaultDuration  
FrameRate  
应用  
基本应用  
插值动画  
演变动画  
随时间推移的动画  
动画文本  
参见
相关指南
历史
按以下格式引用：

AnimationVideo

AnimationVideo[fexpr,{u,umin,umax}]

生成 fexpr 的视频，其中 u 的值从 umin 到 umax 变化.

AnimationVideo[fexpr,{u,umin,umax,du}]

让 u 在步骤 du 中变化.

AnimationVideo[fexpr,{u,{u1,u2,…}}]

让 u 取值 u1, u2, ….

更多信息和选项

范例

打开所有单元 关闭所有单元

基本范例  (2)

生成变化图的视频：

Wolfram Language code: AnimationVideo[Plot[Sin[t x], {x, 0, 10}], {t, 0, 15}]

生成旋转三维图形的视频：

Wolfram Language code: AnimationVideo[Graphics3D[GeometricTransformation[Icosahedron[], RotationTransform[rot, {0, 0, 1}]], SphericalRegion -> True], {rot, 0, 2π, .05}]

范围  (3)

通过对迭代器的当前值进行光栅化来生成视频：

Wolfram Language code: v = AnimationVideo[Rasterize[N@i, RasterSize -> {50, 50}], {i, 0, 6}]; VideoFrameList[v, 6]

指定开始、结束和步长值：

Wolfram Language code: v = AnimationVideo[Rasterize[i, RasterSize -> {50, 50}], {i, 10, 60, 2}]; VideoFrameList[v, 6]

指定迭代器的特定值列表：

Wolfram Language code: v = AnimationVideo[Rasterize[i, RasterSize -> {50, 50}], {i, {35, 13, 60, 48, 25, 46}}]; VideoFrameList[v, All]

选项  (4)

DefaultDuration  (2)

生成的视频的默认持续时间为 5 秒：

Wolfram Language code: v = AnimationVideo[Rasterize[N@i, RasterSize -> {50, 50}], {i, 0, 6}]; Duration[v]

指定不同的持续时间：

Wolfram Language code: v = AnimationVideo[Rasterize[N@i, RasterSize -> {50, 50}], {i, 0, 6}, DefaultDuration -> 1]; Duration[v]

如果同时指定了步长规范和帧速率，则忽略 DefaultDuration 选项：

Wolfram Language code: v = AnimationVideo[Rasterize[N@i, RasterSize -> {50, 50}], {i, 0, 6, .1}, DefaultDuration -> 1, FrameRate -> 10]; Duration[v]

FrameRate  (2)

如果指定了一个步骤，将根据生成的帧数和请求的持续时间计算帧速率：

Wolfram Language code: v = AnimationVideo[Rasterize[N@i, RasterSize -> {50, 50}], {i, 0, 6, .1}]; Information[v, "VideoTracks"]

如果不指定步骤，则生成的视频将具有 30 帧/秒的帧速率：

Wolfram Language code: v = AnimationVideo[Rasterize[N@i, RasterSize -> {50, 50}], {i, 0, 6}]; Information[v, "VideoTracks"]

指定不同的帧速率：

Wolfram Language code: v = AnimationVideo[Rasterize[N@i, RasterSize -> {50, 50}], {i, 0, 6}, FrameRate -> 10]; Information[v, "VideoTracks"]

应用  (9)

基本应用  (4)

生成有色相变化的帧的视频：

Wolfram Language code: AnimationVideo[ConstantImage[Hue[t]], {t, 0, 1}]

从旋转图像创建视频：

Wolfram Language code: AnimationVideo[ImageRotate[[image], rot, Full, Masking -> Full, Padding -> "Fixed"], {rot, 0, 2π}]

创建重复图像效果：

Wolfram Language code: AnimationVideo[ImageTransformation[[image], FractionalPart[s#]&], {s, 1, 5}]

放大当前位置：

Wolfram Language code: Parallelize@AnimationVideo[GeoGraphics[GeoMarker[], GeoRange -> Quantity[i, "Miles"]], {i, .1, 200}]

插值动画  (1)

生成一千个弹珠的轨迹，并想象它们在盒子里弹跳的样子.

定义轨迹方程和附加变量：

Wolfram Language code: δ := RandomChoice[{1, -1}]; n = 1000; dur = 20; colors = RandomColor[n];
Wolfram Language code: eqns := {z''[t] == -9.81, z[0] == 10 * RandomReal[{0.5, 1}], z'[0] == 20δ RandomReal[], x'[t] == 5δ RandomReal[], x[0] == 5δ RandomReal[], y'[t] == 3 δ RandomReal[], y[0] == 5δ RandomReal[], WhenEvent[z[t] == 0, z'[t] -> -0.95z'[t]]};

计算轨迹：

Wolfram Language code: trajectories = Table[First@NDSolve[eqns, {x[t], y[t], z[t]}, {t, 0, dur}], n]; newtrajectories = Table[Function[t, Evaluate@tr], {tr, trajectories[[All, All, -1]]}];

制作运动轨迹视频：

Wolfram Language code: Parallelize@AnimationVideo[Graphics3D[Table[{colors[[i]], Sphere[newtrajectories[[i]][t], 1]}, {i, n}], PlotRange -> {{-100, 100}, {-50, 50}, {0, 40}}, ImageSize -> 400, Lighting -> "ThreePoint"], {t, 1, dur}, RasterSize -> 480]

演变动画  (2)

生成一个进化的元胞自动机：

Wolfram Language code: n = 128; AnimationVideo[ ImageCrop[ Image[CellularAutomaton[30, {{1}, 0}, Floor[i]]], {2n - 1, n}, Top ], {i, 1, n, 1} ]

制做一头球形牛：

Wolfram Language code: mesh = ExampleData[{"Geometry3D", "Cow"}]

计算等效球面半径：

Wolfram Language code: radiusCow = (3 / (4 Pi)NIntegrate[1, {x, y, z}∈MeshRegion[mesh[[1, 2, 1]], mesh[[1, 2, 2]]]] ) ^ (1 / 3);

将点移至球体边界：

Wolfram Language code: fattenArray[array_, coeff_] := Table[(item * ((Norm[item] / radiusCow) ^ -coeff)), {item, array}]

生成视频：

Wolfram Language code: Parallelize@AnimationVideo[Show[mesh /. GraphicsComplex[array_, rest___] :> GraphicsComplex[fattenArray[array, coeff], rest]], {coeff, 0, 1}]

随时间推移的动画  (1)

站着看夜空变化：

Wolfram Language code: AnimationVideo[AstroGraphics[AstroReferenceFrame -> {"Horizon", DateObject[{2023, 12, 27, 0, 0, 0}, "Instant", "Gregorian", 2.] + Quantity[i, "Hours"]}, AstroBackground -> "GalacticSky"], {i, 0, 24}]

动画文本  (1)

逐字符生成文本视频：

Wolfram Language code: str = "Wolfram ";D AnimationVideo[Graphics[{Haloing[White], Text[Style[StringTake[str, i], 45, Red]]}, Background -> Black], {i, 1, StringLength[str], 1}, DefaultDuration -> 2]
Wolfram Research (2021)，AnimationVideo，Wolfram 语言函数，https://reference.wolfram.com/language/ref/AnimationVideo.html.

文本

Wolfram Research (2021)，AnimationVideo，Wolfram 语言函数，https://reference.wolfram.com/language/ref/AnimationVideo.html.

CMS

Wolfram 语言. 2021. "AnimationVideo." Wolfram 语言与系统参考资料中心. Wolfram Research. https://reference.wolfram.com/language/ref/AnimationVideo.html.

APA

Wolfram 语言. (2021). AnimationVideo. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/AnimationVideo.html 年

BibTeX

@misc{reference.wolfram_2026_animationvideo, author="Wolfram Research", title="{AnimationVideo}", year="2021", howpublished="\url{https://reference.wolfram.com/language/ref/AnimationVideo.html}", note=[Accessed: 16-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_animationvideo, organization={Wolfram Research}, title={AnimationVideo}, year={2021}, url={https://reference.wolfram.com/language/ref/AnimationVideo.html}, note=[Accessed: 16-September-2026]}