WOLFRAM

Wolfram 语言与系统参考资料中心

ArcCoth[z]

给出复数 的反双曲余切 .

更多信息
Details and Options Details and Options
背景
范例  
基本范例  
范围  
数值计算  
特殊值  
可视化  
Show More Show More
函数属性  
微分  
积分  
级数展开式  
函数恒等式和化简  
函数表示  
应用  
属性和关系  
参见
技术笔记
相关指南
相关链接
历史
按以下格式引用：

ArcCoth

ArcCoth[z]

给出复数 的反双曲余切 .

更多信息

  • 数学函数，适宜于符号和数值计算.
  • 对于某些特殊参数，ArcCoth 自动计算出精确值.
  • ArcCoth 可以计算到任意数值精度.
  • ArcCoth 自动逐项作用于列表的各个元素.
  • ArcCoth[z] 在复平面 上有一个分支切割，从 到 .
  • ArcCoth 可与 Interval 和 CenteredInterval 对象一起使用. »

背景

范例

打开所有单元 关闭所有单元

基本范例  (6)

数值计算：

Wolfram Language code: ArcCoth[2.5]

在实数域子集上绘图：

Wolfram Language code: Plot[ArcCoth[x], {x, -5, 5}]

在复数的子集上绘图：

Wolfram Language code: ComplexPlot3D[ArcCoth[z], {z, -3 - I, 3 + I}, PlotLegends -> Automatic]

在原点处的级数展开：

Wolfram Language code: Series[ArcCoth[x], {x, 0, 3}, Assumptions -> x > 0]

在 Infinity 处的渐进展开：

Wolfram Language code: Series[ArcCoth[x], {x, ∞, 5}]

在奇点处的渐近展开：

Wolfram Language code: Series[ArcCoth[x], {x, 1, 3}, Assumptions -> x > 1]

范围  (43)

数值计算  (6)

数值计算：

Wolfram Language code: ArcCoth[2.0]

高精度求值：

Wolfram Language code: N[ArcCoth[2], 50]

输出精度与输入精度一致：

Wolfram Language code: ArcCoth[2.00000000000000000000000000000000000000000]

对复变量进行计算：

Wolfram Language code: ArcCoth[2.5 + I]

在高精度条件下高效计算 ArcCoth：

Wolfram Language code: ArcCoth[2`500]//Timing
Wolfram Language code: ArcCoth[2`100000];//Timing

用 Interval 和 CenteredInterval 对象计算最坏情况下的区间：

Wolfram Language code: ArcCoth[Interval[{1, Coth[5]}]]
Wolfram Language code: ArcCoth[CenteredInterval[-4, 1 / 100]]
Wolfram Language code: ArcCoth[CenteredInterval[1 - 5I, (1 + I) / 100]]

或使用 Around 计算一般情况下的统计区间：

Wolfram Language code: ArcCoth[Around[.9, 0.1]]

计算数组中每个元素的值：

Wolfram Language code: ArcCoth[{{I, -I}, {0, -I}}]

或用 MatrixFunction 以矩阵形式计算 ArcCoth 函数：

Wolfram Language code: MatrixFunction[ArcCoth[#]&, {{I, -I}, {0, -I}}]

特殊值  (5)

ArcCoth 在固定点上的值：

Wolfram Language code: Table[ArcCoth[I n], {n, -1, 1}]

无穷处的值：

Wolfram Language code: ArcCoth[Infinity]
Wolfram Language code: ArcCoth[ComplexInfinity]

ArcCoth 的奇点：

Wolfram Language code: ArcCoth[1]
Wolfram Language code: ArcCoth[-1]

求满足方程 的 值：

Wolfram Language code: f[x_] := ArcCoth[x] - 1; xzero = Solve[f[x] == 0 && 0 < x < 3, x][[1, 1]]
Wolfram Language code: Plot[f[x], {x, 0, 3}, Epilog -> Style[Point[{xzero[[2]], f[xzero[[2]]]}], PointSize[Large], Red]]

自动生成简单精确值：

Wolfram Language code: ArcCoth[0]
Wolfram Language code: ArcCoth[I]

可视化  (3)

绘制 ArcCoth 函数：

Wolfram Language code: Plot[ArcCoth[x], {x, -2, 2}]

绘制 的实部：

Wolfram Language code: ComplexContourPlot[Re[ArcCoth[z]], {z, -3 - 3 I, 3 + 3 I}, Contours -> 24]

绘制 的虚部：

Wolfram Language code: ComplexContourPlot[Im[ArcCoth[z]], {z, -3 - 3 I, 3 + 3 I}, Contours -> 24]

，绘制极坐标图：

Wolfram Language code: Table[PolarPlot[ArcCoth[k ϕ], {ϕ, -4π, 4π}, Sequence[Frame -> True, PlotLabel -> "k=" <> ToString[k], PlotRange -> {{-3, 3}, {-1, 3}}]], {k, 1, 4}]

函数属性  (11)

ArcCoth 是针对除区间 外的所有实数定义的：

Wolfram Language code: FunctionDomain[ArcCoth[x], x]

复定义域：

Wolfram Language code: FunctionDomain[ArcCoth[z], z, Complexes]

ArcCoth 获得除0以外的所有实数值：

Wolfram Language code: FunctionRange[ArcCoth[x], x, y]

复定义域参数的值域范围：

Wolfram Language code: FunctionRange[ArcCoth[z], z, y, Complexes]

ArcCoth 是一个奇函数：

Wolfram Language code: ArcCoth[-x]

ArcCoth 不是解析函数：

Wolfram Language code: FunctionAnalytic[ArcCoth[x], x]

也不是亚纯函数：

Wolfram Language code: FunctionMeromorphic[ArcCoth[x], x]

ArcCoth 既不是非递增，也不是非递减：

Wolfram Language code: FunctionMonotonicity[ArcCoth[x], x]

ArcCoth 是单射函数：

Wolfram Language code: FunctionInjective[ArcCoth[x], x]
Wolfram Language code: Plot[{ArcCoth[x], 1}, {x, -5, 5}]

ArcCoth 不是满射函数：

Wolfram Language code: FunctionSurjective[ArcCoth[x], x]
Wolfram Language code: Plot[{ArcCoth[x], 0}, {x, -2, 2}]

ArcCoth 既不是非负，也不是非正：

Wolfram Language code: FunctionSign[ArcCoth[x], x]

函数在 [-1,1] 内有奇点和断点：

Wolfram Language code: FunctionSingularities[ArcCoth[x], x]
Wolfram Language code: FunctionDiscontinuities[ArcCoth[x], x]

ArcCoth 既不凸，也不凹：

Wolfram Language code: FunctionConvexity[ArcCoth[x], x]

TraditionalForm 格式输出：

Wolfram Language code: ArcCoth[x]//TraditionalForm

微分  (3)

一阶导数：

Wolfram Language code: D[ArcCoth[x], x]

高阶导数：

Wolfram Language code: Table[D[ArcCoth[x], {x, n}], {n, 1, 4}]
Wolfram Language code: Plot[Evaluate[%], {x, -1, 1}, PlotLegends -> {"First Derivative", "Second Derivative", "Third Derivative", "Fourth Derivative"}]

阶导数的公式：

Wolfram Language code: D[ArcCoth[x], {x, n}]

积分  (3)

ArcCoth 的不定积分：

Wolfram Language code: Integrate[ArcCoth[x], x]

含有 ArcCoth 的定积分：

Wolfram Language code: Integrate[(ArcCoth[x]/x), {x, 1, Infinity}]

更多积分：

Wolfram Language code: Integrate[x ArcCoth[x], x]
Wolfram Language code: Integrate[x ^ k ArcCoth[x], x]

级数展开式  (4)

使用 Series 求泰勒级数展开式：

Wolfram Language code: Series[ArcCoth[x], {x, 2, 4}]

绘制 ArcCoth 在 处的前三个近似式：

Wolfram Language code: terms = Normal@Table[Series[ArcCoth[x], {x, 2, m}], {m, 1, 3}]; Plot[{ArcCoth[x], terms}, {x, 1, 3}, PlotRange -> {{1, 3}, {0, 3}}]

ArcCoth 级数展开式的通项:

Wolfram Language code: SeriesCoefficient[ArcCoth[x], {x, 2, n}]

在分支点和分支切口处求级数展开式：

Wolfram Language code: Series[ArcCoth[x], {x, 1, 1}]
Wolfram Language code: Series[ArcCoth[x], {x, (1/2), 1}]

ArcCoth 可被应用于幂级数：

Wolfram Language code: ArcCoth[SeriesData[x, 0, {1, 0, 1/3, 0, -1/45, 0, 2/945, 0, -1/4725}, -1, 8, 1]]

函数恒等式和化简  (3)

化简含有 ArcCoth 的表达式：

Wolfram Language code: Simplify[Coth[ArcCoth[x] + ArcCoth[y]] - (1 + x y/x + y)]

用 Log 表示 ArcCoth：

Wolfram Language code: TrigToExp[ArcCoth[z]]

转换回来：

Wolfram Language code: ExpToTrig[%]//FullSimplify

假定实数变量 和 的情况下进行展开：

Wolfram Language code: ComplexExpand[ArcCoth[x + I y]]//FullSimplify

函数表示  (5)

使用 ArcCoth 表示：

Wolfram Language code: ArcCoth[1 / x]//FullSimplify

通过逆 Jacobi 函数表示：

Wolfram Language code: InverseJacobiNS[z, 1]
Wolfram Language code: InverseJacobiSN[(1/z), 1]//FullSimplify

ArcCoth 是 Hypergeometric2F1 的特例：

Wolfram Language code: (Hypergeometric2F1[1, (1/2), (3/2), (1/z^2)]/z)//FullSimplify

可用 MeijerG 来表示 ArcCoth：

Wolfram Language code: MeijerGReduce[ArcCoth[x], x]
Wolfram Language code: Activate[%]//FullSimplify

也可用 DifferentialRoot 来表示 ArcCoth：

Wolfram Language code: DifferentialRootReduce[ArcCoth[x], x]

应用  (3)

ArcCoth 的分支切割：

Wolfram Language code: Plot3D[Im[ArcCoth[x - I y]], {x, -2, 2}, {y, -1, 1}]

解微分方程：

Wolfram Language code: DSolve[x y'[x] - y[x] - ArcCoth[x] == 0, y[x], x]

计算随机变量与平均值相差一个标准差以内的概率：

Wolfram Language code: 𝒟 = ProbabilityDistribution[Sqrt[2] / Pi / (1 + x ^ 4), {x, -∞, ∞}];
Wolfram Language code: μ = Mean[𝒟]; σ = StandardDeviation[𝒟]; pdf = PDF[𝒟, x];
Wolfram Language code: Probability[μ - σ < x < μ + σ, x𝒟]

获取该概率的数值：

Wolfram Language code: N[%]

绘制该区域的概率密度函数 (PDF)：

Wolfram Language code: Show[Plot[pdf, {x, -3, μ - σ}, Filling -> Axis, AxesOrigin -> {0, 0}], Plot[pdf, {x, μ - σ, μ + σ}], Plot[pdf, {x, μ + σ, 3}, Filling -> Axis, AxesOrigin -> {0, 0}], PlotRange -> {0, 1 / 2}, Ticks -> {Automatic, None}]

属性和关系  (1)

利用 Log 表示 ArcCoth：

Wolfram Language code: TrigToExp[ArcCoth[z]]

反向变换：

Wolfram Language code: ExpToTrig[%]
Wolfram Research (1988)，ArcCoth，Wolfram 语言函数，https://reference.wolfram.com/language/ref/ArcCoth.html （更新于 2021 年）.

文本

Wolfram Research (1988)，ArcCoth，Wolfram 语言函数，https://reference.wolfram.com/language/ref/ArcCoth.html （更新于 2021 年）.

CMS

Wolfram 语言. 1988. "ArcCoth." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2021. https://reference.wolfram.com/language/ref/ArcCoth.html.

APA

Wolfram 语言. (1988). ArcCoth. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/ArcCoth.html 年

BibTeX

@misc{reference.wolfram_2026_arccoth, author="Wolfram Research", title="{ArcCoth}", year="2021", howpublished="\url{https://reference.wolfram.com/language/ref/ArcCoth.html}", note=[Accessed: 18-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_arccoth, organization={Wolfram Research}, title={ArcCoth}, year={2021}, url={https://reference.wolfram.com/language/ref/ArcCoth.html}, note=[Accessed: 18-August-2026]}