WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

ArcSech[z]

複素数 の逆双曲線正割を与える．

詳細
Details and Options Details and Options
予備知識
例題  
例  
スコープ  
数値評価  
特定の値  
可視化  
Show More Show More
関数の特性  
微分  
積分  
級数展開  
関数の恒等式と簡約  
関数表現  
アプリケーション  
特性と関係  
関連項目
テクニカルノート
関連するガイド
関連リンク
履歴
引用書式

ArcSech

ArcSech[z]

複素数 の逆双曲線正割を与える．

詳細

  • 記号操作・数値操作の両方に適した数学関数である．
  • 特別な引数の場合，ArcSechは自動的に厳密値を計算する．
  • ArcSechは任意の数値精度で評価できる．
  • ArcSechは自動的にリストに関数の並列的な適用を行う．
  • ArcSech[z]は，複素 平面上，〜そして〜の範囲で不連続な分枝切断線を持つ．
  • ArcSechはIntervalオブジェクトおよびCenteredIntervalオブジェクトに使うことができる． »

予備知識

  • ArcSechは逆双曲線正割関数である．ArcSec[x]は，実数 について， となるようなの双曲線角度を表す．
  • ArcSechは自動的にリストに縫い込まれる．特別な引数の場合，ArcSechは自動的に厳密値を計算する．厳密な数式が引数として与えられると，ArcSechは任意の数値精度に評価できることがある．ArcSechを含む記号式の操作に便利なその他の演算には，FunctionExpand，TrigToExp，TrigExpand，Simplify，FullSimplifyがある．
  • ArcSechは，複素引数 について，によって定義される．ArcSech[z]は複素 平面上で不連続な分枝切断線を持つ．
  • 関連する数学関数には，Sech，ArcCsch，ArcSecがある．

例題

すべて開く すべて閉じる

例  (6)

数値的に評価する：

Wolfram Language code: ArcSech[0.5]

実数の部分集合上でプロットする：

Wolfram Language code: Plot[ArcSech[x], {x, 0, 1}]

複素数の部分集合上でプロットする：

Wolfram Language code: ComplexPlot3D[ArcSech[z], {z, -1 - 2I, 1 + 2I}, PlotLegends -> Automatic]

原点における級数展開：

Wolfram Language code: Series[ArcSech[z], {z, 0, 10}, Assumptions -> z > 0]

Infinityにおける漸近展開：

Wolfram Language code: Series[ArcSech[z], {z, ∞, 3}]

特異点における漸近展開：

Wolfram Language code: Series[ArcSech[z], {z, 1, 3}, Assumptions -> z < 1]

スコープ  (40)

数値評価  (6)

数値的に評価する：

Wolfram Language code: ArcSech[1.0 / 3.0]

高精度で評価する：

Wolfram Language code: N[ArcSech[1 / 3], 50]

出力精度は入力精度に従う：

Wolfram Language code: ArcSech[0.33333333333333333333333333333333333333333]

数値引数について評価する：

Wolfram Language code: ArcSech[1.5 - I]

ArcSechを高精度で効率よく評価する：

Wolfram Language code: ArcSech[1.2`500]//Timing
Wolfram Language code: ArcSech[1.2`100000];//Timing

IntervalオブジェクトとCenteredIntervalオブジェクトを使って最悪の場合に保証される区間を計算する：

Wolfram Language code: ArcSech[Interval[{1 / 2, 1}]]
Wolfram Language code: ArcSech[CenteredInterval[-3, 1 / 100]]
Wolfram Language code: ArcSech[CenteredInterval[2 + 3I, (1 + I) / 100]]

Aroundを使って平均的な場合の統計区間を計算することもできる：

Wolfram Language code: ArcSech[Around[.9, 0.1]]

配列の要素ごとの値を計算する：

Wolfram Language code: ArcSech[{{2, 0}, {1, -2}}]

MatrixFunctionを使って行列のArcSech関数を計算することもできる：

Wolfram Language code: MatrixFunction[ArcSech[#]&, {{2, 0}, {1, -2}}]

特定の値  (4)

固定点におけるArcSechの値：

Wolfram Language code: Table[ArcSech[n], {n, -2, 2}]

無限大における値：

Wolfram Language code: ArcSech[Infinity]
Wolfram Language code: ArcSech[ComplexInfinity]

ArcSechの零点：

Wolfram Language code: ArcSech[1]

方程式を満足する の値を求める：

Wolfram Language code: f[x_] := ArcSech[x] - Log[2];
Wolfram Language code: sol = Solve[f[x] == 0, x]

値を代入する：

Wolfram Language code: xzero = x /. First[sol]

結果を可視化する：

Wolfram Language code: Plot[f[x], {x, 0, 1}, Epilog -> Style[Point[{xzero, f[xzero]}], PointSize[Large], Red]]

可視化  (3)

ArcSech関数をプロットする：

Wolfram Language code: Plot[ArcSech[x], {x, 0, 1}]

の実部をプロットする：

Wolfram Language code: ComplexContourPlot[Re[ArcSech[z]], {z, -3 - 3 I, 3 + 3 I}, Contours -> 24]

の虚部をプロットする：

Wolfram Language code: ComplexContourPlot[Im[ArcSech[z]], {z, -3 - 3 I, 3 + 3 I}, Contours -> 24]

の極プロット：

Wolfram Language code: Table[PolarPlot[ArcSech[k ϕ], {ϕ, -π, π}, Sequence[Frame -> True, PlotLabel -> "k=" <> ToString[k], PlotRange -> {{0, 12}, {-0.7, 0.7}}, AspectRatio -> 0.8]], {k, 1, 4}]

関数の特性  (10)

ArcSechは，区間からのすべての実数値について定義される：

Wolfram Language code: FunctionDomain[ArcSech[x], x]

複素領域：

Wolfram Language code: FunctionDomain[ArcSech[z], z, Complexes]

ArcSechは，0以上のすべての実数値に達する：

Wolfram Language code: FunctionRange[ArcSech[x], x, y]

複素領域からの引数についての関数の範囲：

Wolfram Language code: FunctionRange[ArcSech[z], z, y, Complexes]

ArcSechは解析関数ではない：

Wolfram Language code: FunctionAnalytic[ArcSech[x], x]

有理型でもない：

Wolfram Language code: FunctionMeromorphic[ArcSech[x], x]

ArcSechは実数領域上で減少する：

Wolfram Language code: FunctionMonotonicity[{ArcSech[x], 0 < x ≤ 1}, x, StrictInequalities -> True]

ArcSechは単射である：

Wolfram Language code: FunctionInjective[ArcSech[x], x]
Wolfram Language code: Plot[{ArcSech[x], 1}, {x, 0, 1}]

ArcSechは全射ではない：

Wolfram Language code: FunctionSurjective[ArcSech[x], x]
Wolfram Language code: Plot[{ArcSech[x], -1}, {x, -1, 1}]

ArcSechは実数領域上で非負である：

Wolfram Language code: FunctionSign[{ArcSech[x], 0 < x ≤ 1}, x]

(-∞,0]および[1,∞)に特異点と不連続点の両方を持つ：

Wolfram Language code: FunctionSingularities[ArcSech[x], x]
Wolfram Language code: FunctionDiscontinuities[ArcSech[x], x]

ArcSechは凸でも凹でもない：

Wolfram Language code: FunctionConvexity[ArcSech[x], x]

TraditionalFormによる表示：

Wolfram Language code: ArcSech[x]//TraditionalForm

微分  (3)

一次導関数：

Wolfram Language code: D[ArcSech[x], x]

高次導関数：

Wolfram Language code: Table[D[ArcSech[x], {x, n}], {n, 1, 4}]//FullSimplify
Wolfram Language code: Plot[Evaluate[%], {x, -1, 1}, PlotLegends -> {"First Derivative", "Second Derivative", "Third Derivative", "Fourth Derivative"}]

次導関数の式：

Wolfram Language code: D[ArcSech[x], {x, n}]

積分  (3)

ArcSechの不定積分：

Wolfram Language code: Integrate[ArcSech[x], x]

ArcSechの実領域上での定積分：

Wolfram Language code: Integrate[ArcSech[x], {x, 0, 1}]

その他の積分例：

Wolfram Language code: Integrate[x ArcSech[x], x]
Wolfram Language code: Integrate[Sqrt[x] ArcSech[x], x]

級数展開  (3)

Seriesを使ってテイラー(Taylor)展開を求める：

Wolfram Language code: Series[ArcSech[x], {x, 1 / 2, 4}]

の周りでのArcSechの最初の3つの近似をプロットする：

Wolfram Language code: terms = Normal@Table[Series[ArcSech[x], {x, 1 / 2, m}], {m, 1, 3}]; Plot[{ArcSech[x], terms}, {x, 0, 1}, PlotRange -> {{0, 1}, {0, 5}}]

分岐点と分枝切断線における級数展開を求める：

Wolfram Language code: Series[ArcSech[x], {x, 1, 1}]
Wolfram Language code: Series[ArcSech[x], {x, 0, 1}]

ArcSechをベキ級数に適用する：

Wolfram Language code: ArcSech[Exp[x] / 2 + O[x] ^ 5]

関数の恒等式と簡約  (3)

ArcSechを含む式を簡約する：

Wolfram Language code: FullSimplify[(x^2y^2 - x^2 - y^2)Sech[ArcSech[x] + ArcSech[y]]^2 + 2x y Sech[ArcSech[x] + ArcSech[y]] - x^2y^2]

TrigToExpを使って対数で表す：

Wolfram Language code: ArcSech[z]//TrigToExp

変換し直す：

Wolfram Language code: ExpToTrig[%]

実変数 および を仮定して展開する：

Wolfram Language code: ComplexExpand[ArcSech[x + I y]]//FullSimplify

関数表現  (5)

ArcCoshを使って表現する：

Wolfram Language code: ArcCosh[1 / x]//FullSimplify

逆ヤコビ関数を介して表現する：

Wolfram Language code: InverseJacobiCN[z, 1]
Wolfram Language code: InverseJacobiDN[z, 1]

Hypergeometric2F1を使って表現する：

Wolfram Language code: FullSimplify[ArcSech[z] == (Sqrt[(1/z) - 1] ((π/2) - (HypergeometricPFQ[{(1/2), (1/2)}, {(3/2)}, (1/z^2)]/z))/Sqrt[1 - (1/z)])]

ArcSechはMeijerGによって表すことができる：

Wolfram Language code: MeijerGReduce[ArcSech[x], x]
Wolfram Language code: Activate[%]//FullSimplify

ArcSechはDifferentialRootとして表すことができる：

Wolfram Language code: DifferentialRootReduce[ArcSech[x], x]

アプリケーション  (2)

分枝切断線は実軸に沿っている：

Wolfram Language code: Plot3D[Im[ArcSech[x - I y]], {x, -2, 2}, {y, -2, 2}]

微分方程式を解く：

Wolfram Language code: DSolve[x y'[x] - y[x] - ArcSech[x] == 0, y[x], x]

特性と関係  (2)

逆関数で構成する：

Wolfram Language code: {ArcSech[Sech[z]], Sech[ArcSech[z]]}

PowerExpandを使ってArcSechの多価性を無視する：

Wolfram Language code: PowerExpand[%]

別の方法として，追加的な仮定を加えて評価する：

Wolfram Language code: Refine[ArcSech[Sech[z]], z∈Reals]

TrigToExpを使って対数で表す：

Wolfram Language code: ArcSech[z]//TrigToExp
Wolfram Language code: ExpToTrig[%]
Wolfram Research (1988), ArcSech, Wolfram言語関数， https://reference.wolfram.com/language/ref/ArcSech.html （2021年に更新）.

テキスト

Wolfram Research (1988), ArcSech, Wolfram言語関数， https://reference.wolfram.com/language/ref/ArcSech.html （2021年に更新）.

CMS

Wolfram Language. 1988. "ArcSech." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2021. https://reference.wolfram.com/language/ref/ArcSech.html.

APA

Wolfram Language. (1988). ArcSech. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/ArcSech.html

BibTeX

@misc{reference.wolfram_2026_arcsech, author="Wolfram Research", title="{ArcSech}", year="2021", howpublished="\url{https://reference.wolfram.com/language/ref/ArcSech.html}", note=[Accessed: 14-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_arcsech, organization={Wolfram Research}, title={ArcSech}, year={2021}, url={https://reference.wolfram.com/language/ref/ArcSech.html}, note=[Accessed: 14-August-2026]}