WOLFRAM

Wolfram 语言与系统参考资料中心

ArcSech[z]

给出复数 的反双曲正割 .

更多信息
Details and Options Details and Options
背景
范例  
基本范例  
范围  
数值计算  
特殊值  
可视化  
Show More Show More
函数的属性  
微分  
积分  
级数展开式  
函数恒等式和化简  
函数表示  
应用  
属性和关系  
参见
技术笔记
相关指南
相关链接
历史
按以下格式引用：

ArcSech

ArcSech[z]

给出复数 的反双曲正割 .

更多信息

  • 数学函数，适宜于符号和数值计算.
  • 对于某些特殊参数，ArcSech 自动计算出精确值.
  • ArcSech 可以计算到任意数值精度.
  • ArcSech 自动逐项作用于列表的各个元素.
  • ArcSech[z] 在复平面 上有分支切割，从 到 ，从 到 .
  • ArcSech 可与 Interval 和 CenteredInterval 对象一起使用. »

背景

范例

打开所有单元 关闭所有单元

基本范例  (6)

数值计算：

Wolfram Language code: ArcSech[0.5]

在实数域子集上绘图：

Wolfram Language code: Plot[ArcSech[x], {x, 0, 1}]

在复数的子集上绘图：

Wolfram Language code: ComplexPlot3D[ArcSech[z], {z, -1 - 2I, 1 + 2I}, PlotLegends -> Automatic]

在原点的级数展开：

Wolfram Language code: Series[ArcSech[z], {z, 0, 10}, Assumptions -> z > 0]

在 Infinity 处的渐近展开：

Wolfram Language code: Series[ArcSech[z], {z, ∞, 3}]

奇点处的渐近展开：

Wolfram Language code: Series[ArcSech[z], {z, 1, 3}, Assumptions -> z < 1]

范围  (40)

数值计算  (6)

数值计算：

Wolfram Language code: ArcSech[1.0 / 3.0]

高精度求值：

Wolfram Language code: N[ArcSech[1 / 3], 50]

输出精度跟踪输入精度：

Wolfram Language code: ArcSech[0.33333333333333333333333333333333333333333]

计算复变量：

Wolfram Language code: ArcSech[1.5 - I]

在高精度条件下高效计算 ArcSech：

Wolfram Language code: ArcSech[1.2`500]//Timing
Wolfram Language code: ArcSech[1.2`100000];//Timing

用 Interval 和 CenteredInterval 对象计算最坏情况下的区间：

Wolfram Language code: ArcSech[Interval[{1 / 2, 1}]]
Wolfram Language code: ArcSech[CenteredInterval[-3, 1 / 100]]
Wolfram Language code: ArcSech[CenteredInterval[2 + 3I, (1 + I) / 100]]

或使用 Around 计算一般情况下的统计区间：

Wolfram Language code: ArcSech[Around[.9, 0.1]]

计算数组中每个元素的值：

Wolfram Language code: ArcSech[{{2, 0}, {1, -2}}]

或用 MatrixFunction 以矩阵形式计算 ArcSech 函数：

Wolfram Language code: MatrixFunction[ArcSech[#]&, {{2, 0}, {1, -2}}]

特殊值  (4)

ArcSech 在固定点上的值：

Wolfram Language code: Table[ArcSech[n], {n, -2, 2}]

无穷处的值：

Wolfram Language code: ArcSech[Infinity]
Wolfram Language code: ArcSech[ComplexInfinity]

ArcSech 的零点：

Wolfram Language code: ArcSech[1]

求满足方程 的 值：

Wolfram Language code: f[x_] := ArcSech[x] - Log[2];
Wolfram Language code: sol = Solve[f[x] == 0, x]

替换为值：

Wolfram Language code: xzero = x /. First[sol]

可视化结果：

Wolfram Language code: Plot[f[x], {x, 0, 1}, Epilog -> Style[Point[{xzero, f[xzero]}], PointSize[Large], Red]]

可视化  (3)

绘制 ArcSech 函数：

Wolfram Language code: Plot[ArcSech[x], {x, 0, 1}]

绘制 的实部：

Wolfram Language code: ComplexContourPlot[Re[ArcSech[z]], {z, -3 - 3 I, 3 + 3 I}, Contours -> 24]

绘制 的虚部：

Wolfram Language code: ComplexContourPlot[Im[ArcSech[z]], {z, -3 - 3 I, 3 + 3 I}, Contours -> 24]

，绘制极坐标图：

Wolfram Language code: Table[PolarPlot[ArcSech[k ϕ], {ϕ, -π, π}, Sequence[Frame -> True, PlotLabel -> "k=" <> ToString[k], PlotRange -> {{0, 12}, {-0.7, 0.7}}, AspectRatio -> 0.8]], {k, 1, 4}]

函数的属性  (10)

ArcSech 对区间 内的实数有定义：

Wolfram Language code: FunctionDomain[ArcSech[x], x]

复定义域：

Wolfram Language code: FunctionDomain[ArcSech[z], z, Complexes]

ArcSech 的值域是大于或等于 0 的所有实数：

Wolfram Language code: FunctionRange[ArcSech[x], x, y]

参数取复定义域内的值时的值域：

Wolfram Language code: FunctionRange[ArcSech[z], z, y, Complexes]

ArcSech 不是解析函数：

Wolfram Language code: FunctionAnalytic[ArcSech[x], x]

也不是亚纯函数：

Wolfram Language code: FunctionMeromorphic[ArcSech[x], x]

ArcSech 在其实定义域上是递减的：

Wolfram Language code: FunctionMonotonicity[{ArcSech[x], 0 < x ≤ 1}, x, StrictInequalities -> True]

ArcSech 是单射函数：

Wolfram Language code: FunctionInjective[ArcSech[x], x]
Wolfram Language code: Plot[{ArcSech[x], 1}, {x, 0, 1}]

ArcSech 不是满射函数：

Wolfram Language code: FunctionSurjective[ArcSech[x], x]
Wolfram Language code: Plot[{ArcSech[x], -1}, {x, -1, 1}]

ArcSech 在其实定义域上非负：

Wolfram Language code: FunctionSign[{ArcSech[x], 0 < x ≤ 1}, x]

函数在 (-∞,0] 和 [1,∞) 内有奇点和断点：

Wolfram Language code: FunctionSingularities[ArcSech[x], x]
Wolfram Language code: FunctionDiscontinuities[ArcSech[x], x]

ArcSech 既不凸，也不凹：

Wolfram Language code: FunctionConvexity[ArcSech[x], x]

TraditionalForm 格式：

Wolfram Language code: ArcSech[x]//TraditionalForm

微分  (3)

一阶导数：

Wolfram Language code: D[ArcSech[x], x]

高阶导数：

Wolfram Language code: Table[D[ArcSech[x], {x, n}], {n, 1, 4}]//FullSimplify
Wolfram Language code: Plot[Evaluate[%], {x, -1, 1}, PlotLegends -> {"First Derivative", "Second Derivative", "Third Derivative", "Fourth Derivative"}]

阶导数的公式：

Wolfram Language code: D[ArcSech[x], {x, n}]

积分  (3)

ArcSech 的不定积分：

Wolfram Language code: Integrate[ArcSech[x], x]

ArcSech 在其实数域上的定积分：

Wolfram Language code: Integrate[ArcSech[x], {x, 0, 1}]

更多积分：

Wolfram Language code: Integrate[x ArcSech[x], x]
Wolfram Language code: Integrate[Sqrt[x] ArcSech[x], x]

级数展开式  (3)

使用 Series 求泰勒级数展开式：

Wolfram Language code: Series[ArcSech[x], {x, 1 / 2, 4}]

绘制 ArcSech 在 处的前三个近似式：

Wolfram Language code: terms = Normal@Table[Series[ArcSech[x], {x, 1 / 2, m}], {m, 1, 3}]; Plot[{ArcSech[x], terms}, {x, 0, 1}, PlotRange -> {{0, 1}, {0, 5}}]

求分支点上和分支切割的级数展开式：

Wolfram Language code: Series[ArcSech[x], {x, 1, 1}]
Wolfram Language code: Series[ArcSech[x], {x, 0, 1}]

将 ArcSech 应用于幂级数：

Wolfram Language code: ArcSech[Exp[x] / 2 + O[x] ^ 5]

函数恒等式和化简  (3)

化简含有 ArcSech 的表达式：

Wolfram Language code: FullSimplify[(x^2y^2 - x^2 - y^2)Sech[ArcSech[x] + ArcSech[y]]^2 + 2x y Sech[ArcSech[x] + ArcSech[y]] - x^2y^2]

通过 TrigToExp 用对数来表示：

Wolfram Language code: ArcSech[z]//TrigToExp

转换回来：

Wolfram Language code: ExpToTrig[%]

假定实数变量 和 的情况下进行展开：

Wolfram Language code: ComplexExpand[ArcSech[x + I y]]//FullSimplify

函数表示  (5)

使用 ArcCosh 表示：

Wolfram Language code: ArcCosh[1 / x]//FullSimplify

通过逆 Jacobi 函数表示：

Wolfram Language code: InverseJacobiCN[z, 1]
Wolfram Language code: InverseJacobiDN[z, 1]

使用 Hypergeometric2F1 表示：

Wolfram Language code: FullSimplify[ArcSech[z] == (Sqrt[(1/z) - 1] ((π/2) - (HypergeometricPFQ[{(1/2), (1/2)}, {(3/2)}, (1/z^2)]/z))/Sqrt[1 - (1/z)])]

可用 MeijerG 来表示 ArcSech：

Wolfram Language code: MeijerGReduce[ArcSech[x], x]
Wolfram Language code: Activate[%]//FullSimplify

ArcSech 可被表示为 DifferentialRoot：

Wolfram Language code: DifferentialRootReduce[ArcSech[x], x]

应用  (2)

沿实轴延伸的分支切割：

Wolfram Language code: Plot3D[Im[ArcSech[x - I y]], {x, -2, 2}, {y, -2, 2}]

解微分方程：

Wolfram Language code: DSolve[x y'[x] - y[x] - ArcSech[x] == 0, y[x], x]

属性和关系  (2)

与反函数组合：

Wolfram Language code: {ArcSech[Sech[z]], Sech[ArcSech[z]]}

利用 PowerExpand 去掉 ArcSech 的多值性：

Wolfram Language code: PowerExpand[%]

也可在其他加假设条件下计算：

Wolfram Language code: Refine[ArcSech[Sech[z]], z∈Reals]

利用 TrigToExp 通过对数表示：

Wolfram Language code: ArcSech[z]//TrigToExp
Wolfram Language code: ExpToTrig[%]
Wolfram Research (1988)，ArcSech，Wolfram 语言函数，https://reference.wolfram.com/language/ref/ArcSech.html （更新于 2021 年）.

文本

Wolfram Research (1988)，ArcSech，Wolfram 语言函数，https://reference.wolfram.com/language/ref/ArcSech.html （更新于 2021 年）.

CMS

Wolfram 语言. 1988. "ArcSech." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2021. https://reference.wolfram.com/language/ref/ArcSech.html.

APA

Wolfram 语言. (1988). ArcSech. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/ArcSech.html 年

BibTeX

@misc{reference.wolfram_2026_arcsech, author="Wolfram Research", title="{ArcSech}", year="2021", howpublished="\url{https://reference.wolfram.com/language/ref/ArcSech.html}", note=[Accessed: 11-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_arcsech, organization={Wolfram Research}, title={ArcSech}, year={2021}, url={https://reference.wolfram.com/language/ref/ArcSech.html}, note=[Accessed: 11-August-2026]}