WOLFRAM

Wolfram 语言与系统参考资料中心

ArrayFilter[f,array,r]

将 f 应用于全部范围-指定数组中的 r 块.

ArrayFilter[f,array,{r1,r2,…}]

将 f 按维度依次应用于 r1, r2, ….

ArrayFilter[f,array,template]

将 f 应用于根据在数组 template 中1的位置所指定的块.

更多信息和选项
Details and Options Details and Options
范例  
基本范例  
范围  
选项  
Padding  
应用  
属性和关系  
参见
相关指南
历史
按以下格式引用：

ArrayFilter

ArrayFilter[f,array,r]

将 f 应用于全部范围-指定数组中的 r 块.

ArrayFilter[f,array,{r1,r2,…}]

将 f 按维度依次应用于 r1, r2, ….

ArrayFilter[f,array,template]

将 f 应用于根据在数组 template 中1的位置所指定的块.

更多信息和选项

  • ArrayFilter[f,array,…] 要求 array 是一个有一定深度的完整数组.
  • ArrayFilter[f,array,r] 应用 f 于 array 中所有 个重叠块中的元素.
  • array 和 template 都可以是 SparseArray 对象.
  • 通过 ArrayFilter[f,array,template], template 的与0相应的邻域元素在传递给 f 之前被 Missing[] 替换.
  • ArrayFilter 有用来指定如何在数组边缘形成邻域的选项 Padding. 可以使用如下设置：
  • None返回一个较小的数组
    val用 val 填补
    "Fixed"重复边缘元素（默认）
    "Periodic"在各个维度都是周期的

范例

打开所有单元 关闭所有单元

基本范例  (3)

将 f 应用于一列及其范围为1的邻域中的每个元素：

Wolfram Language code: ArrayFilter[f, Range[10], 1]

将 f 应用于一列及其范围为2的邻域中的每个元素：

Wolfram Language code: ArrayFilter[f, Range[10], 2]

将 f 应用于每个元素范围为1的邻域的所有3x3的块：

Wolfram Language code: ArrayFilter[f, (| | | | | --- | --- | --- | | 1 | 2 | 3 | | 10 | 20 | 30 | | 100 | 200 | 300 |), {0, 1}]

以矩阵形式显示：

Wolfram Language code: TraditionalForm[%]

范围  (4)

用模板指定一个长度为3的块：

Wolfram Language code: ArrayFilter[fun, {a, b, c, d, e, f}, {1, 1, 1}]

用一个不考虑中心元素的模板指定长度为3的块：

Wolfram Language code: ArrayFilter[fun, {a, b, c, d, e, f}, {1, 0, 1}]

用一个只考虑左侧元素的模板指定长度为3的块：

Wolfram Language code: ArrayFilter[fun, {a, b, c, d, e, f}, {1, 0, 0}]

用 DeleteMissing 根据指定的模板移除元素：

Wolfram Language code: ArrayFilter[fun[DeleteMissing[#]]&, {a, b, c, d, e, f}, {1, 0, 0}]

选项  (6)

Padding  (6)

默认情况下，固定添加项用于边界处的邻域：

Wolfram Language code: ArrayFilter[fun, {a, b, c, d, e, f}, 1]

使用常数值填充邻域：

Wolfram Language code: ArrayFilter[fun, {a, b, c, d, e, f}, 1, Padding -> 0]

对列表进行周期填充：

Wolfram Language code: ArrayFilter[fun, {a, b, c, d, e, f}, 1, Padding -> "Periodic"]

对一个矩阵的所有维度进行周期填充：

Wolfram Language code: ArrayFilter[fun, (⁠| | | | | -- | -- | -- | | 11 | 12 | 13 | | 21 | 22 | 23 |⁠), 1, Padding -> "Periodic"]

以矩阵形式显示：

Wolfram Language code: TraditionalForm[%]

通过 Padding->None，ArrayFilter 只访问完全在数组内部的邻域：

Wolfram Language code: ArrayFilter[fun, {a, b, c, d}, 1, Padding -> None]

使用具有不同填充的填充值：

Wolfram Language code: ArrayFilter[fun, {a, b, c, d}, 1, Padding -> "Fixed"]

如果 Padding->None，则当邻域尺寸比大于输入时，返回空列表：

Wolfram Language code: ArrayFilter[fun, {a1, a2}, 1, Padding -> None]

无3x3邻域的2x2矩阵：

Wolfram Language code: ArrayFilter[fun, {{a1, a2}, {b1, b2}}, 1, Padding -> None]

具有1x3模板的2x2矩阵：

Wolfram Language code: ArrayFilter[fun, {{a1, a2}, {b1, b2}}, {{1, 0, 1}}, Padding -> None]

应用  (5)

计算连续元素差：

Wolfram Language code: ArrayFilter[Last[#] - First[#]&, {a, b, c, d, e, f}, 1]

用范围为1的邻域计算3个元素运行的移动平均数：

Wolfram Language code: ArrayFilter[Mean, {a, b, c, d, e}, 1]

计算一个矩阵中各个3x3邻域中所有值的移动中位数：

Wolfram Language code: f[neigh_] := Median[Flatten[neigh]]; ArrayFilter[f, {{1, 2, 4}, {5, 3, 1}, {1, 4, 2}, {3, 2, 0}}, 1]

计算某些数据的移动分位数：

Wolfram Language code: data = RandomFunction[WienerProcess[], {0, 10, 0.1}]["Values"];
Wolfram Language code: mq = ArrayFilter[Quantile[#, 0.75]&, data, 1];
Wolfram Language code: ListLinePlot[{data, mq}]

实现一个二维加性元胞自动机：

Wolfram Language code: ArrayPlot /@ NestList[ArrayFilter[Mod[Total[#, 2], 2]&, #, {1, 1}]&, BoxMatrix[0, {11, 11}], 5]

属性和关系  (1)

具有偶数维的模板有效地允许在开始的最大突出：

Wolfram Language code: ArrayFilter[f, {a, b, c}, {1, 1}]
Wolfram Research (2015)，ArrayFilter，Wolfram 语言函数，https://reference.wolfram.com/language/ref/ArrayFilter.html.

文本

Wolfram Research (2015)，ArrayFilter，Wolfram 语言函数，https://reference.wolfram.com/language/ref/ArrayFilter.html.

CMS

Wolfram 语言. 2015. "ArrayFilter." Wolfram 语言与系统参考资料中心. Wolfram Research. https://reference.wolfram.com/language/ref/ArrayFilter.html.

APA

Wolfram 语言. (2015). ArrayFilter. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/ArrayFilter.html 年

BibTeX

@misc{reference.wolfram_2026_arrayfilter, author="Wolfram Research", title="{ArrayFilter}", year="2015", howpublished="\url{https://reference.wolfram.com/language/ref/ArrayFilter.html}", note=[Accessed: 18-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_arrayfilter, organization={Wolfram Research}, title={ArrayFilter}, year={2015}, url={https://reference.wolfram.com/language/ref/ArrayFilter.html}, note=[Accessed: 18-August-2026]}