WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

ArrayPad[array,m]

配列のすべての側を m 個の0で充填する．

ArrayPad[array,m,padding]

指定の充填を使う．

ArrayPad[array,{m,n},…]

先頭を m 個，末尾を n 個の要素で充填する．

ArrayPad[array,{{m1,n1},{m2,n2},…},…]

array のレベル i を mi, ni要素で充填する．

詳細とオプション
Details and Options Details and Options
例題  
例  
スコープ  
一般化と拡張  
オプション  
InterpolationOrder  
アプリケーション  
特性と関係  
考えられる問題  
おもしろい例題  
関連項目
関連するガイド
履歴
引用書式

ArrayPad

ArrayPad[array,m]

配列のすべての側を m 個の0で充填する．

ArrayPad[array,m,padding]

指定の充填を使う．

ArrayPad[array,{m,n},…]

先頭を m 個，末尾を n 個の要素で充填する．

ArrayPad[array,{{m1,n1},{m2,n2},…},…]

array のレベル i を mi, ni要素で充填する．

詳細とオプション

  • 次の形式の充填が指定できる．
  • c定数 c
    {c1,c2,…}定数 c1,…の周期的繰返し
    "Extrapolated"要素の多項式外挿
    "Fixed"各境界での要素の繰返し
    "Periodic"完全配列の周期的繰返し
    "Reflected"境界での配列の反射
    "ReflectedDifferences"要素間の差の反射
    "Reversed"完全配列の逆
    "ReversedDifferences"要素間の差の逆
    "ReversedNegation"配列の逆の否定
  • 充填値"Fixed"は，各コーナーに追加される要素がもとの配列でコーナーにあった要素の複写であることを示す．
  • "Reversed"は，配列の最も外側の要素が充填の最も内側の要素として繰り返されるように指定する．"Reflected"は，要素を繰り返さないように指定する．
  • 充填値"Extrapolated"では，使用される多項式の次数がオプションInterpolationOrderで指定される．
  • ArrayPadは任意の深さの完全配列を充填する．
  • ArrayPadはSparseArrayオブジェクトに使うことができる．
  • ArrayPad[array,-m]は，array の各側から m 個の要素を除去する．

例題

すべて開く すべて閉じる

例  (6)

リストの端を0で充填する：

Wolfram Language code: ArrayPad[{1, 2, 3}, 1]

行列の端を充填する：

Wolfram Language code: ArrayPad[{{1, 2}, {3, 4}}, 2] // MatrixForm

各側に異なる充填を指定する：

Wolfram Language code: ArrayPad[{1, 2, 3}, {2, 4}]

任意の式で充填する：

Wolfram Language code: ArrayPad[{1, 2, 3}, 2, x]

名前付きの規則で充填する：

Wolfram Language code: ArrayPad[{1, 2, 3}, 2, "Fixed"]

各行を5つの要素で，各列を1つの要素で充填する：

Wolfram Language code: ArrayPad[{{1, 2}, {3, 4}}, {{1}, {5}}] // MatrixForm

スコープ  (12)

右側だけを充填する：

Wolfram Language code: ArrayPad[{1, 2, 3}, {0, 2}]

配列の各側から要素を取り除く：

Wolfram Language code: ArrayPad[Range[10], -2]

行を追加して充填する：

Wolfram Language code: ArrayPad[{{1, 2}, {3, 4}}, {{1}, {0}}] //MatrixForm

列を追加して充填する：

Wolfram Language code: ArrayPad[{{1, 2}, {3, 4}}, {{0}, {1}}] //MatrixForm

各側に異なる充填を指定する：

Wolfram Language code: ArrayPad[{{1, 2}, {3, 4}}, {{-1, 2}, {1, 3}}]//MatrixForm

配列の第1レベルだけを充填する：

Wolfram Language code: ArrayPad[{{1, 2}, {3, 4}}, {{1}}]

周期的に繰り返して充填する：

Wolfram Language code: ArrayPad[{a, b, c}, 4, "Periodic"]

リストを反転して充填する：

Wolfram Language code: ArrayPad[{a, b, c}, 4, "Reversed"]

反転の逆で充填する：

Wolfram Language code: ArrayPad[{a, b, c}, 4, "ReversedNegation"]

端で反射して充填する：

Wolfram Language code: ArrayPad[{a, b, c}, 4, "Reflected"]

端で値と反対称に充填する：

Wolfram Language code: ArrayPad[{a, b, c}, 3, "ReflectedDifferences"]
Wolfram Language code: Differences[%]

差分を逆にして配列の端で反対称に充填する：

Wolfram Language code: ArrayPad[{a, b, c}, 4, "ReversedDifferences"]

差分はもとの配列の端のところに反映される：

Wolfram Language code: Differences[%]

線形外挿を使って充填する：

Wolfram Language code: ArrayPad[{a, b, c}, 3, "Extrapolated"]

異なる次数の外挿を使って充填する：

Wolfram Language code: Table[ArrayPad[{1, 4, 9}, 4, "Extrapolated", InterpolationOrder -> o], {o, 0, 2}] //MatrixForm

最大外挿次数を使って充填する：

Wolfram Language code: ArrayPad[N[Exp[Range[0, 5]]], 5, "Extrapolated", InterpolationOrder -> ∞]

一般化と拡張  (1)

ArrayPadはSparseArrayオブジェクトに使うことができる：

Wolfram Language code: ArrayPad[SparseArray[{i_, i_} -> i, {4, 4}], {{0}, {4}}, "ReversedNegation"]
Wolfram Language code: MatrixForm[%]

オプション  (3)

InterpolationOrder  (3)

"Extrapolated"充填の補間次数を指定する：

Wolfram Language code: ArrayPad[{1, 5, 7, 8}, {0, 3}, "Extrapolated", InterpolationOrder -> 2]

デフォルトで，線形補間が使われる：

Wolfram Language code: ArrayPad[{1, 5, 7, 8}, {0, 3}, "Extrapolated"]

使用可能な最大次数，この場合は次数3を使う：

Wolfram Language code: ArrayPad[{1, 5, 7, 8}, {0, 3}, "Extrapolated", InterpolationOrder -> ∞]

アプリケーション  (1)

タイルを端で反射させてレイアウトする：

Wolfram Language code: ArrayPlot[ArrayPad[IdentityMatrix[4], 8, "Reflected"]]

特性と関係  (2)

PadLeft[list,n]とPadRight[list,n]は充填で長さ n のリストにする：

Wolfram Language code: PadLeft[{1, 2, 3}, 5]
Wolfram Language code: PadRight[{1, 2, 3}, 5]

ArrayPad[list,n]は n 個の追加要素を各側に充填する：

Wolfram Language code: ArrayPad[{1, 2, 3}, 5]

ArrayPad[list,{-n,0}]は一次元のリストにとっては事実上Drop[list,n]である：

Wolfram Language code: {ArrayPad[{1, 2, 3, 4}, {-2, 0}], Drop[{1, 2, 3, 4}, 2]}

ArrayPad[list,{0,-n}]は事実上Drop[list,-n]である：

Wolfram Language code: {ArrayPad[{1, 2, 3, 4}, {0, -2}], Drop[{1, 2, 3, 4}, -2]}

考えられる問題  (2)

単一の数あるいは数のペアは各次元で適用されるように解釈される：

Wolfram Language code: ArrayPad[{{1, 2, 4}}, {1, 2}, "ReflectedDifferences"]

各次元での充填量を明示的に指定する：

Wolfram Language code: ArrayPad[{{1, 2, 4}}, {{0, 0}, {1, 2}}, "ReflectedDifferences"]

通常，空の配列次元も充填される：

Wolfram Language code: ArrayPad[{{}, {}}, 1, x]

配列の値に依存する充填のタイプでは，非空の配列次元のみが充填される：

Wolfram Language code: ArrayPad[{{}, {}}, 1, "Fixed"]

おもしろい例題  (1)

異なる名前の充填規則を可視化する：

Wolfram Language code: a = KroneckerProduct[Sqrt[Range[6]], Sqrt[Range[6]]];
Wolfram Language code: MatrixPlot[a]
Wolfram Language code: Table[MatrixPlot[ArrayPad[a, 4, p], Epilog -> {EdgeForm[{Thick, Red}], Transparent, Rectangle[{4, 4}, {10, 10}]}, FrameTicks -> None, PlotLabel -> p], {p, {"Fixed", "Extrapolated", "Periodic", "Reflected", "ReflectedDifferences", "Reversed", "ReversedDifferences", "ReversedNegation"}}]
Wolfram Language code: Table[MatrixPlot[ArrayPad[a, 12, p], Epilog -> {EdgeForm[{Thick, Red}], Transparent, Rectangle[{12, 12}, {18, 18}]}, FrameTicks -> None, PlotLabel -> p], {p, {"Fixed", "Extrapolated", "Periodic", "Reflected", "ReflectedDifferences", "Reversed", "ReversedDifferences", "ReversedNegation"}}]
Wolfram Research (2008), ArrayPad, Wolfram言語関数， https://reference.wolfram.com/language/ref/ArrayPad.html.

テキスト

Wolfram Research (2008), ArrayPad, Wolfram言語関数， https://reference.wolfram.com/language/ref/ArrayPad.html.

CMS

Wolfram Language. 2008. "ArrayPad." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/ArrayPad.html.

APA

Wolfram Language. (2008). ArrayPad. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/ArrayPad.html

BibTeX

@misc{reference.wolfram_2026_arraypad, author="Wolfram Research", title="{ArrayPad}", year="2008", howpublished="\url{https://reference.wolfram.com/language/ref/ArrayPad.html}", note=[Accessed: 13-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_arraypad, organization={Wolfram Research}, title={ArrayPad}, year={2008}, url={https://reference.wolfram.com/language/ref/ArrayPad.html}, note=[Accessed: 13-August-2026]}