WOLFRAM

Wolfram 语言与系统参考资料中心

ArrayPad[array,m]

给出在每侧填充了 m 个零的数组.

ArrayPad[array,m,padding]

用指定的填充.

ArrayPad[array,{m,n},…]

在开始用 m 个元素填充，在末端用 n 个元素填充.

ArrayPad[array,{{m1,n1},{m2,n2},…},…]

在 array 中的层 i 填充元素 mi，ni.

更多信息和选项
Details and Options Details and Options
范例  
基本范例  
范围  
推广和延伸  
选项  
InterpolationOrder  
应用  
属性和关系  
可能存在的问题  
巧妙范例  
参见
相关指南
历史
按以下格式引用：

ArrayPad

ArrayPad[array,m]

给出在每侧填充了 m 个零的数组.

ArrayPad[array,m,padding]

用指定的填充.

ArrayPad[array,{m,n},…]

在开始用 m 个元素填充，在末端用 n 个元素填充.

ArrayPad[array,{{m1,n1},{m2,n2},…},…]

在 array 中的层 i 填充元素 mi，ni.

更多信息和选项

  • 可以指定下列形式的填充：
  • c常数 c
    {c1,c2,…}循环重复常数 c1,…
    "Extrapolated"元素的多项式外推法
    "Fixed"每边重复元素
    "Periodic"完全数组的循环重复
    "Reflected"边界上数组的映射
    "ReflectedDifferences"元素间差别的映射
    "Reversed"完全数组的逆
    "ReversedDifferences"元素间差别的逆
    "ReversedNegation"数组的否定逆
  • 填充值 "Fixed" 指明在每个角增加的元素是原数组的各个角元素的复制.
  • "Reversed" 表示数组中最外层元素应作为填充的最内层元素进行重复. "Reflected" 指定这些元素不需要重复.
  • 填充值为 "Extrapolated" 时，多项式的次数通过选项 InterpolationOrder 指定.
  • ArrayPad 可以填充任意深度的完全数组.
  • ArrayPad 对 SparseArray 对象起作用.
  • ArrayPad[array,-m] 从 array 的每边删除 m 个元素.

范例

打开所有单元 关闭所有单元

基本范例  (6)

用 0 填充一个列表的两边：

Wolfram Language code: ArrayPad[{1, 2, 3}, 1]

填充一个矩阵的四个边：

Wolfram Language code: ArrayPad[{{1, 2}, {3, 4}}, 2] // MatrixForm

每边指定不同的填充：

Wolfram Language code: ArrayPad[{1, 2, 3}, {2, 4}]

用任何表达式来填充：

Wolfram Language code: ArrayPad[{1, 2, 3}, 2, x]

按已命名规则填充：

Wolfram Language code: ArrayPad[{1, 2, 3}, 2, "Fixed"]

在每一行填充 5 个元素，每一列填充 1 个元素：

Wolfram Language code: ArrayPad[{{1, 2}, {3, 4}}, {{1}, {5}}] // MatrixForm

范围  (12)

仅在右边填充：

Wolfram Language code: ArrayPad[{1, 2, 3}, {0, 2}]

删除数组每边的元素：

Wolfram Language code: ArrayPad[Range[10], -2]

用特定的行来填充：

Wolfram Language code: ArrayPad[{{1, 2}, {3, 4}}, {{1}, {0}}] //MatrixForm

用特定的列来填充：

Wolfram Language code: ArrayPad[{{1, 2}, {3, 4}}, {{0}, {1}}] //MatrixForm

每边指定不同的填充：

Wolfram Language code: ArrayPad[{{1, 2}, {3, 4}}, {{-1, 2}, {1, 3}}]//MatrixForm

仅填充数组的第一层：

Wolfram Language code: ArrayPad[{{1, 2}, {3, 4}}, {{1}}]

周期式重复填充：

Wolfram Language code: ArrayPad[{a, b, c}, 4, "Periodic"]

用列表反向填充：

Wolfram Language code: ArrayPad[{a, b, c}, 4, "Reversed"]

用负的反向列表来填充：

Wolfram Language code: ArrayPad[{a, b, c}, 4, "ReversedNegation"]

映射边的方式来填充：

Wolfram Language code: ArrayPad[{a, b, c}, 4, "Reflected"]

反对称填充边：

Wolfram Language code: ArrayPad[{a, b, c}, 3, "ReflectedDifferences"]
Wolfram Language code: Differences[%]

用逆差来反对称填充数组的边：

Wolfram Language code: ArrayPad[{a, b, c}, 4, "ReversedDifferences"]

差反映原数组的边：

Wolfram Language code: Differences[%]

用线性外推法填充：

Wolfram Language code: ArrayPad[{a, b, c}, 3, "Extrapolated"]

用不同次数的外推法填充：

Wolfram Language code: Table[ArrayPad[{1, 4, 9}, 4, "Extrapolated", InterpolationOrder -> o], {o, 0, 2}] //MatrixForm

用最大的外推次数填充：

Wolfram Language code: ArrayPad[N[Exp[Range[0, 5]]], 5, "Extrapolated", InterpolationOrder -> ∞]

推广和延伸  (1)

ArrayPad 对 SparseArray 对象起作用：

Wolfram Language code: ArrayPad[SparseArray[{i_, i_} -> i, {4, 4}], {{0}, {4}}, "ReversedNegation"]
Wolfram Language code: MatrixForm[%]

选项  (3)

InterpolationOrder  (3)

对 "Extrapolated" 填充指定插值次数：

Wolfram Language code: ArrayPad[{1, 5, 7, 8}, {0, 3}, "Extrapolated", InterpolationOrder -> 2]

缺省下使用线性插值：

Wolfram Language code: ArrayPad[{1, 5, 7, 8}, {0, 3}, "Extrapolated"]

使用最大的可能次数，这里次数为3：

Wolfram Language code: ArrayPad[{1, 5, 7, 8}, {0, 3}, "Extrapolated", InterpolationOrder -> ∞]

应用  (1)

通过映射瓷砖的边来排列：

Wolfram Language code: ArrayPlot[ArrayPad[IdentityMatrix[4], 8, "Reflected"]]

属性和关系  (2)

PadLeft[list,n] 和 PadRight[list,n] 填充为长度 n 的一个列表：

Wolfram Language code: PadLeft[{1, 2, 3}, 5]
Wolfram Language code: PadRight[{1, 2, 3}, 5]

ArrayPad[list,n] 在每边填充 n 个其它元素：

Wolfram Language code: ArrayPad[{1, 2, 3}, 5]

对一维列表，ArrayPad[list,{-n,0}] 实际上是 Drop[list,n]：

Wolfram Language code: {ArrayPad[{1, 2, 3, 4}, {-2, 0}], Drop[{1, 2, 3, 4}, 2]}

ArrayPad[list,{0,-n}] 实际上是 Drop[list,-n]：

Wolfram Language code: {ArrayPad[{1, 2, 3, 4}, {0, -2}], Drop[{1, 2, 3, 4}, -2]}

可能存在的问题  (2)

单个数或数对可以解释应用到每个维中：

Wolfram Language code: ArrayPad[{{1, 2, 4}}, {1, 2}, "ReflectedDifferences"]

明确指定每一维填充的数量：

Wolfram Language code: ArrayPad[{{1, 2, 4}}, {{0, 0}, {1, 2}}, "ReflectedDifferences"]

通常情况下，甚至能填充维空数组：

Wolfram Language code: ArrayPad[{{}, {}}, 1, x]

在填充类型取决于数组值时，仅填充非空数组维：

Wolfram Language code: ArrayPad[{{}, {}}, 1, "Fixed"]

巧妙范例  (1)

显示不同的已命名填充规则：

Wolfram Language code: a = KroneckerProduct[Sqrt[Range[6]], Sqrt[Range[6]]];
Wolfram Language code: MatrixPlot[a]
Wolfram Language code: Table[MatrixPlot[ArrayPad[a, 4, p], Epilog -> {EdgeForm[{Thick, Red}], Transparent, Rectangle[{4, 4}, {10, 10}]}, FrameTicks -> None, PlotLabel -> p], {p, {"Fixed", "Extrapolated", "Periodic", "Reflected", "ReflectedDifferences", "Reversed", "ReversedDifferences", "ReversedNegation"}}]
Wolfram Language code: Table[MatrixPlot[ArrayPad[a, 12, p], Epilog -> {EdgeForm[{Thick, Red}], Transparent, Rectangle[{12, 12}, {18, 18}]}, FrameTicks -> None, PlotLabel -> p], {p, {"Fixed", "Extrapolated", "Periodic", "Reflected", "ReflectedDifferences", "Reversed", "ReversedDifferences", "ReversedNegation"}}]
Wolfram Research (2008)，ArrayPad，Wolfram 语言函数，https://reference.wolfram.com/language/ref/ArrayPad.html.

文本

Wolfram Research (2008)，ArrayPad，Wolfram 语言函数，https://reference.wolfram.com/language/ref/ArrayPad.html.

CMS

Wolfram 语言. 2008. "ArrayPad." Wolfram 语言与系统参考资料中心. Wolfram Research. https://reference.wolfram.com/language/ref/ArrayPad.html.

APA

Wolfram 语言. (2008). ArrayPad. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/ArrayPad.html 年

BibTeX

@misc{reference.wolfram_2026_arraypad, author="Wolfram Research", title="{ArrayPad}", year="2008", howpublished="\url{https://reference.wolfram.com/language/ref/ArrayPad.html}", note=[Accessed: 10-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_arraypad, organization={Wolfram Research}, title={ArrayPad}, year={2008}, url={https://reference.wolfram.com/language/ref/ArrayPad.html}, note=[Accessed: 10-August-2026]}