WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

ArrayResample[array,{n1,n2,…}]

次元{n1,n2,…}を持つように，array のリサンプリングを行う．

ArrayResample[array,dspec]

次元指定 dspec に従って，array のリサンプリングを行う．

ArrayResample[array,dspec,scheme]

リサンプリングの scheme を点ベースかビンベースに指定する．

ArrayResample[array,dspec,scheme,{{xmin,xmax},…}]

指定された部分範囲{{xmin,xmax},…}にあるデータのみのリサンプリングを行う．

詳細とオプション
Details and Options Details and Options
例題  
例  
スコープ  
基本的な用法  
出力次元  
サンプリングスキーム  
オプション  
Antialiasing  
DataRange  
Padding  
Resampling  
アプリケーション  
特性と関係  
考えられる問題  
関連項目
テクニカルノート
関連するガイド
履歴
引用書式

ArrayResample

ArrayResample[array,{n1,n2,…}]

次元{n1,n2,…}を持つように，array のリサンプリングを行う．

ArrayResample[array,dspec]

次元指定 dspec に従って，array のリサンプリングを行う．

ArrayResample[array,dspec,scheme]

リサンプリングの scheme を点ベースかビンベースに指定する．

ArrayResample[array,dspec,scheme,{{xmin,xmax},…}]

指定された部分範囲{{xmin,xmax},…}にあるデータのみのリサンプリングを行う．

詳細とオプション

  • ArrayResampleを使うと，数多くの補間と近似のモデルに基づいたデータ配列のリサンプリングを行うことができる．
  • ArrayResampleは，任意の深さのデータ配列に使える．
  • 次元指定 dspec には以下の形が使える．
  • nn 個のサンプル
    Scaled[s]因数 s でサンプリング解像度を再スケールする
    All次元を保つ
    Automatic次元の割合を保つ
    {dspec1,…,dspeck} 次元までリサンプリングを行う
  • 多次元の配列については，表記 n が{n,Automatic,…}に等しく，{n}が{n,All,…}に等しいとみなされる．
  • 次元の配列の次元比は，であるとされる．
  • scheme は，サンプルとリサンプルの位置を決定し，以下の形式を取ることができる．
  • "Point"点のサンプリング（デフォルト）
    "Bin"ビンのサンプリング
    {"Bin",alignment}指定の alignment でのビンのサンプリング
  • 長さ n の入力データについて，"Point"のリサンプリングスキームは，データが1から n までの範囲にあると想定し，"Bin"のスキームはデータが0から n の範囲にあり，各ビン内のサンプルの位置を示すように並べられると想定する．
  • ビンの整列 alignment は，Left，Center，Right，あるいは (Left) と 1 (Right)の間の数である．
  • データ範囲は，DataRangeオプションを使って変更できる．
  • デフォルトで，データは，"Point"スキームでは1から ，"Bin"スキームでは0から までのデータ領域全体についてリサンプルされる．DataRangeオプションを使ってデータ領域の座標を変更する．
  • DataRangeについて指定された部分領域{{xmin,xmax},…}では，指定された区間のデータ値だけがリサンプルされる． »
  • 使用できるオプション
  • Antialiasing Falseダウンサンプリングの際にアンチエイリアシングを適用する
    DataRange Automatic入力データの範囲
    Padding "Fixed"充填方法
    Resampling Automaticリサンプリングの方法
  • Paddingの可能な設定については，ArrayPadのページを参照のこと．

例題

すべて開く すべて閉じる

例  (2)

配列のサブサンプリングを行う：

Wolfram Language code: ArrayResample[{1, 2, 3, 4, 5}, 9]

配列のダウンサンプリングを行う：

Wolfram Language code: ArrayResample[{1, 2, 3, 4, 5}, 3]

2Dデータ配列のサイズを変更する：

Wolfram Language code: ArrayResample[(⁠| | | | | - | - | - | | 1 | 2 | 3 | | 2 | 3 | 4 | | 3 | 4 | 5 |⁠), 6]//MatrixForm

スコープ  (8)

基本的な用法  (4)

厳密な計算：

Wolfram Language code: ArrayResample[{1, 2, 3}, 4]

入力精度は保たれる：

Wolfram Language code: ArrayResample[{1.0000000000000000000, 2.0000000000000000000, 3.0000000000000000000, 4.0000000000000000000}, 6]

記号配列の大きさを変更する：

Wolfram Language code: ArrayResample[{a, b, c}, 5]

入力信号の部分領域のリサンプリングを行う：

Wolfram Language code: input = Range[100];
Wolfram Language code: ArrayResample[input, 20, "Point", {55, 63}]

出力次元  (1)

スカラーとして指定されたサイズで，出力次元は，次元比が保たれるように選ばれる：

Wolfram Language code: ArrayResample[(⁠| | | | | - | - | - | | 1 | 2 | 3 | | 4 | 5 | 6 |⁠), 4]//MatrixForm
Wolfram Language code: Dimensions[%]

サンプリングスキーム  (3)

デフォルトで，"Point"のサンプリングスキームが使われる：

Wolfram Language code: ArrayResample[{1, 2, 3}, 7, "Point"]

中央揃えをデフォルトで使う"Bin"スキームを使う：

Wolfram Language code: ArrayResample[{1, 2, 3}, 6, "Bin"]

ビンの並べ方を指定する：

Wolfram Language code: ArrayResample[{1, 2, 3}, 6, {"Bin", -1}]

入力の3倍の解像度で"Point"リサンプリングを生成する：

Wolfram Language code: input = {2, 1, 3, 4, 2, 5}; m = Length[input]; s = 3; res1 = ArrayResample[input, Scaled[s]]

サンプリングの位置を計算する：

Wolfram Language code: pos = Range[1, m, (m - 1) / Round[s (m - 1)]]
Wolfram Language code: ListPlot[{Thread[{Range[m], input}], Thread[{pos, res1}]}, Joined -> {True, False}, PlotStyle -> {PointSize[.04], Automatic}, Mesh -> All]

オプション  (5)

Antialiasing  (1)

ダウンサンプリングするときは，デフォルトで，アンチエイリアス処理は行われない：

Wolfram Language code: data = {2, 1, 2, 1, 2, 1, 2};
Wolfram Language code: ArrayResample[data, Scaled[1 / 2], Padding -> "Reflected"]

アンチエイリアス処理が行われる場合は，新たなサンプル間のすべてのサンプルが平均される：

Wolfram Language code: ArrayResample[data, Scaled[1 / 2], Padding -> "Reflected", Antialiasing -> True]

DataRange  (1)

DataRangeはリサンプリング領域を指定する．部分領域指定はこの領域について定義される：

Wolfram Language code: data = {0, 2, 0, 1, 4, 1, 9, 4, 4};

データ全体のリサンプリングを行う：

Wolfram Language code: ArrayResample[data, Scaled[2], "Point"]

デフォルトのDataRange->{1,n}を使って前半分をリサンプルする．n は data の長さである：

Wolfram Language code: ArrayResample[data, Scaled[2], "Point", {1, 5}]

{0,1}データ範囲を使ってデータの前半分をリサンプルする：

Wolfram Language code: ArrayResample[data, Scaled[2], "Point", {0, 1 / 2}, DataRange -> {0, 1}]

Padding  (2)

デフォルトの充填の値は，"Fixed"である：

Wolfram Language code: ArrayResample[{1, 2, 3}, 9, "Bin"]

別の充填を指定する：

Wolfram Language code: ArrayResample[{1, 2, 3}, 9, "Bin", Padding -> 0]

デフォルトで，すべての次元に同じ充填が使われる：

Wolfram Language code: ArrayResample[(⁠| | | | | - | - | - | | 1 | 2 | 3 | | 2 | 1 | 6 | | 3 | 6 | 2 |⁠), 5, Resampling -> "Cubic", Padding -> 0]//N//MatrixForm

次元によって異なる充填を使う：

Wolfram Language code: ArrayResample[(⁠| | | | | - | - | - | | 1 | 2 | 3 | | 2 | 1 | 6 | | 3 | 6 | 2 |⁠), 5, Resampling -> "Cubic", Padding -> {0, "Fixed"}]//N//MatrixForm

Resampling  (1)

デフォルトで"Linear"のリサンプリングが使われる：

Wolfram Language code: ArrayResample[{1, 2, 3}, 6]

別のリサンプリングスキームを使う：

Wolfram Language code: ArrayResample[{1, 2, 3}, 6, Resampling -> "Nearest"]

"Nearest"のリサンプリングは，サンプリングの位置がサンプル間の半ばにある場合には，サンプルの平均を取る：

Wolfram Language code: ArrayResample[{1, 2, 3}, 5, Resampling -> "Nearest"]

半整数のサンプリング位置について，左へのバイアスあるいは右へのバイアスにそれぞれ"NearestLeft"と"NearestRight"を使う：

Wolfram Language code: ArrayResample[{1, 2, 3}, 5, Resampling -> "NearestLeft"]

アプリケーション  (1)

可視化速度を上げるためにデータ集合のサイズを小さくする：

Wolfram Language code: data = Import["http://exampledata.wolfram.com/hailey.dem.gz", "Data"];
Wolfram Language code: (data2 = ArrayResample[N@data, Scaled[1 / 5]])//ReliefPlot
Wolfram Language code: AbsoluteTiming[ReliefPlot[#];][[1]]& /@ {data, data2}

特性と関係  (2)

異なるいくつかのカーネルについて配列のリサンプリングを比較する：

Wolfram Language code: a = {1, 3, 1, 2}; n = 25; xpos = Array[#&, n, {1, Length[a]}]; Table[ result = ArrayResample[a, n, Resampling -> ker]; ListPlot[Transpose[{xpos, result}], PlotStyle -> PointSize[Medium], Epilog -> {Red, Line[Transpose[{Range[Length[a]], a}]]}, Axes -> {True, False}, PlotLabel -> ker], {ker, {"Linear", "Cubic", "German"}}]

Downsampleを使って整数因子分ダウンサンプリングすることができる：

Wolfram Language code: Downsample[Range[9], 2]
Wolfram Language code: ArrayResample[Range[9], Scaled[1 / 2]]

考えられる問題  (1)

厳密計算は整数データで行われる：

Wolfram Language code: input = Range[100];
Wolfram Language code: AbsoluteTiming[ArrayResample[input, 1000, Resampling -> "Cubic"];]

Nを整数データに適用して検索速度を上げる：

Wolfram Language code: AbsoluteTiming[ArrayResample[N@input, 1000, Resampling -> "Cubic"];]
Wolfram Research (2014), ArrayResample, Wolfram言語関数， https://reference.wolfram.com/language/ref/ArrayResample.html （2016年に更新）.

テキスト

Wolfram Research (2014), ArrayResample, Wolfram言語関数， https://reference.wolfram.com/language/ref/ArrayResample.html （2016年に更新）.

CMS

Wolfram Language. 2014. "ArrayResample." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2016. https://reference.wolfram.com/language/ref/ArrayResample.html.

APA

Wolfram Language. (2014). ArrayResample. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/ArrayResample.html

BibTeX

@misc{reference.wolfram_2026_arrayresample, author="Wolfram Research", title="{ArrayResample}", year="2016", howpublished="\url{https://reference.wolfram.com/language/ref/ArrayResample.html}", note=[Accessed: 13-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_arrayresample, organization={Wolfram Research}, title={ArrayResample}, year={2016}, url={https://reference.wolfram.com/language/ref/ArrayResample.html}, note=[Accessed: 13-September-2026]}