WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

ArrayRules[SparseArray[…]]

疎な配列にある要素を指定する規則{pos1val1,pos2val2,…}を与える．

ArrayRules[list]

SparseArray[list]の規則を与える．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
アプリケーション  
特性と関係  
関連項目
テクニカルノート
関連するガイド
履歴
引用書式

ArrayRules

ArrayRules[SparseArray[…]]

疎な配列にある要素を指定する規則{pos1val1,pos2val2,…}を与える．

ArrayRules[list]

SparseArray[list]の規則を与える．

詳細

  • ArrayRules[s]の最後の要素は常に{_,_,…}->def である．ただし，def は疎な配列にある指定されていない要素のデフォルト値であるとする． »
  • ArrayRules[list,val]は val というデフォルト値を取る． »
  • ArrayRules[list]はデフォルト値が0であると推定する． »

例題

すべて開く すべて閉じる

例  (1)

SparseArray中の明示的な要素を得る：

Wolfram Language code: s = SparseArray[{{i_, j_} /; Abs[i - j] ≤ 1 -> -2 + 3Abs[i - j]}, {5, 5}]
Wolfram Language code: ar = ArrayRules[s]

これらの規則は全く同じSparseArrayを効率的に構築するのに十分である：

Wolfram Language code: s2 = SparseArray[ar]
Wolfram Language code: s === s2

スコープ  (2)

ArrayRules[s]の最終要素は常に{_,_,…}->def である：

Wolfram Language code: m = RandomInteger[2, {3, 3}]

デフォルト値が2のSparseArray：

Wolfram Language code: s2 = SparseArray[m, Automatic, 2]
Wolfram Language code: ar2 = ArrayRules[s2]

使用したいデフォルト値を明示的に指定することでこれを無効にすることができる：

Wolfram Language code: ar1 = ArrayRules[s2, 1]

次はSparseArray[m,Automatic,1]と全く等しいSparseArrayを構築する：

Wolfram Language code: SparseArray[ar1, {3, 3}] === SparseArray[m, Automatic, 1]

デフォルトが0と思われる明示的な配列中の1の位置：

Wolfram Language code: a = RandomInteger[1, {2, 2, 2}]
Wolfram Language code: ArrayRules[a]

次は，SparseArray[a]と全く等しいSparseArrayを構築する：

Wolfram Language code: SparseArray[%, {2, 2, 2}] === SparseArray[a]

1がデフォルトであるときの0の位置：

Wolfram Language code: ArrayRules[a, 1]

次は，SparseArray[a,Automatic,1]と全く等しいSparseArrayを構築する：

Wolfram Language code: SparseArray[%, {2, 2, 2}] === SparseArray[a, Automatic, 1]

アプリケーション  (4)

SparseArray中の明示的な要素の数を得る：

Wolfram Language code: s = SparseArray[RandomChoice[{100, 1} -> {0, 1}, 1000]]
Wolfram Language code: Length[ArrayRules[s]] - 1

条件を満足する疎な配列中の明示的な要素を得る：

Wolfram Language code: SeedRandom[1234];s = SparseArray[RandomInteger[{1, 9}, {19, 2}] -> RandomInteger[{-9, 9}, 19], {9, 9}]

CasesはRuleに関して特別な動作をするので，より複雑なパターンが必要になる点に注意：

Wolfram Language code: Cases[ArrayRules[s], (r : (_ -> x_ /; Positive[x])) -> r]

正の値と負の値を持つSparseArrayオブジェクト：

Wolfram Language code: spos = SparseArray[%, Dimensions[s]]
Wolfram Language code: sneg = SparseArray[Cases[ArrayRules[s], (r : (_ -> x_ /; Negative[x])) -> r], Dimensions[s]]

疎行列の上三角と下三角の部分を得る：

Wolfram Language code: s = SparseArray[{{1, -2, 1, 0, 0}, {0, 1, -2, 1, 0}, {0, 0, 1, -2, 1}, {0, 0, 0, 1, -2}, {-2, -3, -4, -5, -6}}]
Wolfram Language code: upperrules = Cases[ArrayRules[s], (r : ({i_, j_} /; i ≤ j -> _)) -> r]
Wolfram Language code: u = SparseArray[upperrules, Dimensions[s]]

対角線上に1を持つ下三角の部分：

Wolfram Language code: lowerrules = Cases[ArrayRules[s], (r : ({i_, j_} /; i > j -> _)) -> r]; l = SparseArray[Append[lowerrules, {i_, i_} -> 1], Dimensions[s]]

これは，偶然にも三重対角行列のLU分解である：

Wolfram Language code: MatrixForm[(l.u)[[{5, 1, 2, 3, 4}]]]

SparseArrayの明示的な要素の位置をツールチップで示したプロットを作る：

Wolfram Language code: s = SparseArray[{{i_, i_} -> 1 / i, {i_, j_} /; Mod[i + 2 j, 4] == 0 -> 1 / (i + j)}, {10, 10}]
Wolfram Language code: ListPlot[Apply[Tooltip, Drop[ArrayRules[s], -1], {1}], AspectRatio -> 1, PlotStyle -> PointSize[1 / 10], PlotMarkers -> {"■"}]

MatrixPlotは一般に視覚的により映えるプロットを作る：

Wolfram Language code: MatrixPlot[s]

特性と関係  (2)

SparseArray s について，SparseArray[ArrayRules[s],Dimensions[s]]は s と等価である：

Wolfram Language code: s = SparseArray[RandomInteger[{1, 9}, {5, 2}] :> RandomInteger[{-9, 9}], {10, 10}]
Wolfram Language code: ar = ArrayRules[s]
Wolfram Language code: s === SparseArray[ar, Dimensions[s]]

次元は明示的な要素から推測されるので，これを指定する必要がある：

Wolfram Language code: {Max[ar[[1 ;; -2, 1, 1]]], Max[ar[[1 ;; -2, 1, 2]]]}
Wolfram Language code: SparseArray[ar]

明示的な配列について，ArrayRulesはPositionを使って書くことができる：

Wolfram Language code: par[list_ ? ArrayQ, def_ : 0] := Module[{n = ArrayDepth[list], pos}, pos = Position[list, x_ /; x ≠ def, {n}]; Append[Thread[pos -> Extract[list, pos]], Table[_, {n}] -> def]]
Wolfram Language code: a = RandomInteger[1, {2, 3}]
Wolfram Language code: par[a]
Wolfram Language code: % === ArrayRules[a]
Wolfram Language code: par[a, 1] === ArrayRules[a, 1]

パターンマッチはFullFormについて使えるものなので，これはSparseArrayオブジェクトではうまくいかない：

Wolfram Language code: Position[SparseArray[a], x_ /; x ≠ 0, {ArrayDepth[a]}]
Wolfram Language code: FullForm[SparseArray[a]]
Wolfram Research (2003), ArrayRules, Wolfram言語関数， https://reference.wolfram.com/language/ref/ArrayRules.html.

テキスト

Wolfram Research (2003), ArrayRules, Wolfram言語関数， https://reference.wolfram.com/language/ref/ArrayRules.html.

CMS

Wolfram Language. 2003. "ArrayRules." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/ArrayRules.html.

APA

Wolfram Language. (2003). ArrayRules. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/ArrayRules.html

BibTeX

@misc{reference.wolfram_2026_arrayrules, author="Wolfram Research", title="{ArrayRules}", year="2003", howpublished="\url{https://reference.wolfram.com/language/ref/ArrayRules.html}", note=[Accessed: 07-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_arrayrules, organization={Wolfram Research}, title={ArrayRules}, year={2003}, url={https://reference.wolfram.com/language/ref/ArrayRules.html}, note=[Accessed: 07-August-2026]}