WOLFRAM

Wolfram 语言与系统参考资料中心

AstroSubpoint[astro]

返回地球上当前在天顶处具有给定 astro 的地理位置.

AstroSubpoint[astro,date]

返回地球上在给定 date 在天顶处具有 astro 的地理位置.

AstroSubpoint[astro,{body,date}]

返回在给定 date 观测到的给定 body 的天文下点.

更多信息
Details and Options Details and Options
范例  
基本范例  
范围  
应用  
属性和关系  
参见
历史
按以下格式引用：

AstroSubpoint

AstroSubpoint[astro]

返回地球上当前在天顶处具有给定 astro 的地理位置.

AstroSubpoint[astro,date]

返回地球上在给定 date 在天顶处具有 astro 的地理位置.

AstroSubpoint[astro,{body,date}]

返回在给定 date 观测到的给定 body 的天文下点.

更多信息

  • 天体的天文下点是给定天体上可以以 90 度高度观察该物体的位置.
  • 太阳的天文下点称为日下点. 月球的天文下点称为月下点.
  • 在 AstroSubpoint[astro,…] 中，astro 对象可为任意天体，如 Entity["Star","Sun"] 或 Entity["Planet","Mars"]，已命名的天文位置，如太阳系质心 "SSB"，或天体表面附近的 GeoPosition 位置.
  • 从观测的天体对象到下点的连线垂直于下点处的水平面，且通常不会穿过天体的中心除非该天体是球形的.
  • AstroSubpoint[astro,{body,date}] 返回一个地理位置，形式为 GeoPosition[{lat,lon},body].
  • 对于给定的天体 body，AstroSubpoint[astro,body] 等价于 AstroSubpoint[astro,{body,Now}].

范例

打开所有单元 关闭所有单元

基本范例  (4)

找到当前的日下点：

Wolfram Language code: AstroSubpoint[Entity["Star", "Sun"]]

计算该日期的月下点：

Wolfram Language code: AstroSubpoint[Entity["PlanetaryMoon", "Moon"], DateObject[{2000, 1, 1, 0, 0, 0}]]

找出这一天地球上哪个位置上火星正好位于其天顶处：

Wolfram Language code: date = DateObject[{2023, 15, 9, 16, 0, 0}]
Wolfram Language code: sp = AstroSubpoint[Entity["Planet", "Mars"], date]

检查当天从该位置观测到的火星地平纬度是否为 90 度：

Wolfram Language code: AstroPosition[Entity["Planet", "Mars"], {sp, date}]["Altitude"]

求以下日期火星的太阳下点：

Wolfram Language code: AstroSubpoint[Entity["Star", "Sun"], {Entity["Planet", "Mars"], DateObject[{2000, 1, 1, 0, 0, 0}]}]

范围  (3)

将 AstroSubpoint 与任意天文实体一起使用：

Wolfram Language code: AstroSubpoint[Entity["Star", "Sun"]]
Wolfram Language code: AstroSubpoint[Entity["Star", "Betelgeuse"]]

计算太阳系质心的当前下点：

Wolfram Language code: AstroSubpoint["SSB"]

计算月球表面某个位置的下点：

Wolfram Language code: date = DateObject[{2023, 5, 13, 16, 50, 4.9221}, "Instant", "Gregorian", -5.];
Wolfram Language code: AstroSubpoint[GeoPosition[{0, 0}, Entity["PlanetaryMoon", "Moon"]], date]

与月下点，即月球中心的下点相比较：

Wolfram Language code: AstroSubpoint[Entity["PlanetaryMoon", "Moon"], date]
Wolfram Language code: GeoDistance[%, %%]

应用  (1)

计算一年中每天同一时间的日下点：

Wolfram Language code: sps = Table[AstroSubpoint[Entity["Star", "Sun"], DateObject[{2023, 1, day, 12, 0, 0}]], {day, 1, 365}];

它们形成了日行迹：

Wolfram Language code: GeoGraphics[Point[sps]]

属性和关系  (5)

计算天文物体在给定日期的下点：

Wolfram Language code: date = Now
Wolfram Language code: sp = AstroSubpoint[Entity["Planet", "Neptune"], date]

那一天从该位置观察时，该物体的地平纬度将为 90 度：

Wolfram Language code: AstroPosition[Entity["Planet", "Neptune"], {sp, date}]

北极星的下点靠近北极：

Wolfram Language code: AstroSubpoint[Entity["Star", "Polaris"], DateObject[{2023, 9, 22}]]

对于给定日期，计算天体的赤道坐标和下点：

Wolfram Language code: date = Now;
Wolfram Language code: ap = AstroPosition[Entity["Star", "Antares"], {"Equatorial", date}]
Wolfram Language code: gp = AstroSubpoint[Entity["Star", "Antares"], date]

天体的赤纬与其下点的纬度一致：

Wolfram Language code: {ap["Declination"], gp["Latitude"]}

天体的赤经与其下点的经度并不重合：

Wolfram Language code: {ap["RightAscension"], gp["Longitude"]}

差异由格林威治恒星时给出：

Wolfram Language code: {Subtract@@%, QuantityMagnitude[SiderealTime[GeoPosition[{0, 0}], date], "AngularDegrees"]}

太阳下点的纬度范围定义了北回归线和南回归线：

Wolfram Language code: Plot[Latitude[AstroSubpoint[Entity["Star", "Sun"], DateObject[{2023, 1, d, 0, 0, 0}]]], {d, 1, 365}]

计算给定日期的日下点：

Wolfram Language code: date = RandomDate[]
Wolfram Language code: ssp = AstroSubpoint[Entity["Star", "Sun"], date]

该位置上那一刻的太阳时始终是中午：

Wolfram Language code: SolarTime[ssp, date]
Wolfram Research (2024)，AstroSubpoint，Wolfram 语言函数，https://reference.wolfram.com/language/ref/AstroSubpoint.html （更新于 2026 年）.

文本

Wolfram Research (2024)，AstroSubpoint，Wolfram 语言函数，https://reference.wolfram.com/language/ref/AstroSubpoint.html （更新于 2026 年）.

CMS

Wolfram 语言. 2024. "AstroSubpoint." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2026. https://reference.wolfram.com/language/ref/AstroSubpoint.html.

APA

Wolfram 语言. (2024). AstroSubpoint. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/AstroSubpoint.html 年

BibTeX

@misc{reference.wolfram_2026_astrosubpoint, author="Wolfram Research", title="{AstroSubpoint}", year="2026", howpublished="\url{https://reference.wolfram.com/language/ref/AstroSubpoint.html}", note=[Accessed: 16-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_astrosubpoint, organization={Wolfram Research}, title={AstroSubpoint}, year={2026}, url={https://reference.wolfram.com/language/ref/AstroSubpoint.html}, note=[Accessed: 16-August-2026]}