Wolfram 语言与系统参考资料中心

AsymptoticEqual

AsymptoticEqual[f,g,xx^*]

给出当 xx^* 时或的条件.

AsymptoticEqual[f,g,{x₁,…,x_n}{,…,}]

给出当 {x₁,…,x_n}{,…,} 时或的条件.

范例

打开所有单元关闭所有单元

基本范例 (2)

验证当时，：

Wolfram Language code: AsymptoticEqual[x ^ 2 + x Sin[x], 2x ^ 2 + 5, x -> ∞]

前者可以“夹在”后者的两个固定倍数之间：

Wolfram Language code: Plot[{x ^ 2 + x Sin[x], 2x ^ 2 + 5, 1 / 10(2x ^ 2 + 5)}, {x, 0, 10}, PlotTheme -> {"Detailed", "DashedLines"}]

验证当时，：

Wolfram Language code: AsymptoticEqual[x ^ 2 + 3y ^ 2, 2x ^ 2 + 6y ^ 2 + x, {x, y} -> ∞]

前者可以“夹在”后者的两个固定倍数之间：

Wolfram Language code:

Plot3D[{x ^ 2  + 3y ^ 2, 2x ^ 2 + 6y ^ 2 + x, 1 / 3(2x ^ 2 + 6y ^ 2 + x)}, {x, 0, 10}, {y, 0, 10}, PlotLegends -> "Expressions"]

范围 (9)

比较不是严格为正 (positive) 的函数:

Wolfram Language code: AsymptoticEqual[x, -x ^ 2, x -> ∞]

显示在原点处发散的速度与相同：

Wolfram Language code: AsymptoticEqual[(1/x^2), (1/x Sin[x]), x -> 0]

答案可能是布尔表达式，而不是明确的 True 或 False：

Wolfram Language code: AsymptoticEqual[Sinh[p(x - 2)], Sin[x - 2], x -> 2]

当比较有参数的函数时，可能会针对结果给出条件：

Wolfram Language code: AsymptoticEqual[(1/(x - 1)^p), (10/x - 1), x -> 1]

缺省情况下，在两个方向上对函数进行比较：

Wolfram Language code: AsymptoticEqual[x^4, x^2(1 - Cos[x]) UnitStep[x], x -> 0]

当比较较大的值时，与 $x^2(1-cos(x)) TemplateBox[{{x}}, UnitStepSeq]$ 减小的速率相同：

Wolfram Language code: AsymptoticEqual[x^4, x^2(1 - Cos[x]) UnitStep[x], x -> 0, Direction -> "FromAbove"]

但对于较小的值，这种关系不再成立：

Wolfram Language code: AsymptoticEqual[x^4, x^2(1 - Cos[x]) UnitStep[x], x -> 0, Direction -> "FromBelow"]

可视化两个函数的比值，显示它从上面趋近于非零极限：

Wolfram Language code: Plot[(x^2(1 - Cos[x]) UnitStep[x]/x^4), {x, -1, 1}, PlotTheme -> {"DashedLines", "Detailed"}]

像 Sqrt 这样的函数可能在负实数的两个实数方向上具有相同的关系：

Wolfram Language code: AsymptoticEqual[(Sqrt[z] - I)^3, (z + 1)^3, z -> -1]

如果从复平面的上方接近，可以看到同样的关系：

Wolfram Language code: AsymptoticEqual[(Sqrt[z] - I)^3, (z + 1)^3, z -> -1, Direction -> -I]

然而，如果从复平面的下方接近会得到不同的结果：

Wolfram Language code: AsymptoticEqual[(Sqrt[z] - I)^3, (z + 1)^3, z -> -1, Direction -> I]

这是由于在与坐标轴相交时 Sqrt 的虚部的符号发生了反转：

Wolfram Language code:

TableForm[Table[{-1 + Δ, Sqrt[-1 + Δ], Abs[Sqrt[-1 + Δ] - I]}, {Δ, {0.01, -0.01, 0.01I, -0.01I}}], TableHeadings -> {None, {z, Sqrt[z], HoldForm@Abs[Sqrt[z] - I]}}]

因而，总的来说，这种关系在复平面上不成立：

Wolfram Language code: AsymptoticEqual[(Sqrt[z] - I)^3, (z + 1)^3, z -> -1, Direction -> Complexes]

可视化从四个实方向和虚方向逼近时函数的相对大小：

Wolfram Language code:

Plot[{Abs[ (Δz^3/(Sqrt[-1 + Δz] - I)^3)], Abs[ ((I Δz)^3/(Sqrt[-1 + I Δz] - I)^3)]}, {Δz, -1, 1}, IconizedObject[«plot options»]]

比较多变量函数：

Wolfram Language code: AsymptoticEqual[(x - 1)^2(y - 2), Sin[ x]Cos[3y / 4], {x, y} -> {1, 2}]

可视化两个函数的范数：

Wolfram Language code: Plot3D[{Abs[(x - 1)^2(y - 2)], Abs[Sin[ x]Cos[ 3y / 2]]}, {x, y}∈Disk[{1, 2}, .9], PlotTheme -> "Detailed"]

在无穷大处比较多变量函数：

Wolfram Language code: AsymptoticEqual[ Exp[x]Log[y], x y, {x, y} -> {-∞, ∞}]

在比较多变量函数时使用参数：

Wolfram Language code: AsymptoticEqual[Sinh[x]y, Sinh[a x]y ^ 2, {x, y} -> {∞, 1}]

选项 (9)

Assumptions (1)

用 Assumptions 为参数指定条件：

Wolfram Language code: AsymptoticEqual[1 + x ^ a, 1, x -> 0, Assumptions -> a ≥ 0]

不同的假设给出不同的结果：

Wolfram Language code: AsymptoticEqual[1 + x ^ a, 1, x -> 0, Assumptions -> a < 0]

Direction (5)

从下方比较相等性：

Wolfram Language code: AsymptoticEqual[x UnitStep[x], Sin[x], x -> 0, Direction -> "FromBelow"]

等价于：

Wolfram Language code: AsymptoticEqual[x UnitStep[x], Sin[x], x -> 0, Direction -> 1]

从上方比较相等性：

Wolfram Language code: AsymptoticEqual[x UnitStep[x], Sin[x], x -> 0, Direction -> "FromAbove"]

等价于：

Wolfram Language code: AsymptoticEqual[x UnitStep[x], Sin[x], x -> 0, Direction -> -1]

在分段不连续处的相等性：

Wolfram Language code: AsymptoticEqual[FractionalPart[x ^ 2]Sin[x], Cos[x / 2], x -> 2, Direction -> "FromBelow"]

Wolfram Language code: AsymptoticEqual[FractionalPart[x ^ 2]Sin[x], Cos[x / 2], x -> 2, Direction -> "FromAbove"]

由于在一个方向上不成立，两个方向上同样不成立：

Wolfram Language code: AsymptoticEqual[FractionalPart[x ^ 2]Sin[x], Cos[x], x -> 2, Direction -> "TwoSided"]

可视化两个函数及它们的比值：

Wolfram Language code:

Plot[{FractionalPart[x ^ 2]Sin[x], Cos[x / 2], Abs[(FractionalPart[x ^ 2]Sin[x]/Cos[x / 2])]}, {x, 1.5, 2.5}, PlotLegends -> "Expressions"]

在极点处的相等性与逼近的方向无关：

Wolfram Language code: AsymptoticEqual[Tan[x], (2/2x - π), x -> π / 2, Direction -> "FromBelow"]

Wolfram Language code: AsymptoticEqual[Tan[x], (2/2x - π), x -> π / 2, Direction -> "FromAbove"]

Wolfram Language code: AsymptoticEqual[Tan[x], (2/2x - π), x -> π / 2, Direction -> ℝ]

Wolfram Language code: AsymptoticEqual[Tan[x], (2/2x - π), x -> π / 2, Direction -> ℂ]

在分支切割处的相等性：

Wolfram Language code: AsymptoticEqual[ Sqrt[x - 1] - I, Tanh[x], x -> 0, Direction -> +I]

Wolfram Language code: AsymptoticEqual[ Sqrt[x - 1] - I, Tanh[x], x -> 0, Direction -> -I]

Wolfram Language code: AsymptoticEqual[ Sqrt[x - 1] - I, Tanh[x], x -> 0, Direction -> Reals]

Wolfram Language code: AsymptoticEqual[ Sqrt[x - 1] - I, Tanh[x], x -> 0, Direction -> Complexes]

从不同象限逼近，计算相等性：

Wolfram Language code: f[x_, y_] := Piecewise[{{2*x*y, y >= 0 && x <= 0}, {4*x*y, y > 0 && x > 0}}, 0]

Wolfram Language code: g[x_, y_] := Sin[x y]

从第三象限逼近原点：

Wolfram Language code: AsymptoticEqual[f[x, y], g[x, y], {x, y} -> {0, 0}, Direction -> "FromBelow"]

等价于：

Wolfram Language code: AsymptoticEqual[f[x, y], g[x, y], {x, y} -> {0, 0}, Direction -> {"FromBelow", "FromBelow"}]

从第二象限逼近原点：

Wolfram Language code: AsymptoticEqual[f[x, y], g[x, y], {x, y} -> {0, 0}, Direction -> {"FromBelow", "FromAbove"}]

从右半平面逼近原点：

Wolfram Language code: AsymptoticEqual[f[x, y], g[x, y], {x, y} -> {0, 0}, Direction -> {"FromAbove", Reals}]//Quiet

从下半平面逼近原点：

Wolfram Language code: AsymptoticEqual[f[x, y], g[x, y], {x, y} -> {0, 0}, Direction -> {Reals, "FromBelow"}]

可视化函数的比值：

Wolfram Language code: Plot3D[(f[x, y]/g[x , y]), {x, y}∈Annulus[{.01, 1}], AxesLabel -> Automatic, Exclusions -> {Sin[x y] == 0}]//Quiet

GenerateConditions (3)

返回结果，不给出条件：

Wolfram Language code: AsymptoticEqual[1 + x ^ n, 1, x -> 0, GenerateConditions -> False]

只有在 n>0 时结果才有效：

Wolfram Language code: AsymptoticEqual[1 + x ^ n, 1, x -> 0]

Wolfram Language code: AsymptoticEqual[1 + x ^ n, 1, x -> 0, Assumptions -> n < 0]

如果结果取决于参数的值，不计算，直接返回：

Wolfram Language code: AsymptoticEqual[Exp[a x], 1, x -> ∞, GenerateConditions -> None]

Wolfram Language code: AsymptoticEqual[Exp[a x], 1, x -> ∞]

缺省情况下，如果结果只在特殊值的时候才无效，不给出条件：

Wolfram Language code: AsymptoticEqual[x^2 y^2, (x - a)^2y^2, {x, y} -> {0, 0}]

当 GenerateConditions->True 时，非通用条件也要报告：

Wolfram Language code: AsymptoticEqual[x^2 y^2, (x - a)^2y^2, {x, y} -> {0, 0}, GenerateConditions -> True]

应用 (10)

基本应用 (5)

证明在无穷远处等价的两个单项式具有相同的幂：

Wolfram Language code: AsymptoticEqual[x^n, x^m, x -> ∞, Assumptions -> m > n]

Wolfram Language code: AsymptoticEqual[a x^n, b x^n, x -> ∞, Assumptions -> a ≠ 0 && b ≠ 0]

用上式来证明两个等价的多项式的大小相同：

Wolfram Language code: AsymptoticEqual[a x^n + b x^k, c x^n + d x^l, x -> ∞, Assumptions -> 0 < k ≤ l < n && a ≠ 0 && c ≠ 0]

可视化三对渐近等价多项式的比值：

Wolfram Language code:

LogLogPlot[{(5x^3 + 1 + 50x^2/x^3 + 100x + 75), (x^3 + 5x^2 + 1/x^3 + 100x + 75), (x^4/x^4 + 100x^2 + 2500)}, {x, 1, 1000}, PlotTheme -> {"Detailed", "Marketing"}]

证明在处等价的两个形为的单项式具有相同的幂：

Wolfram Language code: AsymptoticEqual[(1/x^n), (1/x^m), x -> 0, Assumptions -> m > n > 0]

Wolfram Language code: AsymptoticEqual[(a/x^n), (b /x^n), x -> 0, Assumptions -> a ≠ 0 && b ≠ 0]

用上式来证明两个形为的等价多项式的首项单项式相同：

Wolfram Language code: AsymptoticEqual[(a/x^n) + (b/x^k), (c/x^n) + (d/x^l), x -> 0, Assumptions -> 0 < k ≤ l < n && a ≠ 0 && c ≠ 0]

可视化三对形为的渐近等价的多项式的比值：

Wolfram Language code:

LogLogPlot[{(5x^-3 + 1 + 50x^-2/x^-3 + 100x + 75), (x^-3 + 5x^-2 + 1000/x^-3 + 100x + 75), (x^-4/x^-4 + 100x^-2 + 2500)}, {x, 0, 1}, PlotTheme -> {"Detailed", "Marketing"}, ImageSize -> Medium]

证明在处：

Wolfram Language code: AsymptoticEqual[x^2(2 + Sin[1 / x]), x^2, x -> 0]

可视化该函数：

Wolfram Language code: Plot[{Abs[x^2(2 + Sin[1 / x])], x^2}, {x, -(1/3), (1/3)}, PlotLegends -> "Expressions"]

尽管它们的比值的绝对值在，但始终是偏离值的：

Wolfram Language code: Plot[Abs[(x^2(2 + Sin[1 / x])/x^2)], {x, 10 ^ -3, 1 / 3}, PlotLegends -> "AllExpressions", PlotRange -> {0, 3}]

证明：

Wolfram Language code: AsymptoticEqual[x^2(2 + Sin[x]), x^2, x -> ∞]

尽管它们的比值的绝对值在时不断地摆动，但始终是偏离值的：

Wolfram Language code: Plot[Abs[(x^2(2 + Sin[x])/x^2)], {x, 1, 100}, PlotLegends -> "AllExpressions", PlotRange -> {0, 3}]

证明在处：

Wolfram Language code: AsymptoticEqual[x^2Sin[10 / x], x, x -> ∞]

Wolfram Language code: Plot[Abs[(x^2Sin[10 / x]/x)], {x, 1, 50}, PlotLegends -> "AllExpressions", PlotRange -> {0, 10}]

计算复杂度 (3)

在冒泡排序中，对相邻的项进行比较，如果顺序不对即进行交换. 经过 n-1 次比较后，最大的元素在最后. 然后在剩余的 n-1 个元素上重复该过程，直到开头处只剩下两个元素. 如果比较和交换需要 c 个步骤，则排序需要的总步骤如下所示：

Wolfram Language code: Sum[c(i - 1), {i, n, 2, -1}]

证明，因此该算法具有二次幂的运行时间：

Wolfram Language code: AsymptoticEqual[(1/2) (-c n + c n^2), n^2, n -> ∞, Assumptions -> c > 0]

显示不同 c 值的两个函数的比值：

Wolfram Language code: Plot[((1/2) (-c n + c n^2)/n^2) /. {{c -> 1}, {c -> 3}, {c -> 5}}//Evaluate, {n, 1, 100}, PlotLegends -> "Expressions"]

在合并排序中，元素列表被分成两部分，分别对每部分进行排序，然后合并两个部分. 因此，进行排序的总时间 T[n] 将是用于计算中值的某个固定时间 b 加上对每一半元素进行排序的时间 2T[n/2]，再加上用于将两部分元素合并在一起的时间，即元素个数的倍数 a n：

Wolfram Language code: reqn = T[n] == 2T[n / 2] + a n + b

求解循环方程，计算对 n 个元素进行排序所需的时间 t：

Wolfram Language code: t = RSolveValue[reqn, T[n], n]//Expand

证明，因此算法的运行时间为：

Wolfram Language code: AsymptoticEqual[t, n Log[n], n -> ∞, Assumptions -> a > 0]

Strassen 算法是第一个发现的 subcubic 矩阵乘法算法. 它由 4 个步骤组成：将两个矩阵中的每一个分成 4 个大小相等的子矩阵，从 8 个子矩阵中形成 14 个特定的线性组合，将 7 对这样的组合相乘，形成 7 个结果的线性组合. 因此，执行乘法的时间将是用于分割矩阵的固定定时间，在第二和第四步中形成线性组合的时间则为，第三步花费的时间则为：

Wolfram Language code: reqn = T[n] == 7T[n / 2] + a n ^2 + b

求解循环关系式：

Wolfram Language code: t = RSolveValue[reqn, T[n], n]//Simplify

尽管结果很复杂，它渐近等于：

Wolfram Language code: AsymptoticEqual[t, n ^ Log[2, 7], n -> ∞, Assumptions -> a > 0 && b > 0 && C[1] > 0]

比较 naive cubic 算法和 Strassen 算法的增长率：

Wolfram Language code: Plot[{2n ^ Log[2, 7], n ^ 3}, {n, 1, 1000}, PlotLegends -> "Expressions"]

收敛性测试 (2)

如果 $sum_(n=1)^inftyTemplateBox[{{a, _, n}}, Abs]<infty$ ，序列被认为是绝对可以求和的. 如果第二个序列，比较测试指出，当且仅当是绝对可以求和的，才是绝对可以求和的. 通过与的和进行比较，用测试证明收敛：

Wolfram Language code: AsymptoticEqual[(1/n^2), (1/n^2 + n + 1), n -> ∞]

Wolfram Language code: Sum[(1/Abs[n^2]), {n, 1, ∞}]

与 SumConvergence 给出的答案比较：

Wolfram Language code: SumConvergence[(1/n^2 + n + 1), n]

通过与的和进行比较，证明收敛：

Wolfram Language code: AsymptoticEqual[(1/n^3 / 2), (1/n^2Sin[1 / Sqrt[n]]), n -> ∞]

Wolfram Language code: Sum[(1/Abs[n^3 / 2]), {n, 1, ∞}]

通过与的和进行比较，证明发散：

Wolfram Language code: AsymptoticEqual[(1/n), ArcCot[n], n -> ∞]

Wolfram Language code: DiscreteLimit[Sum[(1/n), {n, 1, k}], k -> ∞]

与 SumConvergence 给出的答案比较：

Wolfram Language code: SumConvergence[ArcCot[n], n]

因此序列不是绝对可以求和的：

Wolfram Language code: AsymptoticEqual[Log[n, Sqrt[(n + 1/n - 1)]], (1/n Log[n]), n -> ∞]

Wolfram Language code: SumConvergence[Abs[(1/n Log[n])], n]

如果 $int_a^bTemplateBox[{{f, , {(, x, )}}}, Abs]dx<infty$ ，函数被认为在上是绝对可积的. 如果和在开区间上是连续的，且在和处有，比较测试指出，当且仅当是绝对可积的，才是绝对可积的. 用测试证明在上是绝对可积的：

Wolfram Language code: AsymptoticEqual[(ArcCot[x]/x), (1/x^2), x -> ∞]

Wolfram Language code: AsymptoticEqual[(ArcCot[x]/x), (1/x^2), x -> 1]

因为在上是绝对可积的，所以也是如此：

Wolfram Language code: Integrate[(1/x^2), {x, 1, ∞}]

通过与比较，可以证明在上不可积：

Wolfram Language code: AsymptoticEqual[(ArcCot[x]/x), (1/x), x -> 0]

Wolfram Language code: AsymptoticEqual[(ArcCot[x]/x), (1/x), x -> 1]

结果来自在单位区间上的不可积性：

Wolfram Language code: Integrate[Abs[(1/x)], {x, 0, 1}]

函数在上不是绝对可积的：

Wolfram Language code: Integrate[Abs[(1/Log[x])], {x, 1, ∞}]

通过与比较，证明同样不是绝对可积的：

Wolfram Language code: AsymptoticLessEqual[(LogIntegral[x]/x), (1/ Log[x]), x -> ∞]

Wolfram Language code: AsymptoticLessEqual[(LogIntegral[x]/x), (1/ Log[x]), x -> 1]

属性和关系 (6)

AsymptoticEqual 是一种等价关系，意味着它是自反的（即）：

Wolfram Language code: AsymptoticEqual[f[x], f[x], x -> x0]

还是一种传递关系（即若和成立，则有）：

Wolfram Language code: {f, g, h} = {x, x^2 / (1 + x), x^3 / (1 + x^2)};

Wolfram Language code: {AsymptoticEqual[f, g, x -> ∞], AsymptoticEqual[g, h, x -> ∞], AsymptoticEqual[f, h, x -> ∞]}

也是对称的（即意味着）：

Wolfram Language code: {AsymptoticEqual[f, g, x -> ∞], AsymptoticEqual[g, f, x -> ∞]}

当且仅当 MaxLimit[Abs[f[x]/g[x]],xx₀]<∞ 和 MinLimit[Abs[f[x]/g[x]],xx₀]>0 时，AsymptoticEqual[f[x],g[x],xx₀] 的结果为：

Wolfram Language code: {f, g} = {x (Sin[x] + 2), x};

Wolfram Language code: {AsymptoticEqual[f, g, x -> ∞], MaxLimit[Abs[f / g], x -> ∞], MinLimit[Abs[f / g], x -> ∞]}

Wolfram Language code: {f, g} = {1, Sin[x]};

Wolfram Language code: {AsymptoticEqual[f, g, x -> ∞], MaxLimit[Abs[f / g], x -> ∞], MinLimit[Abs[f / g], x -> ∞]}

如果 0<Limit[Abs[f[x]/g[x]],xx₀]<∞，则 AsymptoticEqual[f[x],g[x],xx₀] 的结果为：

Wolfram Language code: {f, g} = {x ^2 / (1 + x), x};

Wolfram Language code: {AsymptoticEqual[f, g, x -> ∞], Limit[Abs[f / g], x -> ∞]}

但极限不必存在：

Wolfram Language code: {f, g} = {x, x Exp[Cos[x]]};

Wolfram Language code: {AsymptoticEqual[f, g, x -> ∞], Limit[Abs[f / g], x -> ∞]}

当且仅当和时，：

Wolfram Language code: {f, g} = {x ^2 / (1 + x), x};

Wolfram Language code: {AsymptoticEqual[f, g, x -> ∞], AsymptoticLessEqual[f, g, x -> ∞], AsymptoticGreaterEqual[f, g, x -> ∞]}

如果或，则：

Wolfram Language code: {f, g} = {x ^2 / (1 + x^2), x};

Wolfram Language code: {AsymptoticLess[f, g, x -> ∞], AsymptoticEqual[f, g, x -> ∞]}

Wolfram Language code: {AsymptoticGreater[g, f, x -> ∞], AsymptoticEqual[g, f, x -> ∞]}

但反过来不成立：

Wolfram Language code: {f, g} = {Sin[x], Cos[x]};

Wolfram Language code: {AsymptoticEqual[f, g, x -> ∞], AsymptoticLess[f, g, x -> ∞], AsymptoticGreater[f, g, x -> ∞]}

如果，则：

Wolfram Language code: {f, g} = {x, x^2 / (1 + x)};

Wolfram Language code: {AsymptoticEquivalent[f, g, x -> ∞], AsymptoticEqual[f, g, x -> ∞]}

但反过来不成立，所以 AsymptoticEqual 没有 AsymptoticEquivalent 严格：

Wolfram Language code: {f, g} = {x, 2x^2 / (1 + x)};

Wolfram Language code: {AsymptoticEquivalent[f, g, x -> ∞], AsymptoticEqual[f, g, x -> ∞]}

Top

	AsymptoticEqual[f[x],g[x],xx^*]	存在、和，使得 $0<TemplateBox[{{x, -, {x, ^, }}}, Abs]<delta(c_1,c_2,x^)$ 意味着 $c_1 TemplateBox[{{g, (, x, )}}, Abs]<=TemplateBox[{{f, (, x, )}}, Abs]<=c_2 TemplateBox[{{g, (, x, )}}, Abs]$ 成立
	AsymptoticEqual[f[x₁,…,x_n],g[x₁,…,x_n],{x₁,…,x_n}{,…,}]	存在、和，使得 $0<TemplateBox[{{{, {{{x, _, 1}, -, {x, _, {(, 1, )}, ^, }}, ,, ..., ,, {{x, _, n}, -, {x, _, {(, n, )}, ^, }}}, }}}, Norm]<delta(epsilon,x^*)$ 意味着 $c_1 TemplateBox[{{g, (, {{x, _, 1}, ,, ..., ,, {x, _, n}}, )}}, Abs]<=TemplateBox[{{f, (, {{x, _, 1}, ,, ..., ,, {x, _, n}}, )}}, Abs]<=c_2 TemplateBox[{{g, (, {{x, _, 1}, ,, ..., ,, {x, _, n}}, )}}, Abs]$ 成立

	AsymptoticEqual[f[x],g[x],x∞]	存在、和，使得意味着 $c_1 TemplateBox[{{g, (, x, )}}, Abs]<=TemplateBox[{{f, (, x, )}}, Abs]<=c_2 TemplateBox[{{g, (, x, )}}, Abs]$ 成立
	AsymptoticEqual[f[x₁,…,x_n],g[x₁,…,x_n],{x₁,…,x_n}{∞,…,∞}]	存在、和，使得意味着 $c_1 TemplateBox[{{g, (, {{x, _, 1}, ,, ..., ,, {x, _, n}}, )}}, Abs]<=TemplateBox[{{f, (, {{x, _, 1}, ,, ..., ,, {x, _, n}}, )}}, Abs]<=c_2 TemplateBox[{{g, (, {{x, _, 1}, ,, ..., ,, {x, _, n}}, )}}, Abs]$ 成立

Assumptions	$Assumptions	对参数的设定
Direction	Reals	趋近极限点的方向
GenerateConditions	Automatic	对参数生成条件
Method	Automatic	所使用的方法
PerformanceGoal	"Quality"	优化目标

	Reals or "TwoSided"	从两个实方向
	"FromAbove" or -1	从上面或较大的值
	"FromBelow" or +1	从下面或较小的值
	Complexes	从所有复方向
	Exp[ θ]	从方向
	{dir₁,…,dir_n}	对变量 x_i 分别使用方向 dir_i

更多学习资源

技术支持

Wolfram 解决方案

Wolfram 的教育解决方案

开始

提高你的技能

与我们合作

成人教育计划

青少年教育计划

欢迎阅读

AsymptoticEqual

更多信息和选项

范例

基本范例 (2)

范围 (9)

选项 (9)

Assumptions (1)

Direction (5)

GenerateConditions (3)

应用 (10)

基本应用 (5)

计算复杂度 (3)

收敛性测试 (2)

属性和关系 (6)

文本

CMS

APA

BibTeX

BibLaTeX

	Automatic	只给出非通用条件
	True	所有条件
	False	不给出条件
	None	如果需要条件则不经计算直接返回

AsymptoticEqual

更多信息和选项

范例

基本范例 (2)

范围 (9)

选项 (9)

Assumptions (1)

Direction (5)

GenerateConditions (3)

应用 (10)

基本应用 (5)

计算复杂度 (3)

收敛性测试 (2)

属性和关系 (6)

参见

相关指南

历史

文本

CMS

APA

BibTeX

BibLaTeX