WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

AtomQ[expr]

式 expr がこれ以上分割不可能であるときにTrueを，その他の場合にFalseを返す．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
アプリケーション  
特性と関係  
関連項目
テクニカルノート
関連するガイド
履歴
引用書式

AtomQ

AtomQ[expr]

式 expr がこれ以上分割不可能であるときにTrueを，その他の場合にFalseを返す．

詳細

  • 再帰的な手続きの中で，式に対応するツリー構造の最下層に到達したかどうかを判定するためにAtomQが利用できる．
  • AtomQは，記号や数，列，疎な配列のような生のオブジェクト等にはTrueを返す．
  • AtomQは，オブジェクトの部分にMapのような関数でアクセスできない場合にTrueを返す．

例題

すべて開く すべて閉じる

例  (1)

式が再分割できるかどうかテストする：

Wolfram Language code: e = x + 22 / 7
Wolfram Language code: AtomQ[e]

これは原子ではないので，一部分を抽出することができる：

Wolfram Language code: e[[1]]

これは原子である数である：

Wolfram Language code: AtomQ[%]

スコープ  (6)

文字列は再分割できない：

Wolfram Language code: AtomQ["This is an atom"]

記号は再分割できない：

Wolfram Language code: AtomQ[ThisIsAnAtom]

数は再分割できない：

Wolfram Language code: AtomQ[1.23]

有理(Rational)数は複合構造を持つように見える：

Wolfram Language code: FullForm[22 / 7]

数であるので，再分割はできない：

Wolfram Language code: AtomQ[22 / 7]

各部分にはNumeratorおよびDenominatorでアクセスできる：

Wolfram Language code: {Numerator[22 / 7], Denominator[22 / 7]}

複素(Complex)数は複合構造を持っているように見える：

Wolfram Language code: FullForm[1 + 2 I]

数であるので，再分割はできない：

Wolfram Language code: AtomQ[1 + 2 I]

各部分にはReおよびImでアクセスできる：

Wolfram Language code: {Re[1 + 2 I], Im[1 + 2 I]}

SparseArrayオブジェクトは原子的な生のオブジェクトである：

Wolfram Language code: s = SparseArray[{i_, i_} -> i, 3]
Wolfram Language code: AtomQ[s]

SparseArrayオブジェクトに使えるコマンドは，一般に表示された配列に対して使われる：

Wolfram Language code: a = Normal[s]
Wolfram Language code: s[[2, 2]]
Wolfram Language code: a[[2, 2]]

SparseArrayオブジェクトの完全形(FullForm)は，生のオブジェクトを再構築するのに十分であるように設計されている：

Wolfram Language code: FullForm[s]
Wolfram Language code: s1 = SparseArray[Automatic, List[3, 3], 0, List[1, List[List[0, 1, 2, 3], List[List[1], List[2], List[3]]], List[1, 2, 3]]]

アプリケーション  (2)

式中の再分割が不可能な葉の数を求める：

Wolfram Language code: leaves[expr_, OptionsPattern[]] := Block[{c = 0, cl, e}, cl[e_ ? AtomQ] := c++; cl[e_] := Scan[cl, e, Heads -> OptionValue[Heads]]; cl[expr]; c]; Options[leaves] = {Heads -> True};

深くネストした式：

Wolfram Language code: e = Fold[f, x, Range[5]]
Wolfram Language code: leaves[e]

次はLeafCountに等しい：

Wolfram Language code: LeafCount[e]

オブションをHeads->Falseとすると，枝を持たない原子のみが数えられる：

Wolfram Language code: leaves[e, Heads -> False]

次はTreeFormで見られるぶら下がった葉に相当する：

Wolfram Language code: TreeForm[e]

式の最小と最大の「深さ」を求める：

Wolfram Language code: depth[expr_] := Block[{mind = Infinity, maxd = 0, burrow}, burrow[e_ ? AtomQ, d_] := (mind = Min[d, mind];maxd = Max[d, maxd]); burrow[e_, d_] := Scan[burrow[#, d + 1]&, e]; burrow[expr, 0]; {mind, maxd}]
Wolfram Language code: depth[1 + x + 2x ^ 2]
Wolfram Language code: depth[{{1, 2}, {3, 4}}]

Depthは最大の深さに1加えたものを返す：

Wolfram Language code: Depth[1 + x + 2x ^ 2]

特性と関係  (1)

Map[f,expr,{-1}]は通常 f を expr 中の原子にマップする：

Wolfram Language code: Map[f, 1 + x + 2x ^ 2, {-1}]

これは次の再帰関数に等しい：

Wolfram Language code: mapf[e_ ? AtomQ] := f[e]; mapf[head_[args___]] := Apply[head, Table[mapf[arg], {arg, {args}}]]
Wolfram Language code: mapf[1 + x + 2x ^ 2]
Wolfram Research (1988), AtomQ, Wolfram言語関数， https://reference.wolfram.com/language/ref/AtomQ.html （2003年に更新）.

テキスト

Wolfram Research (1988), AtomQ, Wolfram言語関数， https://reference.wolfram.com/language/ref/AtomQ.html （2003年に更新）.

CMS

Wolfram Language. 1988. "AtomQ." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2003. https://reference.wolfram.com/language/ref/AtomQ.html.

APA

Wolfram Language. (1988). AtomQ. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/AtomQ.html

BibTeX

@misc{reference.wolfram_2026_atomq, author="Wolfram Research", title="{AtomQ}", year="2003", howpublished="\url{https://reference.wolfram.com/language/ref/AtomQ.html}", note=[Accessed: 11-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_atomq, organization={Wolfram Research}, title={AtomQ}, year={2003}, url={https://reference.wolfram.com/language/ref/AtomQ.html}, note=[Accessed: 11-August-2026]}