WOLFRAM

Wolfram 语言与系统参考资料中心

AtomQ[expr]

用来判断一个表达式 expr 是否能分成子表达式，如不能则返回 True ，否则返回 False.

更多信息
Details and Options Details and Options
范例  
基本范例  
范围  
应用  
属性和关系  
参见
技术笔记
相关指南
历史
按以下格式引用：

AtomQ

AtomQ[expr]

用来判断一个表达式 expr 是否能分成子表达式，如不能则返回 True ，否则返回 False.

更多信息

  • 可以在一个循环过程中使用 AtomQ 判断何时到达与表达式相应的树的底部.
  • 对符号、数字、字符串以及诸如稀疏数组等其它原始对象，AtomQ 的返回值是 True.
  • 对任何使用诸如 Map 之类的函数都不能访问子部分的对象，AtomQ 的返回值是 True.

范例

打开所有单元 关闭所有单元

基本范例  (1)

检验一个表达式是否不可以再细分：

Wolfram Language code: e = x + 22 / 7
Wolfram Language code: AtomQ[e]

由于它不是一个基元，可以提取它的各部分：

Wolfram Language code: e[[1]]

这是一个数，它是一个基元：

Wolfram Language code: AtomQ[%]

范围  (6)

字符串不可以再细分：

Wolfram Language code: AtomQ["This is an atom"]

符号不可以再细分：

Wolfram Language code: AtomQ[ThisIsAnAtom]

数字不可以再细分：

Wolfram Language code: AtomQ[1.23]

Rational 数显示具有复合结构：

Wolfram Language code: FullForm[22 / 7]

作为数，它们不可以再细分：

Wolfram Language code: AtomQ[22 / 7]

通过 Numerator和Denominator 可以访问这些部分：

Wolfram Language code: {Numerator[22 / 7], Denominator[22 / 7]}

Complex 数显示具有复合结构：

Wolfram Language code: FullForm[1 + 2 I]

作为数字，它们不可以再细分：

Wolfram Language code: AtomQ[1 + 2 I]

通过 Re 和 Im 可以访问这些部分：

Wolfram Language code: {Re[1 + 2 I], Im[1 + 2 I]}

SparseArray 对象为基元式原始对象：

Wolfram Language code: s = SparseArray[{i_, i_} -> i, 3]
Wolfram Language code: AtomQ[s]

用于 SparseArray 对象的指令通常像这样作用于所表示的数组：

Wolfram Language code: a = Normal[s]
Wolfram Language code: s[[2, 2]]
Wolfram Language code: a[[2, 2]]

一个 SparseArray 对象的 FullForm 被设计为足以重建原始对象：

Wolfram Language code: FullForm[s]
Wolfram Language code: s1 = SparseArray[Automatic, List[3, 3], 0, List[1, List[List[0, 1, 2, 3], List[List[1], List[2], List[3]]], List[1, 2, 3]]]

应用  (2)

求出一个表达式中不可再细分的叶的数量：

Wolfram Language code: leaves[expr_, OptionsPattern[]] := Block[{c = 0, cl, e}, cl[e_ ? AtomQ] := c++; cl[e_] := Scan[cl, e, Heads -> OptionValue[Heads]]; cl[expr]; c]; Options[leaves] = {Heads -> True};

一种深度嵌套的表达式：

Wolfram Language code: e = Fold[f, x, Range[5]]
Wolfram Language code: leaves[e]

它等价于 LeafCount：

Wolfram Language code: LeafCount[e]

使用可选项 Heads->False 只能计算不带分支的基元：

Wolfram Language code: leaves[e, Heads -> False]

它相当于用 TreeForm 看到的悬挂的叶：

Wolfram Language code: TreeForm[e]

求出一个表达式的最小和最大“深度”：

Wolfram Language code: depth[expr_] := Block[{mind = Infinity, maxd = 0, burrow}, burrow[e_ ? AtomQ, d_] := (mind = Min[d, mind];maxd = Max[d, maxd]); burrow[e_, d_] := Scan[burrow[#, d + 1]&, e]; burrow[expr, 0]; {mind, maxd}]
Wolfram Language code: depth[1 + x + 2x ^ 2]
Wolfram Language code: depth[{{1, 2}, {3, 4}}]

Depth 给出最大深度加1：

Wolfram Language code: Depth[1 + x + 2x ^ 2]

属性和关系  (1)

Map[f,expr,{-1}] 通常把 f 映射到 expr 中的基元上：

Wolfram Language code: Map[f, 1 + x + 2x ^ 2, {-1}]

它等价于以下递归函数：

Wolfram Language code: mapf[e_ ? AtomQ] := f[e]; mapf[head_[args___]] := Apply[head, Table[mapf[arg], {arg, {args}}]]
Wolfram Language code: mapf[1 + x + 2x ^ 2]
Wolfram Research (1988)，AtomQ，Wolfram 语言函数，https://reference.wolfram.com/language/ref/AtomQ.html （更新于 2003 年）.

文本

Wolfram Research (1988)，AtomQ，Wolfram 语言函数，https://reference.wolfram.com/language/ref/AtomQ.html （更新于 2003 年）.

CMS

Wolfram 语言. 1988. "AtomQ." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2003. https://reference.wolfram.com/language/ref/AtomQ.html.

APA

Wolfram 语言. (1988). AtomQ. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/AtomQ.html 年

BibTeX

@misc{reference.wolfram_2026_atomq, author="Wolfram Research", title="{AtomQ}", year="2003", howpublished="\url{https://reference.wolfram.com/language/ref/AtomQ.html}", note=[Accessed: 07-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_atomq, organization={Wolfram Research}, title={AtomQ}, year={2003}, url={https://reference.wolfram.com/language/ref/AtomQ.html}, note=[Accessed: 07-August-2026]}