WOLFRAM

Wolfram 语言与系统参考资料中心

BSplineBasis[d,x]

给出在 x 处的第 0 个 d 次均匀 B 样条基函数.

BSplineBasis[d,n,x]

给出第 n 个 d 次均匀 B 样条基函数.

BSplineBasis[{d,{u1,u2,…}},n,x]

给出第 n 个 d 次非均匀 B 样条基函数，在坐标 ui 有节点.

更多信息
Details and Options Details and Options
范例  
基本范例  
范围  
属性和关系  
参见
相关指南
历史
按以下格式引用：

BSplineBasis

BSplineBasis[d,x]

给出在 x 处的第 0 个 d 次均匀 B 样条基函数.

BSplineBasis[d,n,x]

给出第 n 个 d 次均匀 B 样条基函数.

BSplineBasis[{d,{u1,u2,…}},n,x]

给出第 n 个 d 次非均匀 B 样条基函数，在坐标 ui 有节点.

更多信息

  • 数学函数，同时适合符号和数值运算.
  • BSplineBasis[d,x] 等价于 BSplineBasis[d,0,x].
  • BSplineBasis[d,n,x] 给出非零值仅位于 x 的区间 和 内部的 B 样条基函数.
  • BSplineBasis[{d,{u1,u2,…,um}},n,x] 给出非零值仅位于 x 区间 u1 和 um 内部的 B 样条基函数.
  • 节点坐标 ui 必须形成一个非递减的序列.
  • 范围 n 的值从 0 到 m-d-2.
  • PiecewiseExpand 可以用于将符号式 BSplineBasis 函数展开为显式的分段多项式.

范例

打开所有单元 关闭所有单元

基本范例  (4)

计算一个均匀的三次 B 样条基函数：

Wolfram Language code: BSplineBasis[3, 0.5]

绘制：

Wolfram Language code: Plot[BSplineBasis[3, x], {x, 0, 1}]

计算有给定节点的第二个三次 B 样条基函数：

Wolfram Language code: knots = {0, 0, 0, 0, 1 / 3, 2 / 3, 1, 1, 1, 1};
Wolfram Language code: BSplineBasis[{3, knots}, 2, 0.5]

在给定节点绘制所有三次基函数：

Wolfram Language code: Plot[Evaluate[Table[BSplineBasis[{3, knots}, i, x], {i, 0, 5}]], {x, 0, 1}]

B 样条基函数的符号导数：

Wolfram Language code: knots = {0, 0, 0, 1 / 3, 2 / 3, 1, 1, 1};
Wolfram Language code: D[BSplineBasis[{2, knots}, 2, x], {x, 1}]

绘制导数：

Wolfram Language code: Table[Plot[Evaluate[D[BSplineBasis[{2, knots}, 2, x], {x, i}]], {x, 0, 1}], {i, 0, 2}]

范围  (1)

TraditionalForm 格式：

Wolfram Language code: BSplineBasis[{3, {0, 0, 0, 0, 1 / 3, 2 / 3, 1, 1, 1, 1}}, 1, x]//TraditionalForm
Wolfram Language code: InputForm[%]

属性和关系  (3)

B 样条基函数的非零部分由节点范围给出：

Wolfram Language code: k1 = {0, 0, 0, 0, 1 / 3, 2 / 3, 1, 1, 1, 1}; k2 = 2 k1; k3 = k1 + 1;
Wolfram Language code: Table[Plot[BSplineBasis[{3, k}, 2, x], {x, 0, 2}, PlotRange -> {0, 1}, PlotLabel -> Style[k, Small]], {k, {k1, k2, k3}}]
Wolfram Language code: Table[Plot3D[BSplineBasis[{3, k}, 2, x]BSplineBasis[{3, k}, 2, y], {x, 0, 2}, {y, 0, 2}, PlotRange -> {0, 1 / 2}, Mesh -> None, Boxed -> False], {k, {k1, k2, k3}}]

在支持内各点处的全部 B 样条基的和总是 1：

Wolfram Language code: knots = {0, 0, 0, 0, 1 / 3, 2 / 3, 1, 1, 1, 1};
Wolfram Language code: Plot[Evaluate[Sum[BSplineBasis[{3, knots}, i, x], {i, 0, 5}]], {x, 0, 1}, Axes -> False, Frame -> True]

至多 d+1 个基函数对和有贡献，其中 d 是次数：

Wolfram Language code: Plot[Evaluate[Table[BSplineBasis[{3, knots}, i, x], {i, 0, 5}]], {x, 0, 1}]

BSplineBasis 可以用来建立 BSplineCurve：

Wolfram Language code: knots = {0, 0, 0, 1 / 4, 1 / 2, 3 / 4, 1, 1, 1};
Wolfram Language code: pts = {{0, -1}, {1, 1}, {2, -1}, {3, -1}, {4, 1}, {5, -1}};
Wolfram Language code: f[t_] := Sum[pts[[i + 1]]BSplineBasis[{2, knots}, i, t], {i, 0, 5}]
Wolfram Language code: {ParametricPlot[f[t], {t, 0, 1}, Frame -> True, Axes -> False, PlotRange -> {All, {-1, 1}}], Graphics[BSplineCurve[pts, SplineDegree -> 2], Frame -> True]}
Wolfram Research (2008)，BSplineBasis，Wolfram 语言函数，https://reference.wolfram.com/language/ref/BSplineBasis.html.

文本

Wolfram Research (2008)，BSplineBasis，Wolfram 语言函数，https://reference.wolfram.com/language/ref/BSplineBasis.html.

CMS

Wolfram 语言. 2008. "BSplineBasis." Wolfram 语言与系统参考资料中心. Wolfram Research. https://reference.wolfram.com/language/ref/BSplineBasis.html.

APA

Wolfram 语言. (2008). BSplineBasis. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/BSplineBasis.html 年

BibTeX

@misc{reference.wolfram_2026_bsplinebasis, author="Wolfram Research", title="{BSplineBasis}", year="2008", howpublished="\url{https://reference.wolfram.com/language/ref/BSplineBasis.html}", note=[Accessed: 04-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_bsplinebasis, organization={Wolfram Research}, title={BSplineBasis}, year={2008}, url={https://reference.wolfram.com/language/ref/BSplineBasis.html}, note=[Accessed: 04-September-2026]}