Beta

Beta[a,b]

オイラー(Euler)のベータ関数を与える．

Beta[z,a,b]

不完全ベータ関数を与える．

詳細

Betaは記号操作・数値操作の両方に適した数学関数である．
$TemplateBox[{a, b}, Beta]=TemplateBox[{a}, Gamma]TemplateBox[{b}, Gamma]/TemplateBox[{{a, +, b}}, Gamma]=int_0^1t^(a-1)(1-t)^(b-1)dt$
$TemplateBox[{z, a, b}, Beta3]=int_0^zt^(a-1)(1-t)^(b-1)dt$
Beta[z,a,b]は，複素平面上に，〜の範囲で不連続な分枝切断線を持つ．
Beta[z₀,z₁,a,b]は，一般的不完全ベータ関数を与える．
不完全ベータ(Beta)関数の引数は，不完全ガンマ(Gamma)関数と異なった並び順をすることに注意．
特別な引数の場合，Betaは，自動的に厳密値を計算する．
Betaは任意の数値精度で評価できる．
Betaは自動的にリストに縫い込まれる．
TraditionalFormの設定では，\[CapitalBeta]を使ってBetaが表示される．
BetaはIntervalオブジェクトおよびCenteredIntervalオブジェクトに使うことができる． »

例題

すべて開くすべて閉じる

例 (6)

厳密値：

Wolfram Language code: Beta[5, 4]

Wolfram Language code: Beta[5 / 2, 7 / 2]

数値的に評価する：

Wolfram Language code: Beta[2.3, 3.2]

実数の部分集合上でをプロットする：

Wolfram Language code: Plot[Beta[1 / 2, x], {x, -2, 3}]

実数の部分集合上で不完全ベータ関数をプロットする：

Wolfram Language code: Plot[Beta[x, 1 / 2, 1 / 2], {x, 0, 1}]

複素数の部分集合上でプロットする：

Wolfram Language code: ComplexPlot3D[Beta[1 / 2, z], {z, -2 - 2I, 2 + 2I}, PlotLegends -> Automatic]

原点における級数展開：

Wolfram Language code: Series[Beta[1 / 2, x], {x, 0, 2}]//Normal//FullSimplify

Infinityにおける級数展開：

Wolfram Language code: Series[Beta[-1 / 2, x], {x, ∞, 4}]//Normal

スコープ (42)

数値評価 (8)

数値的に評価する：

Wolfram Language code: Beta[1.1, 2.1]

特別な場合には記号的に評価する：

Wolfram Language code: {Beta[0, b], Beta[a, 0]}

高精度で評価する：

Wolfram Language code: N[Beta[22 / 10, 33 / 10], 50]

出力精度は入力精度に従う：

Wolfram Language code: Beta[2.200000000000000000000000, 33 / 10]

Wolfram Language code: Beta[22 / 10, 3.300000000000000000000000]

大きい引数について評価する：

Wolfram Language code: Beta[100000, 100000]//Short

Wolfram Language code: Beta[10. ^ 5, 10. ^ 5]

複素引数について評価する：

Wolfram Language code: Beta[2.5 + I, 1 - I]

Betaを高精度で効率よく評価する：

Wolfram Language code: Beta[1.1`200, 2.2`200]//Timing

Wolfram Language code: Beta[1.1`1000, 2.2`1000];//Timing

IntervalオブジェクトとCenteredIntervalオブジェクトを使って最悪の場合に保証される区間を計算する：

Wolfram Language code: Beta[2, Interval[{1.2, 2.1}]]

Wolfram Language code: Beta[2, CenteredInterval[2, 1 / 8]]

Aroundを使って平均的な場合の統計区間を計算することもできる：

Wolfram Language code: Beta[ Around[1.2, 0.01], 1, 2]

配列の要素ごとの値を計算する：

Wolfram Language code: Beta[{{1 / 2, -1}, {0, 1 / 2}}, 1, 2]

MatrixFunctionを使って行列のBeta関数を計算することもできる：

Wolfram Language code: MatrixFunction[Beta[#, 1, 2]&, {{1 / 2, -1}, {0, 1 / 2}}]//FullSimplify

特定の値 (4)

無限大における値：

Wolfram Language code: Beta[Infinity, 0]

Wolfram Language code: Beta[0, Infinity]

の零点を求める：

Wolfram Language code: xmin = Solve[Beta[x, -1 / 2] == 0 && 0 < x < 1, x, Reals][[1, 1, 2]]//Quiet

Wolfram Language code: Plot[Beta[x, -1 / 2], {x, -1, 3}, Epilog -> Style[Point[{xmin, Beta[xmin, -1 / 2]}], PointSize[Large], Red]]

不完全ベータ関数を整数次と半整数次で記号的に評価する：

Wolfram Language code: Beta[z, 3, b] // FunctionExpand

Wolfram Language code: Beta[13 / 2, 7 / 2, 9 / 2] // FunctionExpand//Simplify

一般化された不完全ベータ関数を記号的に評価する：

Wolfram Language code: Beta[1 / 4, 1 / 3, 1 / 2, 3 / 2]//FunctionExpand//Simplify

可視化 (2)

をプロットする：

Wolfram Language code: Plot[Beta[1 / 2, b], {b, -2, 2}]

の等高線プロット：

Wolfram Language code: ContourPlot[Beta[a, b], {a, -3, 3}, {b, -3, 3}, IconizedObject[«PlotOptions»]]

関数の特性 (11)

オイラーの完全ベータ関数の実領域：

Wolfram Language code: FunctionDomain[Beta[a, b], {a, b}]

複素領域：

Wolfram Language code: FunctionDomain[Beta[az, bz], {az, bz}, Complexes]

置換対称性：

Wolfram Language code: Beta[a, b] == Beta[b, a]//FullSimplify

オイラーのベータ関数には鏡特性がある：

Wolfram Language code: FullSimplify[Beta[Conjugate[a], Conjugate[b]] == Conjugate[Beta[a, b]]]

完全ベータ関数は解析関数ではない：

Wolfram Language code: FunctionAnalytic[Beta[a, b], {a, b}]

しかし，有理型ではある：

Wolfram Language code: FunctionMeromorphic[Beta[a, b], {a, b}]

その特異点と不連続点は非負の整数に限られる：

Wolfram Language code: FunctionSingularities[Beta[a, b], {a, b}]

Wolfram Language code: FunctionDiscontinuities[Beta[a, b], {a, b}]

不完全ベータ関数は正の整数についてのの解析関数である：

Wolfram Language code: FunctionAnalytic[Beta[x, a, 1], x, Assumptions -> a > 0 && a∈ℤ]

そのような関数はどれも，特異点も不連続点も持たない：

Wolfram Language code: FunctionSingularities[Beta[x, 1, 1], x]

Wolfram Language code: FunctionDiscontinuities[Beta[x, 1, 1], x]

は，のその他の値については解析的でも有理型でもない：

Wolfram Language code: FunctionAnalytic[Beta[x, 1 / 2, 1], x]

Wolfram Language code: FunctionMeromorphic[Beta[x, 1 / 2, 1], x]

は非増加でも非減少でもない：

Wolfram Language code: FunctionMonotonicity[Beta[x, 1, 2], x]

は正の奇数については単射であるが，正の偶数についてはそうではない：

Wolfram Language code: FunctionInjective[Beta[x, 2k, 1], x, Assumptions -> k > 0 && k∈ℤ]

Wolfram Language code: FunctionInjective[Beta[x, 2k + 1, 1], x, Assumptions -> k > 0 && k∈ℤ]

Wolfram Language code: Plot[{Beta[x, 3, 1], Beta[x, 4, 1], 1}, {x, -2, 2}]

は正の奇数については全射であるが，正の偶数についてはそうではない：

Wolfram Language code: Table[FunctionSurjective[Beta[x, a, 1], x], {a, 5}]

Wolfram Language code: Plot[{Beta[x, 3, 1], Beta[x, 4, 1], -1}, {x, -2, 2}]

は正の偶数については非負であるが奇数については不定である：

Wolfram Language code: Table[FunctionSign[Beta[x, a, 1], x], {a, 5}]

は正の偶数について凸である：

Wolfram Language code: FunctionConvexity[Beta[x, 2k, 1], x, Assumptions -> k > 0 && k∈ℤ]

TraditionalFormによる表示：

Wolfram Language code: Beta[a, b]//TraditionalForm

微分 (2)

ベータ関数の一次導関数：

Wolfram Language code: D[Beta[a, b], a]

Wolfram Language code: D[Beta[a, b], b]

ベータ関数の高次導関数：

Wolfram Language code: derivs = Table[D[Beta[a, b], {b, n}], {n, 1, 3}]

について高次導関数をプロットする：

Wolfram Language code:

Plot[Evaluate[derivs /. a -> 1 / 2], {b, -2, 2}, PlotLegends -> {"First Derivative", "Second Derivative", "Third Derivative"}]

級数展開 (5)

極におけるベータ関数の級数展開：

Wolfram Language code: Series[Beta[z, -2z], {z, -5, 3}] // FullSimplify

の周りのベータ関数の級数展開の初項：

Wolfram Language code: Series[Beta[a, b], {a, 0, 1}]

ベータ関数の漸近展開：

Wolfram Language code: Series[Beta[a, b], {a, Infinity, 2}]

任意の点における不完全ガンマ関数の級数展開：

Wolfram Language code: Series[Beta[z, a, b], {z, z0, 2}]

Wolfram Language code: Series[Beta[z, a, b], {a, a0, 1}]

Betaはベキ級数に適用できる：

Wolfram Language code: Beta[1 + x + (x^2/2) + O[x]^4, 3]//Simplify

関数の恒等式と簡約 (4)

一般化された不完全ベータ関数は不完全ベータ関数と関連している：

Wolfram Language code: Beta[x, y, a, b]//FunctionExpand

FullSimplifyを使ってベータ関数を簡約する：

Wolfram Language code: FullSimplify[Beta[2 a, 2 b]Beta[b, b] / (Beta[a, b] Beta[a + 1 / 2, b])]

再帰関係：

Wolfram Language code: FullSimplify[Beta[a, b] == (a + b/a)Beta[a + 1, b]]

Wolfram Language code: FullSimplify[Beta[a, b] == Beta[a + 1, b] + Beta[a, b + 1]]

積の関係：

Wolfram Language code: FullSimplify[Beta[a, b]Beta[a + b, c] == Beta[b, c]Beta[b + c, a]]

関数表現 (6)

Gamma関数による主定義：

Wolfram Language code: FunctionExpand[Beta[a, b]]

一般化された不完全ベータ関数を不完全ベータ関数に簡約する：

Wolfram Language code: Beta[z1, z2, a, b]//FunctionExpand

オイラーのベータ関数の積分表現：

Wolfram Language code: Beta[a, b] == Integrate[x^a - 1(1 - x)^b - 1, {x, 0, 1}, Assumptions -> {Re[a] > 0, Re[b] > 0}]//FullSimplify

不完全ベータ関数の積分表現：

Wolfram Language code: Integrate[x^a - 1(1 - x)^b - 1, {x, 0, z}, Assumptions -> {Re[a] > 0 && z ≤ 1}]

BetaはMeijerGによって表すことができる：

Wolfram Language code: MeijerGReduce[Beta[x, a, b], x]

Wolfram Language code: Activate[%]//FullSimplify

BetaはDifferentialRootとして表すことができる：

Wolfram Language code: DifferentialRootReduce[Beta[x, a, b], x]

一般化と拡張 (6)

オイラーのベータ関数 (2)

特別な場合は記号的に評価する：

Wolfram Language code: Beta[0, n]

Betaは要素単位でリストに縫い込まれる：

Wolfram Language code: Beta[2, {2, 3, 4, 5}]

不完全ベータ関数 (2)

整数次と半整数次において記号的に評価する：

Wolfram Language code: Beta[z, 3, b] // FunctionExpand

Wolfram Language code: Beta[13 / 2, 7 / 2, 9 / 2] // FunctionExpand//Simplify

任意の点における級数展開：

Wolfram Language code: Series[Beta[z, a, b], {z, z0, 2}]

Wolfram Language code: Series[Beta[z, a, b], {a, a0, 1}]

一般化された不完全ベータ関数 (2)

一般化された不完全ベータ関数は不完全ベータ関数に関連している：

Wolfram Language code: Beta[x, y, a, b]//FunctionExpand

記号的に評価する：

Wolfram Language code: Beta[1 / 4, 1 / 3, 1 / 2, 3 / 2]//FunctionExpand//Simplify

アプリケーション (5)

正の実数についてベータ関数をプロットする：

Wolfram Language code: Plot3D[Beta[a, b], {a, 0, 2}, {b, 0, 2}]

複素平面でBetaの絶対値をプロットする：

Wolfram Language code: Plot3D[Abs[Beta[x + I y, -3.1]], {x, -5, 2}, {y, -1, 1}]

d次元の超球における点のすべてのペアの平均距離sの分布：

Wolfram Language code: p[d_, s_] := d s ^ (d - 1) Beta[1 - s ^ 2 / 4, (d + 1) / 2, 1 / 2] / Beta[(d + 1) / 2, 1 / 2]

低次元の分布は初等関数で表すことができる：

Wolfram Language code: Table[FullSimplify[FunctionExpand[p[d, s]], s > 0], {d, 3}]

分布をプロットする：

Wolfram Language code: Plot[Evaluate[Table[p[d, s], {d, 10}]], {s, 0, 2}]

確率変数のベータ分布のPDF：

Wolfram Language code: PDF[BetaDistribution[α, β]][x]

PDFをさまざまなパラメータでプロットする：

Wolfram Language code:

Plot[Evaluate[Flatten[Table[PDF[BetaDistribution[α, β]][x], {α, {1, 2, 3, 4} / 4}, {β, {1, 2, 3, 4} / 4}]]], {x, 0, 1}]

平均を計算する：

Wolfram Language code: Mean[BetaDistribution[α, β]]

（容量）を超える同時サービス要求が行われる確率は，Gamma関数とBeta関数で表すことができる：

Wolfram Language code: Probability[x > c, xBinomialDistribution[n, p], Assumptions -> c∈Integers && 0 ≤ c ≤ n]

特性と関係 (7)

オイラーのベータ関数をオイラーのガンマ関数の割合として表す：

Wolfram Language code: FunctionExpand[Beta[a, b]]

一般化された不完全ベータ関数を不完全ベータ関数に還元する：

Wolfram Language code: Beta[z1, z2, a, b]//FunctionExpand

FullSimplifyを使ってベータ関数を簡約する：

Wolfram Language code: FullSimplify[Beta[2 a, 2 b]Beta[b, b] / (Beta[a, b] Beta[a + 1 / 2, b])]

超越方程式の根を数値的に求める：

Wolfram Language code: FindRoot[Beta[1, z] - 4 Beta[2, z ^ 2] + z == 2, {z, 1}]

Betaを含む式の総和を求める：

Wolfram Language code: Underoverscript[∑, k = 1, n]Beta[k, k]

Wolfram Language code: Underoverscript[∑, k = 1, n](z^k/Beta[k, 2k])

母関数：

Wolfram Language code: Underoverscript[∑, k = 1, ∞]Beta[k, b] x^k

超幾何関数の特殊ケースとして得る：

Wolfram Language code: z^aHypergeometric2F1[a, 1 - b, 1 + a, z]//FullSimplify

BetaはDifferentialRootとして表すことができる：

Wolfram Language code: DifferenceRootReduce[Beta[k, z], k]

考えられる問題 (4)

大きい引数は，明示的に計算するのには小さすぎる結果を与えることがある：

Wolfram Language code: Beta[10 ^ 20., 10. ^ 20]

機械数の入力が高精度の結果を与えることがある：

Wolfram Language code: Beta[10. ^ 3, 10. ^ 3]

Wolfram Language code: MachineNumberQ[%]

アルゴリズムを使って生成した結果では，ベータ関数ではなくガンマ関数や超幾何関数が使われることがよくある：

Wolfram Language code: Underoverscript[∑, k = 0, ∞](Pochhammer[1 - b, k]/(a + k) k!)

Wolfram Language code: Integrate[t^a - 1 (1 - t)^b - 1, {t, 0, 1}, Assumptions -> Re[a] > 0∧Re[b] > 0]

Wolfram Language code: (1/a + b - 1)Underoverscript[∏, k = 1, ∞](k (a + b + k - 2)/(a + k - 1) (b + k - 1))

Wolfram Language code:

eq = z (1 - z) w''[z] + (1 - a + (a + b - 2) z)w'[z];
DSolve[eq == 0 , w[z], z]

微分方程式は不完全ベータ関数によって満足される：

Wolfram Language code: eq /. w -> (Beta[#, a, b + 1] + Beta[#, a + 1, b]&)//Simplify

一般に，FullSimplifyではベータ関数は生成されない：

Wolfram Language code: Beta[a, b]//FunctionExpand

Wolfram Language code: FullSimplify[%]

おもしろい例題 (2)

複素平面上でBetaをネストさせる：

Wolfram Language code: DensityPlot[Arg[Nest[Beta[#, #]&, x + I y, 3]], {x, -2, 4}, {y, -2, 2}, Exclusions -> {}]//Quiet

成分がベータ関数の逆数であるベータ行列を定義する：

Wolfram Language code: betaMatrix[n_] := 1 / Array[Beta, {n, n}]

ベータ行列の行列式はである：

Wolfram Language code: Table[Det[betaMatrix[n]], {n, 10}]

Wolfram Language code: FindSequenceFunction[%, n]

ベータ行列は対称正定値で，そのコスキー(Cholesky)分解はの形の成分を持つ：

Wolfram Language code: Table[CholeskyDecomposition[betaMatrix[n]] == Array[Sqrt[#1]Binomial[#2, #1]&, {n, n}], {n, 10}]

Top

その他のラーニングリソース

テクニカルサポート

データサイエンス，金融，ビジネス

工学

科学とテクノロジー

教育のためのテクノロジー

教育イニシアチブ

使い始める

Grow Your Skills

Wolframと繋がる

大人用の教育プログラム

若者のための教育プログラム

読む

Beta

詳細

例題

例 (6)

スコープ (42)

数値評価 (8)

特定の値 (4)

可視化 (2)

関数の特性 (11)

微分 (2)

級数展開 (5)

関数の恒等式と簡約 (4)

関数表現 (6)

一般化と拡張 (6)

オイラーのベータ関数 (2)

不完全ベータ関数 (2)

一般化された不完全ベータ関数 (2)

アプリケーション (5)

特性と関係 (7)

考えられる問題 (4)

おもしろい例題 (2)

テキスト

CMS

APA

BibTeX

BibLaTeX

Beta

詳細

例題

例 (6)

スコープ (42)

数値評価 (8)

特定の値 (4)

可視化 (2)

関数の特性 (11)

微分 (2)

級数展開 (5)

関数の恒等式と簡約 (4)

関数表現 (6)

一般化と拡張 (6)

オイラーのベータ関数 (2)

不完全ベータ関数 (2)

一般化された不完全ベータ関数 (2)

アプリケーション (5)

特性と関係 (7)

考えられる問題 (4)

おもしろい例題 (2)

関連項目

テクニカルノート

関連するガイド

関連リンク

履歴

テキスト

CMS

APA

BibTeX

BibLaTeX