WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

BlomqvistBetaTest[v1,v2]

ベクトル v1と v2が独立であるかどうかの検定を行う．

BlomqvistBetaTest[m1,m2]

行列 m1と m2が独立であるかどうかの検定を行う．

BlomqvistBetaTest[…,"property"]

"property"の値を返す．

詳細とオプション
Details and Options Details and Options
例題  
例  
スコープ  
検定  
レポート  
オプション  
AlternativeHypothesis  
MaxIterations  
Method  
SignificanceLevel  
特性と関係  
関連項目
関連するガイド
履歴
引用書式

BlomqvistBetaTest

BlomqvistBetaTest[v1,v2]

ベクトル v1と v2が独立であるかどうかの検定を行う．

BlomqvistBetaTest[m1,m2]

行列 m1と m2が独立であるかどうかの検定を行う．

BlomqvistBetaTest[…,"property"]

"property"の値を返す．

詳細とオプション

  • BlomqvistBetaTestは，v1と v2に対して，ベクトルが独立であるという帰無仮説 と，そうではないという対立仮説 で仮説検定を行う．
  • デフォルトで，確率の値すなわち 値が返される．
  • 小さい 値は が真である確率が低いことを示唆する．
  • 引数 v1と v2は任意の実数値で同じ長さのベクトルあるいは行列でよい．
  • BlomqvistBetaTestは，BlomqvistBeta[v1,v2]で計算されたBlomqvistの中間相関係数 β に基づいている．
  • 行列の検定のとき，検定統計は内部的な標準化された空間符号に基づいており，ChiSquareDistribution[r*s]に漸近的に従う．ただし，r と s はそれぞれ m1と m2の次元である．検定統計量はアフィン変換の下では不変である．
  • BlomqvistBetaTest[v1,v2,"HypothesisTestData"]は，htd["property"]の形で追加的な検定結果と特性の抽出に使えるHypothesisTestDataオブジェクト htd を返す．
  • BlomqvistBetaTest[v1,v2,"property"]を使って"property"の値を直接与えることができる．
  • 検定結果のレポートに関連する特性
  • "DegreesOfFreedom"検定に使われる自由度
    "PValue"検定の 値
    "PValueTable" 値を含むフォーマットされた表
    "ShortTestConclusion"検定結果の短い記述
    "TestConclusion"検定結果の記述
    "TestData"検定統計量と 値を含むリスト
    "TestDataTable" 値と検定統計量のフォーマットされた表
    "TestStatistic"検定統計量
    "TestStatisticTable"検定統計量を含むフォーマットされた表
  • 使用可能なオプション
  • AlternativeHypothesis "Unequal"対立仮説のための不等式
    MaxIterations Automatic多変量検定のための最大反復回数
    Method Automatic 値の計算に使うメソッド
    SignificanceLevel 0.05診断とレポートのための切捨て
  • 独立性の検定については， のときにのみ が拒絶されるような切捨て が選ばれる．"TestConclusion"特性と"ShortTestConclusion"特性に使われる の値はSignificanceLevelオプションで制御される．デフォルトで， は0.05に設定されている．

例題

すべて開く すべて閉じる

例  (2)

2つのベクトルが独立かどうかの検定を行う：

Wolfram Language code: {v1, v2} = Transpose[RandomVariate[BinormalDistribution[-.8], 100]];
Wolfram Language code: ListPlot[Transpose[{v1, v2}]]
Wolfram Language code: BlomqvistBetaTest[v1, v2, "TestDataTable"]

2つの行列が独立かどうかの検定を行う：

Wolfram Language code: BlockRandom[ SeedRandom[2]; data1 = RandomVariate[BinormalDistribution[.5], 100]; data2 = RandomVariate[BinormalDistribution[.5], 100]; ]

0.05レベルでは独立性は拒絶するのに十分な証拠はない：

Wolfram Language code: BlomqvistBetaTest[data1, data2, "TestDataTable"]

スコープ  (8)

検定  (5)

2つのベクトルが独立かどうかの検定を行う：

Wolfram Language code: {v1, v2} = Transpose[RandomVariate[BinormalDistribution[0], 100]];
Wolfram Language code: {v3, v4} = Transpose[RandomVariate[BinormalDistribution[.7], 100]];

ベクトルが独立のとき， 値は一般に大きくなる：

Wolfram Language code: BlomqvistBetaTest[v1, v2]

ベクトルが従属関係にあるときは， 値は一般に小さくなる：

Wolfram Language code: BlomqvistBetaTest[v3, v4]

2つの行列が独立かどうかの検定を行う：

Wolfram Language code: Σ1 = {{12.8, 0.3, 3., -1.5, 5.1}, {0.3, 2.4, 0.9, -0.3, -0.8}, {3., 0.9, 6.5, 0.8, 1.3}, {-1.5, -0.3, 0.8, 1.4, 2.}, {5.1, -0.8, 1.3, 2., 11.1}};
Wolfram Language code: data1 = RandomVariate[MultinormalDistribution[{0, 0, 0, 0, 0}, Σ1], 100];

行列が従属関係にあるとき， 値は一般に小さくなる：

Wolfram Language code: BlomqvistBetaTest[data1[[All, 1 ;; 2]], data1[[All, 3 ;; 5]]]

行列が独立のとき， 値は一般に大きくなる：

Wolfram Language code: Σ2 = IdentityMatrix[5];
Wolfram Language code: data2 = RandomVariate[MultinormalDistribution[{0, 0, 0, 0, 0}, Σ2], 100];
Wolfram Language code: BlomqvistBetaTest[data2[[All, 1 ;; 2]], data2[[All, 3 ;; 5]]]

繰り返して特性を抽出するためのHypothesisTestDataオブジェクトを作る：

Wolfram Language code: {v1, v2} = Transpose[RandomVariate[BinormalDistribution[0], 100]];
Wolfram Language code: ℋ = BlomqvistBetaTest[v1, v2, "HypothesisTestData"];

抽出可能な特性：

Wolfram Language code: ℋ["Properties"]

HypothesisTestDataオブジェクトから特性をいくつか抽出する：

Wolfram Language code: {v1, v2} = Transpose[RandomVariate[BinormalDistribution[0], 100]];
Wolfram Language code: ℋ = BlomqvistBetaTest[v1, v2, "HypothesisTestData"];

検定からの 値と検定統計量：

Wolfram Language code: ℋ["PValue"]
Wolfram Language code: ℋ["TestStatistic"]

任意数の特性を同時に抽出する：

Wolfram Language code: {v1, v2} = Transpose[RandomVariate[BinormalDistribution[0], 100]];
Wolfram Language code: ℋ = BlomqvistBetaTest[v1, v2, "HypothesisTestData"];

検定からの 値と検定統計量：

Wolfram Language code: ℋ["PValue", "TestStatistic"]

レポート  (3)

検定からの結果を表にする：

Wolfram Language code: {v1, v2} = Transpose[RandomVariate[BinormalDistribution[0], 100]];
Wolfram Language code: ℋ = BlomqvistBetaTest[v1, v2, "HypothesisTestData"];

検定結果の表：

Wolfram Language code: ℋ["TestDataTable"]

カスタマイズしたレポートのために検定の表から項目を読み出す：

Wolfram Language code: {v1, v2} = Transpose[RandomVariate[BinormalDistribution[0], 100]];
Wolfram Language code: ℋ = BlomqvistBetaTest[v1, v2, "HypothesisTestData"];
Wolfram Language code: res = ℋ["TestData"]
Wolfram Language code: Labeled[ProgressIndicator[res[[2]]], Row[{Style["β: ", Bold, FontSize -> 14], res[[1]]}]]

値あるいは検定統計量を表にする：

Wolfram Language code: {v1, v2} = Transpose[RandomVariate[BinormalDistribution[0], 100]];
Wolfram Language code: ℋ = BlomqvistBetaTest[v1, v2, "HypothesisTestData"];
Wolfram Language code: ℋ["PValueTable"]

表からの 値：

Wolfram Language code: ℋ["PValue"]
Wolfram Language code: ℋ["TestStatisticTable"]

表からの検定統計量：

Wolfram Language code: ℋ["TestStatistic"]

オプション  (9)

AlternativeHypothesis  (3)

デフォルトで両側検定が行われる：

Wolfram Language code: {v1, v2} = Transpose[RandomVariate[CopulaDistribution[{"Clayton", 1}, {NormalDistribution[], NormalDistribution[]}], 100]];
Wolfram Language code: BlomqvistBetaTest[v1, v2, AlternativeHypothesis -> "Unequal"]
Wolfram Language code: BlomqvistBetaTest[v1, v2, AlternativeHypothesis -> Automatic]

両側検定あるいは代りとなる片側検定を行う：

Wolfram Language code: {v1, v2} = Transpose@RandomVariate[CopulaDistribution[{"Clayton", 3}, {NormalDistribution[], NormalDistribution[]}], 100];

両側検定：

Wolfram Language code: BlomqvistBetaTest[v1, v2, AlternativeHypothesis -> "Unequal"]

代りとなる2つの片側検定：

Wolfram Language code: BlomqvistBetaTest[v1, v2, AlternativeHypothesis -> "Less"]
Wolfram Language code: BlomqvistBetaTest[v1, v2, AlternativeHypothesis -> "Greater"]

多変量検定は本質的に両側検定である：

Wolfram Language code: m = Transpose@RandomVariate[CopulaDistribution[{"Clayton", 3}, {NormalDistribution[], NormalDistribution[], NormalDistribution[], NormalDistribution[]}], 100];
Wolfram Language code: BlomqvistBetaTest[m[[All, 1 ;; 2]], m[[All, 3 ;; 4]], AlternativeHypothesis -> "Less"]

これは帰無分布の形による：

Wolfram Language code: m1 = RandomVariate[BinormalDistribution[0], {250, 50}]; m2 = RandomVariate[BinormalDistribution[0], {250, 50}];
Wolfram Language code: t = MapThread[BlomqvistBetaTest[#1, #2, "TestStatistic"]&, {m1, m2}];
Wolfram Language code: Histogram[t]

MaxIterations  (1)

多変量検定の最大反復回数を設定する：

Wolfram Language code: data1 = RandomVariate[BinormalDistribution[.5], 25]; data2 = RandomVariate[BinormalDistribution[.5], 25];

デフォルトではが使われる：

Wolfram Language code: BlomqvistBetaTest[data1, data2, MaxIterations -> 10000]

設定値を小さくすると計算時間は短くなるが，収束しない可能性がある：

Wolfram Language code: BlomqvistBetaTest[data1, data2, MaxIterations -> 5]

Method  (4)

デフォルトで， 値は漸近的統計分布を使って計算される：

Wolfram Language code: {v1, v2} = Transpose[RandomVariate[CopulaDistribution[{"Clayton", 1}, {NormalDistribution[], NormalDistribution[]}], 100]];
Wolfram Language code: BlomqvistBetaTest[v1, v2, Method -> Automatic]
Wolfram Language code: BlomqvistBetaTest[v1, v2, Method -> "Asymptotic"]

置換法を使って 値を求めることができる：

Wolfram Language code: {v1, v2} = Transpose[RandomVariate[CopulaDistribution[{"Clayton", 3}, {NormalDistribution[], NormalDistribution[]}], 10]];
Wolfram Language code: BlomqvistBetaTest[v1, v2, Method -> "Permutation"]

使用する置換回数を設定する：

Wolfram Language code: {v1, v2} = Transpose[RandomVariate[CopulaDistribution[{"Clayton", 3}, {NormalDistribution[], NormalDistribution[]}], 10]];
Wolfram Language code: BlomqvistBetaTest[v1, v2, Method -> {"Permutation", "MonteCarloSamples" -> 10^4}]

デフォルトで，回のランダムな置換が行われる：

Wolfram Language code: BlomqvistBetaTest[v1, v2, Method -> {"Permutation", "MonteCarloSamples" -> 10^3}]
Wolfram Language code: BlomqvistBetaTest[v1, v2, Method -> {"Permutation", "MonteCarloSamples" -> Automatic}]

ランダムな置換の生成に使うシードを設定する：

Wolfram Language code: {v1, v2} = Transpose[RandomVariate[CopulaDistribution[{"Clayton", 3}, {NormalDistribution[], NormalDistribution[]}], 10]];
Wolfram Language code: BlomqvistBetaTest[v1, v2, Method -> {"Permutation", "RandomSeed" -> 0}]
Wolfram Language code: BlomqvistBetaTest[v1, v2, Method -> {"Permutation", "RandomSeed" -> 9}]

SignificanceLevel  (1)

"TestConclusion"と"ShortTestConclusion"には有意水準が使われる：

Wolfram Language code: BlockRandom[SeedRandom[3];{v1, v2} = Transpose@RandomVariate[CopulaDistribution[{"Clayton", 2}, {NormalDistribution[], NormalDistribution[]}], 100];];
Wolfram Language code: ℋ1 = BlomqvistBetaTest[v1, v2, "HypothesisTestData", SignificanceLevel -> .1];
Wolfram Language code: ℋ2 = BlomqvistBetaTest[v1, v2, "HypothesisTestData", SignificanceLevel -> .01];
Wolfram Language code: ℋ1["TestConclusion"]//TraditionalForm
Wolfram Language code: ℋ2["TestConclusion"]//TraditionalForm
Wolfram Language code: ℋ1["ShortTestConclusion"]
Wolfram Language code: ℋ2["ShortTestConclusion"]

特性と関係  (4)

ベクトル間の比較では，検定統計量はBlomqvistBetaとして計算される：

Wolfram Language code: v1 = RandomVariate[NormalDistribution[], 100]; v2 = RandomVariate[NormalDistribution[], 100];
Wolfram Language code: BlomqvistBetaTest[v1, v2, "TestStatistic"]
Wolfram Language code: BlomqvistBeta[v1, v2]

行列間の比較では，検定統計量はアフィン変換の下で不変である：

Wolfram Language code: m = RandomVariate[MultinormalDistribution[{1, 2, 3, 4}, {{12.8, 0.3, 3., -1.5}, {0.3, 2.4, 0.9, -0.3}, {3., 0.9, 6.5, 0.8}, {-1.5, -0.3, 0.8, 1.4}}], 100];
Wolfram Language code: 𝒯 = AffineTransform[{{{1, 2}, {3, 4}}, {1, 2}}];
Wolfram Language code: BlomqvistBetaTest[m[[All, 1 ;; 2]], m[[All, 3 ;; 4]], "TestDataTable"]
Wolfram Language code: BlomqvistBetaTest[𝒯[m[[All, 1 ;; 2]]], 𝒯[m[[All, 3 ;; 4]]], "TestDataTable"]

IndependenceTestを使って独立性についての適切な検定を選ぶことができる：

Wolfram Language code: v1 = RandomVariate[NormalDistribution[], 100]; v2 = RandomVariate[NormalDistribution[], 100];
Wolfram Language code: IndependenceTest[v1, v2, "TestDataTable"]

BlomqvistBetaTestは使用できる検定の一つである：

Wolfram Language code: IndependenceTest[v1, v2, {"TestDataTable", "BlomqvistBeta"}]

BlomqvistBetaTestは単調依存しか検出しない：

Wolfram Language code: x = Sort[RandomReal[{-1, 1}, 250]]; y = Tan[x] ^ 3 + RandomReal[{-.25, .25}, 250]; z = Tan[x] ^ 4 + RandomReal[{-.25, .25}, 250];
Wolfram Language code: ListPlot[Transpose[#], Frame -> True]& /@ {{x, y}, {x, z}}
Wolfram Language code: BlomqvistBetaTest[x, y]
Wolfram Language code: BlomqvistBetaTest[x, z]

HoeffdingDTestを使ってより幅広い従属構造を検出することができる：

Wolfram Language code: HoeffdingDTest[x, y]
Wolfram Language code: HoeffdingDTest[x, z]
Wolfram Research (2012), BlomqvistBetaTest, Wolfram言語関数， https://reference.wolfram.com/language/ref/BlomqvistBetaTest.html.

テキスト

Wolfram Research (2012), BlomqvistBetaTest, Wolfram言語関数， https://reference.wolfram.com/language/ref/BlomqvistBetaTest.html.

CMS

Wolfram Language. 2012. "BlomqvistBetaTest." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/BlomqvistBetaTest.html.

APA

Wolfram Language. (2012). BlomqvistBetaTest. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/BlomqvistBetaTest.html

BibTeX

@misc{reference.wolfram_2026_blomqvistbetatest, author="Wolfram Research", title="{BlomqvistBetaTest}", year="2012", howpublished="\url{https://reference.wolfram.com/language/ref/BlomqvistBetaTest.html}", note=[Accessed: 09-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_blomqvistbetatest, organization={Wolfram Research}, title={BlomqvistBetaTest}, year={2012}, url={https://reference.wolfram.com/language/ref/BlomqvistBetaTest.html}, note=[Accessed: 09-August-2026]}