WOLFRAM

Wolfram 语言与系统参考资料中心

BlomqvistBetaTest[v1,v2]

检验向量 v1 与 v2 是否线性独立.

BlomqvistBetaTest[m1,m2]

检验矩阵 v1 与 v2 是否线性独立.

BlomqvistBetaTest[…,"property"]

返回 "property" 的值.

更多信息和选项
Details and Options Details and Options
范例  
基本范例  
范围  
检验  
报告  
选项  
AlternativeHypothesis  
MaxIterations  
Method  
SignificanceLevel  
属性和关系  
参见
相关指南
历史
按以下格式引用：

BlomqvistBetaTest

BlomqvistBetaTest[v1,v2]

检验向量 v1 与 v2 是否线性独立.

BlomqvistBetaTest[m1,m2]

检验矩阵 v1 与 v2 是否线性独立.

BlomqvistBetaTest[…,"property"]

返回 "property" 的值.

更多信息和选项

  • BlomqvistBetaTest 在 v1 和 v2 上执行假设检验，向量是线性独立的为零假设 ，它们不是线性独立的为替代假设 .
  • 缺省时返回一个概率值，即 值.
  • 如果 值较小，则 是 true 的可能性较小.
  • 参变量 v1 和 v2 可以是任何等长的实数值向量或者矩阵.
  • BlomqvistBetaTest 基于由 BlomqvistBeta[v1,v2] 计算得到的 Blomqvist 的中间相关系数 β.
  • 对于矩阵检验，检验统计量基于内部标准化的空间符号，并渐进地服从 ChiSquareDistribution[r*s]，其中 r 和 s 分别是 m1 和 m2 的维度. 检验统计量在仿射变换下是不变的.
  • BlomqvistBetaTest[v1,v2,"HypothesisTestData"] 返回一个 HypothesisTestData 对象 htd，该对象可利用形式 htd["property"] 提取额外的检验结果与性质.
  • BlomqvistBetaTest[v1,v2,"property"] 可以直接给出 "property" 的值.
  • 与检验结果报告相关的性质包括：
  • "DegreesOfFreedom"检验中使用的自由度
    "PValue"检验中的 值
    "PValueTable"包含 值的格式化的表格
    "ShortTestConclusion"一个检验结论的简短描述
    "TestConclusion"一个检验结论的描述
    "TestData"包含检验统计量与 值的列表
    "TestDataTable" 值和检验统计量的格式化表格
    "TestStatistic"检验统计量
    "TestStatisticTable"包含检验统计量的格式化表格
  • 可以给出以下选项：
  • AlternativeHypothesis "Unequal"替代假设的不等性
    MaxIterations Automatic多变量检验的最大迭代次数
    Method Automatic计算 值所用的方法
    SignificanceLevel 0.05诊断和报告的分界点
  • 对于独立检验，选择一个临界值 ，以使得只有当 时，否定 . 用于 "TestConclusion" 和 "ShortTestConclusion" 属性的 值由 SignificanceLevel 选项控制. 默认情况下， 设为 0.05.

范例

打开所有单元 关闭所有单元

基本范例  (2)

检验两个向量是否独立：

Wolfram Language code: {v1, v2} = Transpose[RandomVariate[BinormalDistribution[-.8], 100]];
Wolfram Language code: ListPlot[Transpose[{v1, v2}]]
Wolfram Language code: BlomqvistBetaTest[v1, v2, "TestDataTable"]

检验两个矩阵是否独立：

Wolfram Language code: BlockRandom[ SeedRandom[2]; data1 = RandomVariate[BinormalDistribution[.5], 100]; data2 = RandomVariate[BinormalDistribution[.5], 100]; ]

在 0.05 水平上，没有足够的证据拒绝独立性：

Wolfram Language code: BlomqvistBetaTest[data1, data2, "TestDataTable"]

范围  (8)

检验  (5)

检验两个向量是否独立：

Wolfram Language code: {v1, v2} = Transpose[RandomVariate[BinormalDistribution[0], 100]];
Wolfram Language code: {v3, v4} = Transpose[RandomVariate[BinormalDistribution[.7], 100]];

当向量是独立的， 值一般较大：

Wolfram Language code: BlomqvistBetaTest[v1, v2]

当向量是相关的， 值一般较小：

Wolfram Language code: BlomqvistBetaTest[v3, v4]

检验两个矩阵是否独立：

Wolfram Language code: Σ1 = {{12.8, 0.3, 3., -1.5, 5.1}, {0.3, 2.4, 0.9, -0.3, -0.8}, {3., 0.9, 6.5, 0.8, 1.3}, {-1.5, -0.3, 0.8, 1.4, 2.}, {5.1, -0.8, 1.3, 2., 11.1}};
Wolfram Language code: data1 = RandomVariate[MultinormalDistribution[{0, 0, 0, 0, 0}, Σ1], 100];

当矩阵是相关的， 值一般较小：

Wolfram Language code: BlomqvistBetaTest[data1[[All, 1 ;; 2]], data1[[All, 3 ;; 5]]]

当矩阵是独立的， 值一般较大：

Wolfram Language code: Σ2 = IdentityMatrix[5];
Wolfram Language code: data2 = RandomVariate[MultinormalDistribution[{0, 0, 0, 0, 0}, Σ2], 100];
Wolfram Language code: BlomqvistBetaTest[data2[[All, 1 ;; 2]], data2[[All, 3 ;; 5]]]

为重复的属性提取，创建一个 HypothesisTestData 对象：

Wolfram Language code: {v1, v2} = Transpose[RandomVariate[BinormalDistribution[0], 100]];
Wolfram Language code: ℋ = BlomqvistBetaTest[v1, v2, "HypothesisTestData"];

可提取的属性：

Wolfram Language code: ℋ["Properties"]

从 HypothesisTestData 对象中提取某些属性：

Wolfram Language code: {v1, v2} = Transpose[RandomVariate[BinormalDistribution[0], 100]];
Wolfram Language code: ℋ = BlomqvistBetaTest[v1, v2, "HypothesisTestData"];

检验中的 值和检验统计量：

Wolfram Language code: ℋ["PValue"]
Wolfram Language code: ℋ["TestStatistic"]

同时提取任何数量的属性：

Wolfram Language code: {v1, v2} = Transpose[RandomVariate[BinormalDistribution[0], 100]];
Wolfram Language code: ℋ = BlomqvistBetaTest[v1, v2, "HypothesisTestData"];

值、检验统计量：

Wolfram Language code: ℋ["PValue", "TestStatistic"]

报告  (3)

把检验结果制表：

Wolfram Language code: {v1, v2} = Transpose[RandomVariate[BinormalDistribution[0], 100]];
Wolfram Language code: ℋ = BlomqvistBetaTest[v1, v2, "HypothesisTestData"];

检验结果的表格：

Wolfram Language code: ℋ["TestDataTable"]

从检验表格中提取项以便自定义报表：

Wolfram Language code: {v1, v2} = Transpose[RandomVariate[BinormalDistribution[0], 100]];
Wolfram Language code: ℋ = BlomqvistBetaTest[v1, v2, "HypothesisTestData"];
Wolfram Language code: res = ℋ["TestData"]
Wolfram Language code: Labeled[ProgressIndicator[res[[2]]], Row[{Style["β: ", Bold, FontSize -> 14], res[[1]]}]]

对 值或检验统计制表：

Wolfram Language code: {v1, v2} = Transpose[RandomVariate[BinormalDistribution[0], 100]];
Wolfram Language code: ℋ = BlomqvistBetaTest[v1, v2, "HypothesisTestData"];
Wolfram Language code: ℋ["PValueTable"]

表格中的 值：

Wolfram Language code: ℋ["PValue"]
Wolfram Language code: ℋ["TestStatisticTable"]

表格中的检验统计量：

Wolfram Language code: ℋ["TestStatistic"]

选项  (9)

AlternativeHypothesis  (3)

默认情况下，执行双边检验：

Wolfram Language code: {v1, v2} = Transpose[RandomVariate[CopulaDistribution[{"Clayton", 1}, {NormalDistribution[], NormalDistribution[]}], 100]];
Wolfram Language code: BlomqvistBetaTest[v1, v2, AlternativeHypothesis -> "Unequal"]
Wolfram Language code: BlomqvistBetaTest[v1, v2, AlternativeHypothesis -> Automatic]

执行双边检验或替代的单边检验：

Wolfram Language code: {v1, v2} = Transpose@RandomVariate[CopulaDistribution[{"Clayton", 3}, {NormalDistribution[], NormalDistribution[]}], 100];

双边检验：

Wolfram Language code: BlomqvistBetaTest[v1, v2, AlternativeHypothesis -> "Unequal"]

替代的两个单边检验：

Wolfram Language code: BlomqvistBetaTest[v1, v2, AlternativeHypothesis -> "Less"]
Wolfram Language code: BlomqvistBetaTest[v1, v2, AlternativeHypothesis -> "Greater"]

多变量检验是两侧的：

Wolfram Language code: m = Transpose@RandomVariate[CopulaDistribution[{"Clayton", 3}, {NormalDistribution[], NormalDistribution[], NormalDistribution[], NormalDistribution[]}], 100];
Wolfram Language code: BlomqvistBetaTest[m[[All, 1 ;; 2]], m[[All, 3 ;; 4]], AlternativeHypothesis -> "Less"]

这是由于空分布的形状：

Wolfram Language code: m1 = RandomVariate[BinormalDistribution[0], {250, 50}]; m2 = RandomVariate[BinormalDistribution[0], {250, 50}];
Wolfram Language code: t = MapThread[BlomqvistBetaTest[#1, #2, "TestStatistic"]&, {m1, m2}];
Wolfram Language code: Histogram[t]

MaxIterations  (1)

设置用于多变量检验的最大迭代次数：

Wolfram Language code: data1 = RandomVariate[BinormalDistribution[.5], 25]; data2 = RandomVariate[BinormalDistribution[.5], 25];

默认情况下，使用 ：

Wolfram Language code: BlomqvistBetaTest[data1, data2, MaxIterations -> 10000]

降低设置可能缩短计算时间，但是可能导致不收敛：

Wolfram Language code: BlomqvistBetaTest[data1, data2, MaxIterations -> 5]

Method  (4)

默认情况下，使用渐近检验统计量分布计算 值：

Wolfram Language code: {v1, v2} = Transpose[RandomVariate[CopulaDistribution[{"Clayton", 1}, {NormalDistribution[], NormalDistribution[]}], 100]];
Wolfram Language code: BlomqvistBetaTest[v1, v2, Method -> Automatic]
Wolfram Language code: BlomqvistBetaTest[v1, v2, Method -> "Asymptotic"]

使用排列 (Permutation) 方法可获取 值：

Wolfram Language code: {v1, v2} = Transpose[RandomVariate[CopulaDistribution[{"Clayton", 3}, {NormalDistribution[], NormalDistribution[]}], 10]];
Wolfram Language code: BlomqvistBetaTest[v1, v2, Method -> "Permutation"]

设置使用的排列数：

Wolfram Language code: {v1, v2} = Transpose[RandomVariate[CopulaDistribution[{"Clayton", 3}, {NormalDistribution[], NormalDistribution[]}], 10]];
Wolfram Language code: BlomqvistBetaTest[v1, v2, Method -> {"Permutation", "MonteCarloSamples" -> 10^4}]

默认情况下，使用 随机排列：

Wolfram Language code: BlomqvistBetaTest[v1, v2, Method -> {"Permutation", "MonteCarloSamples" -> 10^3}]
Wolfram Language code: BlomqvistBetaTest[v1, v2, Method -> {"Permutation", "MonteCarloSamples" -> Automatic}]

设置产生随机排列的种子：

Wolfram Language code: {v1, v2} = Transpose[RandomVariate[CopulaDistribution[{"Clayton", 3}, {NormalDistribution[], NormalDistribution[]}], 10]];
Wolfram Language code: BlomqvistBetaTest[v1, v2, Method -> {"Permutation", "RandomSeed" -> 0}]
Wolfram Language code: BlomqvistBetaTest[v1, v2, Method -> {"Permutation", "RandomSeed" -> 9}]

SignificanceLevel  (1)

显著性水平用于 "TestConclusion" 和 "ShortTestConclusion"：

Wolfram Language code: BlockRandom[SeedRandom[3];{v1, v2} = Transpose@RandomVariate[CopulaDistribution[{"Clayton", 2}, {NormalDistribution[], NormalDistribution[]}], 100];];
Wolfram Language code: ℋ1 = BlomqvistBetaTest[v1, v2, "HypothesisTestData", SignificanceLevel -> .1];
Wolfram Language code: ℋ2 = BlomqvistBetaTest[v1, v2, "HypothesisTestData", SignificanceLevel -> .01];
Wolfram Language code: ℋ1["TestConclusion"]//TraditionalForm
Wolfram Language code: ℋ2["TestConclusion"]//TraditionalForm
Wolfram Language code: ℋ1["ShortTestConclusion"]
Wolfram Language code: ℋ2["ShortTestConclusion"]

属性和关系  (4)

对于向量向量比较，检验统计量根据 BlomqvistBeta 计算：

Wolfram Language code: v1 = RandomVariate[NormalDistribution[], 100]; v2 = RandomVariate[NormalDistribution[], 100];
Wolfram Language code: BlomqvistBetaTest[v1, v2, "TestStatistic"]
Wolfram Language code: BlomqvistBeta[v1, v2]

对于矩阵比较，检验统计量在仿射变换下是不变的：

Wolfram Language code: m = RandomVariate[MultinormalDistribution[{1, 2, 3, 4}, {{12.8, 0.3, 3., -1.5}, {0.3, 2.4, 0.9, -0.3}, {3., 0.9, 6.5, 0.8}, {-1.5, -0.3, 0.8, 1.4}}], 100];
Wolfram Language code: 𝒯 = AffineTransform[{{{1, 2}, {3, 4}}, {1, 2}}];
Wolfram Language code: BlomqvistBetaTest[m[[All, 1 ;; 2]], m[[All, 3 ;; 4]], "TestDataTable"]
Wolfram Language code: BlomqvistBetaTest[𝒯[m[[All, 1 ;; 2]]], 𝒯[m[[All, 3 ;; 4]]], "TestDataTable"]

IndependenceTest 可用于自动选择合适的检验：

Wolfram Language code: v1 = RandomVariate[NormalDistribution[], 100]; v2 = RandomVariate[NormalDistribution[], 100];
Wolfram Language code: IndependenceTest[v1, v2, "TestDataTable"]

BlomqvistBetaTest 是已有检验之一：

Wolfram Language code: IndependenceTest[v1, v2, {"TestDataTable", "BlomqvistBeta"}]

BlomqvistBetaTest 只检测单调相关性：

Wolfram Language code: x = Sort[RandomReal[{-1, 1}, 250]]; y = Tan[x] ^ 3 + RandomReal[{-.25, .25}, 250]; z = Tan[x] ^ 4 + RandomReal[{-.25, .25}, 250];
Wolfram Language code: ListPlot[Transpose[#], Frame -> True]& /@ {{x, y}, {x, z}}
Wolfram Language code: BlomqvistBetaTest[x, y]
Wolfram Language code: BlomqvistBetaTest[x, z]

HoeffdingDTest 可用于检测大量相关性结构：

Wolfram Language code: HoeffdingDTest[x, y]
Wolfram Language code: HoeffdingDTest[x, z]
Wolfram Research (2012)，BlomqvistBetaTest，Wolfram 语言函数，https://reference.wolfram.com/language/ref/BlomqvistBetaTest.html.

文本

Wolfram Research (2012)，BlomqvistBetaTest，Wolfram 语言函数，https://reference.wolfram.com/language/ref/BlomqvistBetaTest.html.

CMS

Wolfram 语言. 2012. "BlomqvistBetaTest." Wolfram 语言与系统参考资料中心. Wolfram Research. https://reference.wolfram.com/language/ref/BlomqvistBetaTest.html.

APA

Wolfram 语言. (2012). BlomqvistBetaTest. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/BlomqvistBetaTest.html 年

BibTeX

@misc{reference.wolfram_2026_blomqvistbetatest, author="Wolfram Research", title="{BlomqvistBetaTest}", year="2012", howpublished="\url{https://reference.wolfram.com/language/ref/BlomqvistBetaTest.html}", note=[Accessed: 14-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_blomqvistbetatest, organization={Wolfram Research}, title={BlomqvistBetaTest}, year={2012}, url={https://reference.wolfram.com/language/ref/BlomqvistBetaTest.html}, note=[Accessed: 14-September-2026]}