WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

BondList[mol]

分子 mol の結合のリストを与える．

BondList[mol,patt]

原子パターン patt にマッチする，分子 mol の結合のリストを与える．

BondList[mol,patt,"prop"]

patt にマッチする結合の，指定された特性の値を与える．

詳細とオプション
Details and Options Details and Options
例題  
例  
オプション  
IncludeHydrogens  
考えられる問題  
おもしろい例題  
関連項目
関連するガイド
履歴
引用書式

BondList

BondList[mol]

分子 mol の結合のリストを与える．

BondList[mol,patt]

原子パターン patt にマッチする，分子 mol の結合のリストを与える．

BondList[mol,patt,"prop"]

patt にマッチする結合の，指定された特性の値を与える．

詳細とオプション

  • 次は，patt の可能な形式である．
  • "type"指定された結合タイプを持つ結合
    Bond[{a1,a2},"type"]aiで定義された原子を含む結合
    MoleculePattern[…]1つの結合を含む分子パターン
  • aiは，原子インデックスあるいは原子を表すパターンでよい．
  • 次は，"prop"の可能な値である．
  • "BondIndex"結合インデックス
    "BondLength"指定された原子間のユークリッド距離
    "BondType"結合タイプ
    "ConjugatedBondQ"共役結合
  • デフォルトオプション設定のIncludeHydrogensAllでは，BondListによってすべての結合が返される．オプション値"ExplicitOnly"を使うと暗黙的水素原子との結合が除去できる．

例題

すべて開く すべて閉じる

例  (3)

分子のすべての結合を得る：

Wolfram Language code: BondList[Molecule[{"C", "C", "C", "C", "C", "O", "N", "O"}, {Bond[{1, 2}, "Double"], Bond[{2, 3}, "Single"], Bond[{3, 4}, "Double"], Bond[{4, 5}, "Single"], Bond[{5, 6}, "Single"], Bond[{6, 7}, "Single"], Bond[{7, 8}, "Double"]}, {}]]

炭素炭素結合のみを得る：

Wolfram Language code: BondList[Molecule[{"C", "C", "C", "C", "C", "O", "N", "O"}, {Bond[{1, 2}, "Double"], Bond[{2, 3}, "Single"], Bond[{3, 4}, "Double"], Bond[{4, 5}, "Single"], Bond[{5, 6}, "Single"], Bond[{6, 7}, "Single"], Bond[{7, 8}, "Double"]}, {}], Bond[{"C", "C"}]]

二重結合のみを得る：

Wolfram Language code: BondList[Molecule[{"C", "C", "C", "C", "C", "O", "N", "O"}, {Bond[{1, 2}, "Double"], Bond[{2, 3}, "Single"], Bond[{3, 4}, "Double"], Bond[{4, 5}, "Single"], Bond[{5, 6}, "Single"], Bond[{6, 7}, "Single"], Bond[{7, 8}, "Double"]}, {}], "Double"]

炭素炭素二重結合のみを得る：

Wolfram Language code: BondList[Molecule[{"C", "C", "C", "C", "C", "O", "N", "O"}, {Bond[{1, 2}, "Double"], Bond[{2, 3}, "Single"], Bond[{3, 4}, "Double"], Bond[{4, 5}, "Single"], Bond[{5, 6}, "Single"], Bond[{6, 7}, "Single"], Bond[{7, 8}, "Double"]}, {}], Bond[{"C", "C"}, "Double"]]

パターンを使ってすべての環外結合を求める：

Wolfram Language code: mol = Molecule[{"C", "C", "C", "C", "C", "C", "C", "C", "O", "C", "C", "C", "C", "C", "C", "C", "C", "C", "C", "C", "O", "O", "C", "O", "C", "C", "O", "H", "H", "H", "H", "H", "H", "H", "H", "H", "H", "H", "H", "H", "H", "H", "H", "H", "H", "H", "H ... "Counterclockwise"], Association["StereoType" -> "Tetrahedral", "ChiralCenter" -> 26, "Direction" -> "Clockwise"], Association["StereoType" -> "DoubleBond", "StereoBond" -> {10, 11}, "Value" -> "Opposite", "Ligands" -> {7, 12}]}}]
Wolfram Language code: BondList[mol, Bond[{Atom["RingAtomQ" -> True], Atom[Except["H"], "RingAtomQ" -> False]}]]

MoleculePlotに結果を与えて，結合を所定の位置で可視化する：

Wolfram Language code: MoleculePlot[mol, %]

異なるタイプの炭素結合について，結合の長さを比較する：

Wolfram Language code: m = Molecule[Entity["Chemical", "4Allyloxybenzaldehyde"]]
Wolfram Language code: BondList[m, Bond[{"C", "H"}], "BondLength"]//Mean
Wolfram Language code: BondList[m, Bond[{"C", "C"}], "BondLength"]//Mean

オプション  (1)

IncludeHydrogens  (1)

BondListは，デフォルトで，すべての原子を含む：

Wolfram Language code: mol = Molecule["CCO"]
Wolfram Language code: BondList[mol]

IncludeHydrogensNoneを使って原子の大部分を占める水素を除去する：

Wolfram Language code: BondList[mol, IncludeHydrogens -> None]

これは，水素原子を除去するパターンを使うことに等しい：

Wolfram Language code: % === BondList[mol, Bond[{Except["H"], Except["H"]}]]

考えられる問題  (2)

芳香結合は，視覚的には単結合あるい二重結合として表示される：

Wolfram Language code: m = Molecule["(Z)-2-(furan-2-yl)-3-(5-nitrothiophen-2-yl)prop-2-enamide"]; MoleculePlot[m]

芳香結合を含まない"Double"結合の数を尋ねる：

Wolfram Language code: BondList[m, Bond[_, "Double"]]

数を数える前にMoleculeModifyを使って芳香結合を単結合または二重結合に変換する：

Wolfram Language code: BondList[MoleculeModify[m, "Kekulize"], Bond[_, "Double"]]

Moleculeは原子価を水素原子で埋めようとするので，もとの分子式には含まれない水素原子が数に含まれる：

Wolfram Language code: m = Molecule[{"O"}, {}]; BondList[m]

暗黙的水素原子を除去したければ，IncludeHydrogens"ExplicitOnly"を使うとよい：

Wolfram Language code: BondList[m, IncludeHydrogens -> "ExplicitOnly"]

MoleculeオプションのValenceFillingNoneを使って水素原子が表示されないようにすることもできる：

Wolfram Language code: m2 = Molecule[{"C"}, {}, ValenceFilling -> None]

結果の分子には結合がない単一の原子が含まれている：

Wolfram Language code: BondList[m2]

おもしろい例題  (1)

ExternalIdentifierによって"PubChem"から取り出したデータを使って分子を作る：

Wolfram Language code: m = Molecule[ExternalIdentifier["PubChemCompoundID", 208908]]

存在する結合タイプと結合の平均長を示すDatasetを作る：

Wolfram Language code: Dataset@GroupBy[ BondList[m, All, {"AtomicSymbol", "BondLength"}], Sort @* First -> Last, Mean]
Wolfram Research (2019), BondList, Wolfram言語関数， https://reference.wolfram.com/language/ref/BondList.html （2020年に更新）.

テキスト

Wolfram Research (2019), BondList, Wolfram言語関数， https://reference.wolfram.com/language/ref/BondList.html （2020年に更新）.

CMS

Wolfram Language. 2019. "BondList." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2020. https://reference.wolfram.com/language/ref/BondList.html.

APA

Wolfram Language. (2019). BondList. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/BondList.html

BibTeX

@misc{reference.wolfram_2026_bondlist, author="Wolfram Research", title="{BondList}", year="2020", howpublished="\url{https://reference.wolfram.com/language/ref/BondList.html}", note=[Accessed: 07-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_bondlist, organization={Wolfram Research}, title={BondList}, year={2020}, url={https://reference.wolfram.com/language/ref/BondList.html}, note=[Accessed: 07-August-2026]}