WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

Boole[expr]

expr がTrueのときは1を，Falseのときは0を返す．

詳細
Details and Options Details and Options
例題  
例  
アプリケーション  
特性と関係  
関連項目
テクニカルノート
関連するガイド
履歴
引用書式

Boole

Boole[expr]

expr がTrueのときは1を，Falseのときは0を返す．

詳細

  • Booleは，アイバーソン(Iverson)の記法，指示関数，特性関数としても知られている．
  • Booleは，通常，述語の論理結合で与えられた領域上の積分と総和を表すために使われる．また，統計におけるカテゴリ変数のダミー変数符号化としても使われる．
  • Boole[expr]は，expr がTrueでもFalseでもないときは変化しない．
  • Boole[expr]はIf[expr,1,0]と実質的に等しい．
  • BooleはListableである．
  • Integrate[f Boole[pred],…]は，pred がTrueである領域で f を積分するのに使うことができる．

例題

すべて開く すべて閉じる

例  (3)

真理値を整数に変換する：

Wolfram Language code: {Boole[False], Boole[True]}

真理値のリストを整数に変換する：

Wolfram Language code: Boole[{True, False, True, True, False}]

不等式 で定義される円板の面積を求める：

Wolfram Language code: Integrate[Boole[x ^ 2 + y ^ 2 ≤ 1], {x, -1, 1}, {y, -1, 1}]

アプリケーション  (4)

不等式で定義された範囲の面積を求める：

Wolfram Language code: ineq = y ^ 2 - 4x ^ 2 + 4x ^ 4 ≤ 0;
Wolfram Language code: Integrate[Boole[ineq], {x, -Infinity, Infinity}, {y, -Infinity, Infinity}]
Wolfram Language code: NIntegrate[Boole[ineq], {x, -Infinity, Infinity}, {y, -Infinity, Infinity}]

その範囲をプロットする：

Wolfram Language code: RegionPlot[ineq, {x, -1, 1}, {y, -1, 1}]

不等式で定義された立体の体積を求める：

Wolfram Language code: ineq = y ^ 2 - 4x ^ 2 + 4x ^ 4 ≤ -z ^ 2;
Wolfram Language code: Integrate[Boole[ineq], {x, -Infinity, Infinity}, {y, -Infinity, Infinity}, {z, -Infinity, Infinity}]
Wolfram Language code: NIntegrate[Boole[ineq], {x, -Infinity, Infinity}, {y, -Infinity, Infinity}, {z, -Infinity, Infinity}]

その立体をプロットする：

Wolfram Language code: RegionPlot3D[ineq, {x, -1, 1}, {y, -1, 1}, {z, -1, 1}]

パラメータ半径の円と正方形の共通部分の面積を求める：

Wolfram Language code: Integrate[Boole[x ^ 2 + y ^ 2 < a], {x, -1, 1}, {y, -1, 1}]
Wolfram Language code: Table[RegionPlot[x ^ 2 + y ^ 2 < a, {x, -1, 1}, {y, -1, 1}], {a, {1 / 2, 3 / 2, 5 / 2}}]

プロットのため，True,False値表を1,0に変換する：

Wolfram Language code: ArrayPlot[Boole[Table[PrimeQ[a ^ b + 3], {a, 50}, {b, 50}]]]

特性と関係  (7)

ブール(Boole)値の逆：

Wolfram Language code: (# != 0)& /@ {1, 0, 1, 1, 1}
Wolfram Language code: Boole[%]

PiecewiseExpandを使ってBooleをPiecewiseに変換する：

Wolfram Language code: PiecewiseExpand[Boole[a]]

条件についての論理操作とBooleに対する算術操作の対応：

Wolfram Language code: Simplify[Boole[a && b] - Min[Boole[a], Boole[b]]]
Wolfram Language code: Simplify[Boole[a || b] - Max[Boole[a], Boole[b]]]
Wolfram Language code: Simplify[Boole[a && b] - Boole[a]Boole[b]]
Wolfram Language code: Simplify[Boole[a || b] - (Boole[a] + Boole[b] - Boole[a]Boole[b])]
Wolfram Language code: Simplify[Boole[!a] - (1 - Boole[a])]

Refine，Simplify，FullSimplifyを使ってBooleを含む式を変換する：

Wolfram Language code: Refine[Boole[x ^ 2 + y ^ 2 < 10 && x > y], (x - 2) ^ 2 + y ^ 2 < 1]
Wolfram Language code: Simplify[Boole[x > y], x == y + 2]

Booleを含む方程式を簡約し，Booleを含む関数を最適化する：

Wolfram Language code: Reduce[Exp[Sin[x]Boole[x ^ 2 + y ^ 2 < 1]] < 1, {x, y}]
Wolfram Language code: Minimize[Exp[Sin[x]Boole[x ^ 2 + y ^ 2 <= 1]], {x, y}]

積分問題でBooleを特性関数として使う：

Wolfram Language code: Integrate[(x ^ 2 + x y + 3y ^ 4)Boole[x ^ 2 + y ^ 2 < 1 && y > x], {x, -Infinity, Infinity}, {y, -Infinity, Infinity}]
Wolfram Language code: NIntegrate[Exp[x ^ 2 + x y + 3y ^ 4]Boole[x ^ 2 + y ^ 2 < 1 && y > x], {x, -Infinity, Infinity}, {y, -Infinity, Infinity}]

Booleは，場合によっては，DifferenceRootとして表すことができる：

Wolfram Language code: DifferenceRootReduce[Boole[Mod[k, 5] == 1], k]
Wolfram Research (2004), Boole, Wolfram言語関数， https://reference.wolfram.com/language/ref/Boole.html （2007年に更新）.

テキスト

Wolfram Research (2004), Boole, Wolfram言語関数， https://reference.wolfram.com/language/ref/Boole.html （2007年に更新）.

CMS

Wolfram Language. 2004. "Boole." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2007. https://reference.wolfram.com/language/ref/Boole.html.

APA

Wolfram Language. (2004). Boole. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/Boole.html

BibTeX

@misc{reference.wolfram_2026_boole, author="Wolfram Research", title="{Boole}", year="2007", howpublished="\url{https://reference.wolfram.com/language/ref/Boole.html}", note=[Accessed: 10-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_boole, organization={Wolfram Research}, title={Boole}, year={2007}, url={https://reference.wolfram.com/language/ref/Boole.html}, note=[Accessed: 10-September-2026]}