WOLFRAM

Wolfram 语言与系统参考资料中心

Boole[expr]

如果 expr 为 True 则返回 1，如果 expr 为 False 则返回 0.

更多信息
Details and Options Details and Options
范例  
基本范例  
应用  
属性和关系  
参见
技术笔记
相关指南
历史
按以下格式引用：

Boole

Boole[expr]

如果 expr 为 True 则返回 1，如果 expr 为 False 则返回 0.

更多信息

  • Boole 也被称为艾弗森括号 (Iverson bracket)、指标函数和特征函数.
  • Boole 通常用于表达由谓词的逻辑组合给出的区域上的积分和. 其也被用作统计学中分类变量的虚拟变量编码.
  • 如果 expr 既非 True 也非 False，则 Boole[expr] 保持不变.
  • Boole[expr] 实际上相当于 If[expr,1,0].
  • Boole 具有属性 Listable.
  • Integrate[f Boole[pred],…] 可用于在 pred 为 True 的积分区域上对 f 进行积分.

范例

打开所有单元 关闭所有单元

基本范例  (3)

将真值转换为整数：

Wolfram Language code: {Boole[False], Boole[True]}

将真值表转换为整数：

Wolfram Language code: Boole[{True, False, True, True, False}]

求由不等式 定义的圆盘面积：

Wolfram Language code: Integrate[Boole[x ^ 2 + y ^ 2 ≤ 1], {x, -1, 1}, {y, -1, 1}]

应用  (4)

求不等式所定义的区域面积：

Wolfram Language code: ineq = y ^ 2 - 4x ^ 2 + 4x ^ 4 ≤ 0;
Wolfram Language code: Integrate[Boole[ineq], {x, -Infinity, Infinity}, {y, -Infinity, Infinity}]
Wolfram Language code: NIntegrate[Boole[ineq], {x, -Infinity, Infinity}, {y, -Infinity, Infinity}]

绘制此区域：

Wolfram Language code: RegionPlot[ineq, {x, -1, 1}, {y, -1, 1}]

求不等式所定义的实体体积：

Wolfram Language code: ineq = y ^ 2 - 4x ^ 2 + 4x ^ 4 ≤ -z ^ 2;
Wolfram Language code: Integrate[Boole[ineq], {x, -Infinity, Infinity}, {y, -Infinity, Infinity}, {z, -Infinity, Infinity}]
Wolfram Language code: NIntegrate[Boole[ineq], {x, -Infinity, Infinity}, {y, -Infinity, Infinity}, {z, -Infinity, Infinity}]

绘制此实体：

Wolfram Language code: RegionPlot3D[ineq, {x, -1, 1}, {y, -1, 1}, {z, -1, 1}]

求半径为参数的圆和正方形的交集面积：

Wolfram Language code: Integrate[Boole[x ^ 2 + y ^ 2 < a], {x, -1, 1}, {y, -1, 1}]
Wolfram Language code: Table[RegionPlot[x ^ 2 + y ^ 2 < a, {x, -1, 1}, {y, -1, 1}], {a, {1 / 2, 3 / 2, 5 / 2}}]

将 True,False 值表转换为 1,0 用以绘图：

Wolfram Language code: ArrayPlot[Boole[Table[PrimeQ[a ^ b + 3], {a, 50}, {b, 50}]]]

属性和关系  (7)

Boole 的逆：

Wolfram Language code: (# != 0)& /@ {1, 0, 1, 1, 1}
Wolfram Language code: Boole[%]

用 PiecewiseExpand 将 Boole 转换为 Piecewise：

Wolfram Language code: PiecewiseExpand[Boole[a]]

条件逻辑运算与 Boole 算术运算之间的对应：

Wolfram Language code: Simplify[Boole[a && b] - Min[Boole[a], Boole[b]]]
Wolfram Language code: Simplify[Boole[a || b] - Max[Boole[a], Boole[b]]]
Wolfram Language code: Simplify[Boole[a && b] - Boole[a]Boole[b]]
Wolfram Language code: Simplify[Boole[a || b] - (Boole[a] + Boole[b] - Boole[a]Boole[b])]
Wolfram Language code: Simplify[Boole[!a] - (1 - Boole[a])]

使用 Refine、Simplify 和 FullSimplify 转换含有 Boole 的表达式：

Wolfram Language code: Refine[Boole[x ^ 2 + y ^ 2 < 10 && x > y], (x - 2) ^ 2 + y ^ 2 < 1]
Wolfram Language code: Simplify[Boole[x > y], x == y + 2]

简化含有 Boole 的方程以及优化含有 Boole 的函数：

Wolfram Language code: Reduce[Exp[Sin[x]Boole[x ^ 2 + y ^ 2 < 1]] < 1, {x, y}]
Wolfram Language code: Minimize[Exp[Sin[x]Boole[x ^ 2 + y ^ 2 <= 1]], {x, y}]

用 Boole 作为积分问题的特征函数：

Wolfram Language code: Integrate[(x ^ 2 + x y + 3y ^ 4)Boole[x ^ 2 + y ^ 2 < 1 && y > x], {x, -Infinity, Infinity}, {y, -Infinity, Infinity}]
Wolfram Language code: NIntegrate[Exp[x ^ 2 + x y + 3y ^ 4]Boole[x ^ 2 + y ^ 2 < 1 && y > x], {x, -Infinity, Infinity}, {y, -Infinity, Infinity}]

某些情况下，Boole 可被表示为 DifferenceRoot：

Wolfram Language code: DifferenceRootReduce[Boole[Mod[k, 5] == 1], k]
Wolfram Research (2004)，Boole，Wolfram 语言函数，https://reference.wolfram.com/language/ref/Boole.html （更新于 2007 年）.

文本

Wolfram Research (2004)，Boole，Wolfram 语言函数，https://reference.wolfram.com/language/ref/Boole.html （更新于 2007 年）.

CMS

Wolfram 语言. 2004. "Boole." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2007. https://reference.wolfram.com/language/ref/Boole.html.

APA

Wolfram 语言. (2004). Boole. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/Boole.html 年

BibTeX

@misc{reference.wolfram_2026_boole, author="Wolfram Research", title="{Boole}", year="2007", howpublished="\url{https://reference.wolfram.com/language/ref/Boole.html}", note=[Accessed: 31-July-2026]}

BibLaTeX

@online{reference.wolfram_2026_boole, organization={Wolfram Research}, title={Boole}, year={2007}, url={https://reference.wolfram.com/language/ref/Boole.html}, note=[Accessed: 31-July-2026]}