Wolfram言語＆システムドキュメントセンター

CDF

CDF[dist,x]

x で評価された分布 dist の累積分布関数を返す．

CDF[dist,{x₁,x₂,…}]

{x₁,x₂,…}で評価された分布 dist についての多変量累積分布関数を返す．

CDF[dist]

累積分布関数を純関数として返す．

詳細

CDF[dist,x]は観測値が x 以下の値を取る確率を返す．
CDF[dist,x]はProbability[ξ≤x,ξdist]に等しい．
CDF[dist,{x₁,…,x_n}]はProbability[ξ₁≤x₁∧⋯∧ξ_n≤x_n,{ξ₁,…,ξ_n}dist]に等しい．
CDF[dist,x]は1-SurvivalFunction[dist,x]に等しい．

例題

すべて開くすべて閉じる

例 (4)

一変量連続分布の累積分布関数：

Wolfram Language code: CDF[StudentTDistribution[ν], x]

Wolfram Language code: Plot[CDF[StudentTDistribution[4], x], {x, -6, 6}, Filling -> Axis]

一変量離散分布の累積分布関数：

Wolfram Language code: CDF[PoissonDistribution[μ], k]

Wolfram Language code: DiscretePlot[CDF[PoissonDistribution[3], k], {k, 0, 10}, ExtentSize -> Right, ExtentMarkers -> {"Filled", "Empty"}]

二変量連続分布の累積分布関数：

Wolfram Language code: Plot3D[CDF[BinormalDistribution[1 / 2], {x, y}], {x, -3, 3}, {y, -3, 3}]

多変量ポアソン分布の累積分布関数：

Wolfram Language code: DiscretePlot3D[CDF[MultivariatePoissonDistribution[5, {2, 3}], {x, y}], {x, 0, 12}, {y, 0, 12}, ExtentSize -> Right]

スコープ (24)

パラメトリック分布 (7)

厳密な数値結果を求める：

Wolfram Language code: CDF[WeibullDistribution[2, 5], 4]

Wolfram Language code: CDF[NegativeBinomialDistribution[20, 1 / 3], 5]

機械精度の結果を求める：

Wolfram Language code: CDF[WeibullDistribution[2, 5], 4.]

連続分布についての任意精度の結果を求める：

Wolfram Language code: CDF[WeibullDistribution[2, 5], N[4, 25]]

厳密ではない母数を持つ離散分布について任意精度の結果を求める：

Wolfram Language code: CDF[NegativeBinomialDistribution[20, N[1 / 3, 30]], 5]

CDFの記号式を入手する：

Wolfram Language code: CDF[ChiSquareDistribution[ν], x]

Wolfram Language code: CDF[UniformDistribution[{{a, b}, {c, d}}], {x, y}]

純関数の結果を入手する：

Wolfram Language code: CDF[GammaDistribution[1, 2]]

値で評価する：

Wolfram Language code: %[3]

CDFは要素単位でリストに縫い込まれる：

Wolfram Language code: CDF[NormalDistribution[], {0.0, 0.2, 0.3}]

多変量分布：

Wolfram Language code: CDF[BinormalDistribution[1 / 2], {{0.0, 0.0}, {0.2, 0.2}, {0.3, 0.3}}]

ノンパラメトリック分布 (4)

ノンパラメトリック分布のCDF：

Wolfram Language code: r = RandomVariate[NormalDistribution[], 10 ^ 4];

Wolfram Language code: CDF[HistogramDistribution[r], 0.2]

Wolfram Language code: CDF[SmoothKernelDistribution[r], 0.2]

Wolfram Language code: CDF[KernelMixtureDistribution[r], 0.2]

Wolfram Language code: CDF[SurvivalDistribution[r], 0.2]

Wolfram Language code: CDF[EmpiricalDistribution[r], 0.2]

Wolfram Language code: CDF[NormalDistribution[], 0.2]

ヒストグラム分布の累積分布関数をプロットする：

Wolfram Language code:

Plot[CDF[HistogramDistribution[RandomVariate[NormalDistribution[], 10 ^ 3]], x]//Evaluate, {x, -3, 3}, Filling -> Axis, Exclusions -> None]

カーネル混合分布の累積分布関数の閉形の式：

Wolfram Language code:

CDF[KernelMixtureDistribution[RandomVariate[GammaDistribution[1, 2], 10
	]], x]

二変量平滑化カーネル分布の累積分布関数のプロット：

Wolfram Language code:

Plot3D[CDF[SmoothKernelDistribution[RandomVariate[BinormalDistribution[1 / 3], 30]], {x, y}]//Evaluate, {x, -4, 4}, {y, -4, 4}, PlotRange -> {0, 1.2}]

派生分布 (10)

独立分布の積：

Wolfram Language code: CDF[ProductDistribution[TriangularDistribution[{2, 4}], TriangularDistribution[{1, 7}]], {x, y}]

Wolfram Language code: Plot3D[%, {x, 1, 5}, {y, 0, 8}, PlotRange -> All, Exclusions -> None]

成分混合分布：

Wolfram Language code: CDF[MixtureDistribution[{1, 4}, {NormalDistribution[a, b], NormalDistribution[c, d]}], x]

Wolfram Language code: Plot[% /. {a -> 0, b -> 1, c -> 6, d -> 3 / 2}, {x, -2, 10}, Filling -> Axis]

離散分布の二次変換：

Wolfram Language code: CDF[TransformedDistribution[x ^ 2, xPoissonDistribution[2]], y]

Wolfram Language code: DiscretePlot[%, {y, 0, 50}]

打切り分布：

Wolfram Language code: CDF[CensoredDistribution[{-2, 4}, CauchyDistribution[0, 1]], x]

Wolfram Language code: Plot[{CDF[CauchyDistribution[0, 1], x], %}, {x, -4, 6}, PlotStyle -> Thick, Filling -> Axis]

切断分布：

Wolfram Language code: CDF[TruncatedDistribution[{2, 3}, TriangularDistribution[{1, 4}]], x]

Wolfram Language code: Plot[{CDF[TriangularDistribution[{1, 4}], x], %}, {x, 1, 5}, Filling -> Axis, Exclusions -> None]

母数混合分布：

Wolfram Language code: CDF[ParameterMixtureDistribution[GeometricDistribution[r], rUniformDistribution[{1 / 2, 2 / 3}]], x]

Wolfram Language code: DiscretePlot[%, {x, 0, 5}, ExtentSize -> {0, 1}]

コピュラ分布：

Wolfram Language code: CDF[CopulaDistribution[{"Frank", 3}, {ExponentialDistribution[2], ExponentialDistribution[5]}], {x, y}]

Wolfram Language code: Plot3D[%, {x, 0, 3}, {y, 0, 3}]

それ自体の確率密度関数で定義される，定式化されている分布：

Wolfram Language code: CDF[ProbabilityDistribution[(Sqrt[2] / Pi)(1 / (1 + x ^ 4)), {x, -Infinity, Infinity}], x]

それ自体の累積分布関数で定義されるもの：

Wolfram Language code: CDF[ProbabilityDistribution[{"CDF", Piecewise[{{-2 + x, 2 ≤ x ≤ 3}, {1, x > 3}}, 0]}, {x, -Infinity, Infinity}], x]

それ自体のSurvivalFunctionで定義されるもの：

Wolfram Language code:

CDF[ProbabilityDistribution[{"SF", Piecewise[{{1 - 2(-2 + x) ^ 2, 2 ≤ x ≤ 5 / 2}, {2(3 - x) ^ 2, 5 / 2 < x ≤ 3}, {1, x < 2}}, 0]}, {x, -Infinity, Infinity}], x]

周辺分布：

Wolfram Language code:

CDF[MarginalDistribution[ProbabilityDistribution[E^-(y^2/2) π^-3 / 2 (1 + x^4)^-1, {x, -∞, ∞}, {y, -∞, ∞}], 2], y]

QuantityDistributionの累積分布関数は，引数が互換単位を持つQuantityであると仮定する：

Wolfram Language code: 𝒟 = ExponentialDistribution[Quantity[2.2, 1 / "Days"]]

Wolfram Language code: CDF[𝒟, t]

次は，数量の直接置換を許す：

Wolfram Language code: % /. t -> Quantity[MixedMagnitude[{3, 20}], MixedUnit[{"Hours", "Minutes"}]]

数量引数を直接使った場合と比較する：

Wolfram Language code: CDF[𝒟, Quantity[MixedMagnitude[{3, 20}], MixedUnit[{"Hours", "Minutes"}]]]

ランダム過程 (3)

離散状態ランダム過程のSliceDistributionについて累積分布関数を求める：

Wolfram Language code: CDF[PoissonProcess[μ][2], x]

Wolfram Language code: DiscretePlot[Evaluate[% /. μ -> 2], {x, 0, 15}, ExtentSize -> 0.5]

連続状態ランダム過程について：

Wolfram Language code: CDF[WienerProcess[][2], x]

Wolfram Language code: Plot[%, {x, -1, 3}, Filling -> Axis]

離散状態過程について，複数の時間スライスの累積分布関数を求める：

Wolfram Language code: CDF[PoissonProcess[μ][{2, 3}], {x, y}]

Wolfram Language code: DiscretePlot3D[Evaluate[% /. μ -> 2], {x, 0, 10}, {y, 0, 10}, ExtentSize -> 0.5]

連続状態過程についての複数のスライス：

Wolfram Language code: Plot3D[CDF[WienerProcess[][{2, 3}], {x, y}], {x, -3, 3}, {y, -3, 3}]

離散状態ランダム過程のStationaryDistributionについての累積分布関数を求める：

Wolfram Language code: CDF[StationaryDistribution[QueueingProcess[λ, μ, 2]], x]//FullSimplify

Wolfram Language code: DiscretePlot[Evaluate[% /. {μ -> 3, λ -> 2.9}], {x, 0, 10}, ExtentSize -> 0.5]

一般化と拡張 (1)

CDFは要素単位でリストに縫い込まれる：

Wolfram Language code: CDF[NormalDistribution[], {0.2, 0.3}]

Wolfram Language code: {CDF[NormalDistribution[], 0.2], CDF[NormalDistribution[], 0.3]}

多変量分布：

Wolfram Language code: CDF[BinormalDistribution[1 / 2], {{0.0, 0.0}, {0.2, 0.2}, {0.3, 0.3}}]

アプリケーション (5)

標準正規分布の累積分布関数をプロットする：

Wolfram Language code: Plot[CDF[NormalDistribution[0, 1], x], {x, -3, 3}]

二項分布の累積分布関数をプロットする：

Wolfram Language code: Plot[CDF[BinomialDistribution[20, .5], k], {k, 0, 20}]

自由度20の分布でとなる確率を計算する：

Wolfram Language code: CDF[StudentTDistribution[20], 3.5]

Wolfram Language code: NProbability[t ≤ 3.5, tStudentTDistribution[20]]

同じ分布でとなる確率を計算する：

Wolfram Language code: 1 - CDF[StudentTDistribution[20], 3.5]

Wolfram Language code: NProbability[t > 3.5, tStudentTDistribution[20]]

となる確率を計算する：

Wolfram Language code: 2CDF[StudentTDistribution[20], -3.5]

Wolfram Language code: NProbability[Abs[t] > 3.5, tStudentTDistribution[20]]

CDFをデータ上にマッピングすることで，データの確率積分変換を実行する：

Wolfram Language code: data = RandomVariate[NormalDistribution[], 10 ^ 4];

Wolfram Language code: tdata = CDF[NormalDistribution[], data];

もとのデータが与えられた分布に従っているなら，変換されたデータは一様分布に従う：

Wolfram Language code: Histogram[tdata, Automatic, "PDF"]

変換データを一様分布と，もとのデータをもとの分布と比較すると，適用可能なすべての検定について同一の結果が与えられる：

Wolfram Language code:

Row[{DistributionFitTest[data, NormalDistribution[], {"TestStatisticTable", All}], DistributionFitTest[tdata, UniformDistribution[], {"TestStatisticTable", All}]}, Spacer[20]]

保険数理で使われるような，一般的な生存分布関数(SDF)を定義する：

Wolfram Language code: SDF[dist_, x_] := 1 - CDF[dist, x]

Wolfram Language code: SDF[ExponentialDistribution[.05], x]

Wolfram Language code: Plot[%, {x, 0, 100}, PlotRange -> All]

SurvivalFunctionで与えられる式と比較する：

Wolfram Language code: SurvivalFunction[ExponentialDistribution[.05], x]

Wolfram Language code: % - SDF[ExponentialDistribution[.05], x]//Simplify

死力(FM)を定義する：

Wolfram Language code: FM[dist_, x_] := -D[SDF[dist, x], x] / SDF[dist, x]

Wolfram Language code: FM[ExponentialDistribution[λ], x]

Wolfram Language code: PiecewiseExpand[%]

HazardFunctionで与えられる式と比較する：

Wolfram Language code: HazardFunction[ExponentialDistribution[λ], x]

Wolfram Language code: Simplify[% - FM[ExponentialDistribution[λ], x], x > 0]

特性と関係 (12)

一変量分布でとなる確率は，それ自身の累積分布関数で与えられる：

Wolfram Language code: {Probability[x ≤ a, xNormalDistribution[]], CDF[NormalDistribution[], a]}

Wolfram Language code: {Probability[x ≤ 5, xGeometricDistribution[1 / 3]], CDF[GeometricDistribution[1 / 3], 5]}

多変量分布でとなる確率はそれ自身の累積分布関数で与えられる：

Wolfram Language code: Probability[x ≤ 1 / 2∧y ≤ 1 / 3, {x, y}DirichletDistribution[{1, 2, 3}]]

Wolfram Language code: CDF[DirichletDistribution[{1, 2, 3}], {1 / 2, 1 / 3}]

一変量の累積分布関数はで0，で1である：

Wolfram Language code: CDF[NormalDistribution[], -∞]

Wolfram Language code: CDF[NormalDistribution[], ∞]

多変量の累積分布関数の値はで0，で1である：

Wolfram Language code: CDF[BinormalDistribution[1 / 2], {-∞, -∞}]

Wolfram Language code: CDF[BinormalDistribution[1 / 2], {∞, ∞}]

累積分布関数は連続分布の確率密度関数の積分である：

Wolfram Language code: Integrate[PDF[ExponentialDistribution[λ], x], {x, 0, y}, Assumptions -> λ > 0 && y∈Reals]//Simplify

Wolfram Language code: CDF[ExponentialDistribution[λ], y]

累積分布関数は離散分布の確率密度関数の総和である：

Wolfram Language code: Sum[PDF[GeometricDistribution[p], m], {m, -∞, Floor[n]}]//FullSimplify

Wolfram Language code: CDF[GeometricDistribution[p], n]

Wolfram Language code: Simplify[% - %%, Im[n] == 0]

CDFとInverseCDFは連続分布の逆分布である：

Wolfram Language code:

dist = ExponentialDistribution[λ];
assum = DistributionParameterAssumptions[dist];

Wolfram Language code: Simplify[InverseCDF[dist, CDF[dist, x]] == x, assum && x > 0]

Wolfram Language code: Simplify[CDF[dist, InverseCDF[dist, q]] == q, assum && 0 < q < 1]

CDFとInverseCDFを合成すると離散分布のステップ関数ができる：

Wolfram Language code: dist = PoissonDistribution[2];

Wolfram Language code: Plot[CDF[dist, InverseCDF[dist, q]], {q, 0, 1}]

Wolfram Language code: Plot[InverseCDF[dist, CDF[dist, y]], {y, 0, 20}]

CDFとQuantileは連続分布の逆分布である：

Wolfram Language code: dist = ExponentialDistribution[λ];

Wolfram Language code: Assuming[x > 0 && λ > 0, Simplify[Quantile[dist, CDF[dist, x]] == x]]

Wolfram Language code: Assuming[1 > q > 0 && λ > 0, Simplify[CDF[dist, Quantile[dist, q]] == q]]

累積分布関数と生存関数の総和は1である：

Wolfram Language code: CDF[UniformDistribution[], x]

Wolfram Language code: SurvivalFunction[UniformDistribution[], x]

Wolfram Language code: % + %%//Simplify

ProbabilityPlotは，経験的CDFと推定的CDFのパラメトリックプロットを生成する：

Wolfram Language code: data = RandomVariate[ExponentialDistribution[1], 100];

Wolfram Language code: ProbabilityPlot[data, ExponentialDistribution[λ]]

CDFは，左に極限がある右連続関数である：

Wolfram Language code: DiscretePlot[CDF[BenfordDistribution[7], x], {x, 1, 8}, ExtentSize -> Right, ExtentMarkers -> {"Filled", "Empty"}]

Wolfram Language code: CDF[BenfordDistribution[7], x]//PiecewiseExpand

考えられる問題 (2)

記号的閉形式が存在しない分布もある：

Wolfram Language code: CDF[StableDistribution[0, 1.8, -0.5, 1, 2], x]

数値評価はできる：

Wolfram Language code: CDF[StableDistribution[0, 1.8, -0.5, 1, 2], 0.3]

記号式に無効な値を代入すると意味のない結果になることがある：

Wolfram Language code: CDF[CauchyDistribution[2, 3], y] /. {y -> 1.I}

CDFに引数として明示的な値を与えると，完全な検証が行われるので，無効な結果は返されない：

Wolfram Language code: CDF[CauchyDistribution[2, 3], 1.I]

おもしろい例題 (1)

二変量打切り分布についてのCDF：

Wolfram Language code: 𝒟 = CensoredDistribution[{{1 / 3, 1 / 3}, {1 / 3, 1 / 4}}, DirichletDistribution[{3, 2, 4}]];

Wolfram Language code:

Plot3D[{CDF[DirichletDistribution[{3, 2, 4}], {x, y}], CDF[𝒟, {x, y}]}//Evaluate, {x, -1 / 10, 3 / 4}, {y, -1 / 10, 4 / 5}, ExclusionsStyle -> Red, ImageSize -> Small, PlotPoints -> 35, ViewPoint -> #]& /@ {{2, 0, 1}, {-2, -2, 1}}

Top

その他のラーニングリソース

テクニカルサポート

Wolframソリューション

教育のためのWolframソリューション

使い始める

Grow Your Skills

Wolframと繋がる

大人用の教育プログラム

若者のための教育プログラム

読む

CDF

詳細

例題

例 (4)

スコープ (24)

パラメトリック分布 (7)

ノンパラメトリック分布 (4)

派生分布 (10)

ランダム過程 (3)

一般化と拡張 (1)

アプリケーション (5)

特性と関係 (12)

考えられる問題 (2)

おもしろい例題 (1)

テキスト

CMS

APA

BibTeX

BibLaTeX

CDF

詳細

例題

例 (4)

スコープ (24)

パラメトリック分布 (7)

ノンパラメトリック分布 (4)

派生分布 (10)

ランダム過程 (3)

一般化と拡張 (1)

アプリケーション (5)

特性と関係 (12)

考えられる問題 (2)

おもしろい例題 (1)

関連項目

テクニカルノート

関連するガイド

履歴

テキスト

CMS

APA

BibTeX

BibLaTeX