WOLFRAM

Wolfram 语言与系统参考资料中心

CDF[dist,x]

给出在 x 上计算的分布 dist 的累积分布函数.

CDF[dist,{x1,x2,…}]

给出在 {x1,x2,…} 上计算的分布 dist 的多变量累积分布函数.

CDF[dist]

给出作为纯函数的累积分布函数.

更多信息
Details and Options Details and Options
范例  
基本范例  
范围  
参数分布  
非参数分布  
导出分布  
随机过程  
推广和延伸  
应用  
属性和关系  
可能存在的问题  
巧妙范例  
参见
技术笔记
相关指南
历史
按以下格式引用：

CDF

CDF[dist,x]

给出在 x 上计算的分布 dist 的累积分布函数.

CDF[dist,{x1,x2,…}]

给出在 {x1,x2,…} 上计算的分布 dist 的多变量累积分布函数.

CDF[dist]

给出作为纯函数的累积分布函数.

更多信息

  • CDF[dist,x] 给出观察值将小于或等于 x 的概率.
  • CDF[dist,x] 等价于 Probability[ξ≤x,ξdist].
  • CDF[dist,{x1,…,xn}] 等价于 Probability[ξ1≤x1∧⋯∧ξn≤xn,{ξ1,…,ξn}dist].
  • CDF[dist,x] 等价于 1-SurvivalFunction[dist,x].

范例

打开所有单元 关闭所有单元

基本范例  (4)

一个单变量连续分布的累积分布函数：

Wolfram Language code: CDF[StudentTDistribution[ν], x]
Wolfram Language code: Plot[CDF[StudentTDistribution[4], x], {x, -6, 6}, Filling -> Axis]

一个单变量离散分布的累积分布函数：

Wolfram Language code: CDF[PoissonDistribution[μ], k]
Wolfram Language code: DiscretePlot[CDF[PoissonDistribution[3], k], {k, 0, 10}, ExtentSize -> Right, ExtentMarkers -> {"Filled", "Empty"}]

一个双变量连续分布的累积分布函数：

Wolfram Language code: Plot3D[CDF[BinormalDistribution[1 / 2], {x, y}], {x, -3, 3}, {y, -3, 3}]

一个多变量泊松分布的累积分布函数：

Wolfram Language code: DiscretePlot3D[CDF[MultivariatePoissonDistribution[5, {2, 3}], {x, y}], {x, 0, 12}, {y, 0, 12}, ExtentSize -> Right]

范围  (24)

参数分布  (7)

获取精确数值结果：

Wolfram Language code: CDF[WeibullDistribution[2, 5], 4]
Wolfram Language code: CDF[NegativeBinomialDistribution[20, 1 / 3], 5]

获取机器精度结果：

Wolfram Language code: CDF[WeibullDistribution[2, 5], 4.]

对于一个连续分布，获取任意精度的结果：

Wolfram Language code: CDF[WeibullDistribution[2, 5], N[4, 25]]

对于具有不精确参数的离散分布，获取任意精度的结果：

Wolfram Language code: CDF[NegativeBinomialDistribution[20, N[1 / 3, 30]], 5]

获取 CDF 的符号表达式：

Wolfram Language code: CDF[ChiSquareDistribution[ν], x]
Wolfram Language code: CDF[UniformDistribution[{{a, b}, {c, d}}], {x, y}]

获取纯函数结果：

Wolfram Language code: CDF[GammaDistribution[1, 2]]

Evaluate at a value:

Wolfram Language code: %[3]

CDF 逐项作用于列表的各个元素：

Wolfram Language code: CDF[NormalDistribution[], {0.0, 0.2, 0.3}]

多变量分布：

Wolfram Language code: CDF[BinormalDistribution[1 / 2], {{0.0, 0.0}, {0.2, 0.2}, {0.3, 0.3}}]

非参数分布  (4)

非参数分布的 CDF：

Wolfram Language code: r = RandomVariate[NormalDistribution[], 10 ^ 4];
Wolfram Language code: CDF[HistogramDistribution[r], 0.2]
Wolfram Language code: CDF[SmoothKernelDistribution[r], 0.2]
Wolfram Language code: CDF[KernelMixtureDistribution[r], 0.2]
Wolfram Language code: CDF[SurvivalDistribution[r], 0.2]
Wolfram Language code: CDF[EmpiricalDistribution[r], 0.2]
Wolfram Language code: CDF[NormalDistribution[], 0.2]

绘制直方图分布的累积分布函数：

Wolfram Language code: Plot[CDF[HistogramDistribution[RandomVariate[NormalDistribution[], 10 ^ 3]], x]//Evaluate, {x, -3, 3}, Filling -> Axis, Exclusions -> None]

一个核混合分布的累积分布函数的解析表达式（closed form expression）：

Wolfram Language code: CDF[KernelMixtureDistribution[RandomVariate[GammaDistribution[1, 2], 10 ]], x]

绘制一个二元平滑核分布的累积分布函数：

Wolfram Language code: Plot3D[CDF[SmoothKernelDistribution[RandomVariate[BinormalDistribution[1 / 3], 30]], {x, y}]//Evaluate, {x, -4, 4}, {y, -4, 4}, PlotRange -> {0, 1.2}]

导出分布  (10)

独立分布的乘积：

Wolfram Language code: CDF[ProductDistribution[TriangularDistribution[{2, 4}], TriangularDistribution[{1, 7}]], {x, y}]
Wolfram Language code: Plot3D[%, {x, 1, 5}, {y, 0, 8}, PlotRange -> All, Exclusions -> None]

分量混合分布：

Wolfram Language code: CDF[MixtureDistribution[{1, 4}, {NormalDistribution[a, b], NormalDistribution[c, d]}], x]
Wolfram Language code: Plot[% /. {a -> 0, b -> 1, c -> 6, d -> 3 / 2}, {x, -2, 10}, Filling -> Axis]

一个离散分布的二次变换：

Wolfram Language code: CDF[TransformedDistribution[x ^ 2, xPoissonDistribution[2]], y]
Wolfram Language code: DiscretePlot[%, {y, 0, 50}]

删截分布：

Wolfram Language code: CDF[CensoredDistribution[{-2, 4}, CauchyDistribution[0, 1]], x]
Wolfram Language code: Plot[{CDF[CauchyDistribution[0, 1], x], %}, {x, -4, 6}, PlotStyle -> Thick, Filling -> Axis]

截断分布：

Wolfram Language code: CDF[TruncatedDistribution[{2, 3}, TriangularDistribution[{1, 4}]], x]
Wolfram Language code: Plot[{CDF[TriangularDistribution[{1, 4}], x], %}, {x, 1, 5}, Filling -> Axis, Exclusions -> None]

参数混合分布：

Wolfram Language code: CDF[ParameterMixtureDistribution[GeometricDistribution[r], rUniformDistribution[{1 / 2, 2 / 3}]], x]
Wolfram Language code: DiscretePlot[%, {x, 0, 5}, ExtentSize -> {0, 1}]

Copula 分布：

Wolfram Language code: CDF[CopulaDistribution[{"Frank", 3}, {ExponentialDistribution[2], ExponentialDistribution[5]}], {x, y}]
Wolfram Language code: Plot3D[%, {x, 0, 3}, {y, 0, 3}]

由概率密度函数定义的公式分布：

Wolfram Language code: CDF[ProbabilityDistribution[(Sqrt[2] / Pi)(1 / (1 + x ^ 4)), {x, -Infinity, Infinity}], x]

由累积分布函数定义：

Wolfram Language code: CDF[ProbabilityDistribution[{"CDF", Piecewise[{{-2 + x, 2 ≤ x ≤ 3}, {1, x > 3}}, 0]}, {x, -Infinity, Infinity}], x]

由 SurvivalFunction 定义：

Wolfram Language code: CDF[ProbabilityDistribution[{"SF", Piecewise[{{1 - 2(-2 + x) ^ 2, 2 ≤ x ≤ 5 / 2}, {2(3 - x) ^ 2, 5 / 2 < x ≤ 3}, {1, x < 2}}, 0]}, {x, -Infinity, Infinity}], x]

边缘分布：

Wolfram Language code: CDF[MarginalDistribution[ProbabilityDistribution[E^-(y^2/2) π^-3 / 2 (1 + x^4)^-1, {x, -∞, ∞}, {y, -∞, ∞}], 2], y]

QuantityDistribution 的 CDF 假定参数是一个带有兼容单位的 Quantity：

Wolfram Language code: 𝒟 = ExponentialDistribution[Quantity[2.2, 1 / "Days"]]
Wolfram Language code: CDF[𝒟, t]

这样允许直接进行量的替换：

Wolfram Language code: % /. t -> Quantity[MixedMagnitude[{3, 20}], MixedUnit[{"Hours", "Minutes"}]]

与直接使用 quantity 参数比较：

Wolfram Language code: CDF[𝒟, Quantity[MixedMagnitude[{3, 20}], MixedUnit[{"Hours", "Minutes"}]]]

随机过程  (3)

求离散状态随机过程的 SliceDistribution 的累积分布函数：

Wolfram Language code: CDF[PoissonProcess[μ][2], x]
Wolfram Language code: DiscretePlot[Evaluate[% /. μ -> 2], {x, 0, 15}, ExtentSize -> 0.5]

连续状态随机过程：

Wolfram Language code: CDF[WienerProcess[][2], x]
Wolfram Language code: Plot[%, {x, -1, 3}, Filling -> Axis]

求离散状态过程的多时切片累积分布函数：

Wolfram Language code: CDF[PoissonProcess[μ][{2, 3}], {x, y}]
Wolfram Language code: DiscretePlot3D[Evaluate[% /. μ -> 2], {x, 0, 10}, {y, 0, 10}, ExtentSize -> 0.5]

连续状态过程的多切片：

Wolfram Language code: Plot3D[CDF[WienerProcess[][{2, 3}], {x, y}], {x, -3, 3}, {y, -3, 3}]

求离散状态随机过程的 StationaryDistribution 的累积分布函数：

Wolfram Language code: CDF[StationaryDistribution[QueueingProcess[λ, μ, 2]], x]//FullSimplify
Wolfram Language code: DiscretePlot[Evaluate[% /. {μ -> 3, λ -> 2.9}], {x, 0, 10}, ExtentSize -> 0.5]

推广和延伸  (1)

CDF 按元素线性作用于列表：

Wolfram Language code: CDF[NormalDistribution[], {0.2, 0.3}]
Wolfram Language code: {CDF[NormalDistribution[], 0.2], CDF[NormalDistribution[], 0.3]}

多变量分布：

Wolfram Language code: CDF[BinormalDistribution[1 / 2], {{0.0, 0.0}, {0.2, 0.2}, {0.3, 0.3}}]

应用  (5)

绘制一个标准的正态分布的累积分布函数：

Wolfram Language code: Plot[CDF[NormalDistribution[0, 1], x], {x, -3, 3}]

绘制一个二项分布的累积分布函数：

Wolfram Language code: Plot[CDF[BinomialDistribution[20, .5], k], {k, 0, 20}]

计算一个具有 20 个自由度的 分布中 的概率：

Wolfram Language code: CDF[StudentTDistribution[20], 3.5]
Wolfram Language code: NProbability[t ≤ 3.5, tStudentTDistribution[20]]

计算相同分布中 的概率：

Wolfram Language code: 1 - CDF[StudentTDistribution[20], 3.5]
Wolfram Language code: NProbability[t > 3.5, tStudentTDistribution[20]]

计算 的概率：

Wolfram Language code: 2CDF[StudentTDistribution[20], -3.5]
Wolfram Language code: NProbability[Abs[t] > 3.5, tStudentTDistribution[20]]

通过将 CDF 映射到数据上，对数据进行概率积分变换：

Wolfram Language code: data = RandomVariate[NormalDistribution[], 10 ^ 4];
Wolfram Language code: tdata = CDF[NormalDistribution[], data];

如果原始数据来自所选择的分布，则转换后的数据是均匀分布的：

Wolfram Language code: Histogram[tdata, Automatic, "PDF"]

将转换后的数据与均匀分布进行比较，并将原始数据与原始分布比较，对所有适用的测试，给出的结果应该相同：

Wolfram Language code: Row[{DistributionFitTest[data, NormalDistribution[], {"TestStatisticTable", All}], DistributionFitTest[tdata, UniformDistribution[], {"TestStatisticTable", All}]}, Spacer[20]]

定义一个精算学中使用的普通生存分布函数（SDF）：

Wolfram Language code: SDF[dist_, x_] := 1 - CDF[dist, x]
Wolfram Language code: SDF[ExponentialDistribution[.05], x]
Wolfram Language code: Plot[%, {x, 0, 100}, PlotRange -> All]

与 SurvivalFunction 给出的表达式比较：

Wolfram Language code: SurvivalFunction[ExponentialDistribution[.05], x]
Wolfram Language code: % - SDF[ExponentialDistribution[.05], x]//Simplify

定义死亡率（FM）：

Wolfram Language code: FM[dist_, x_] := -D[SDF[dist, x], x] / SDF[dist, x]
Wolfram Language code: FM[ExponentialDistribution[λ], x]
Wolfram Language code: PiecewiseExpand[%]

与 HazardFunction 给出的表达式比较：

Wolfram Language code: HazardFunction[ExponentialDistribution[λ], x]
Wolfram Language code: Simplify[% - FM[ExponentialDistribution[λ], x], x > 0]

属性和关系  (12)

一个单变量分布的 的概率由累积分布函数给出：

Wolfram Language code: {Probability[x ≤ a, xNormalDistribution[]], CDF[NormalDistribution[], a]}
Wolfram Language code: {Probability[x ≤ 5, xGeometricDistribution[1 / 3]], CDF[GeometricDistribution[1 / 3], 5]}

一个多变量分布的 的概率由累积分布函数给出：

Wolfram Language code: Probability[x ≤ 1 / 2∧y ≤ 1 / 3, {x, y}DirichletDistribution[{1, 2, 3}]]
Wolfram Language code: CDF[DirichletDistribution[{1, 2, 3}], {1 / 2, 1 / 3}]

一个单变量累积分布函数在 处为0，而在 处为1：

Wolfram Language code: CDF[NormalDistribution[], -∞]
Wolfram Language code: CDF[NormalDistribution[], ∞]

一个多变量累积分布函数在 具有值0而在 具有值1：

Wolfram Language code: CDF[BinormalDistribution[1 / 2], {-∞, -∞}]
Wolfram Language code: CDF[BinormalDistribution[1 / 2], {∞, ∞}]

累积分布函数是连续分布 的概率密度函数的积分：

Wolfram Language code: Integrate[PDF[ExponentialDistribution[λ], x], {x, 0, y}, Assumptions -> λ > 0 && y∈Reals]//Simplify
Wolfram Language code: CDF[ExponentialDistribution[λ], y]

累积分布函数是离散分布 的概率密度函数的和：

Wolfram Language code: Sum[PDF[GeometricDistribution[p], m], {m, -∞, Floor[n]}]//FullSimplify
Wolfram Language code: CDF[GeometricDistribution[p], n]
Wolfram Language code: Simplify[% - %%, Im[n] == 0]

CDF 和 InverseCDF 是连续分布的反函数：

Wolfram Language code: dist = ExponentialDistribution[λ]; assum = DistributionParameterAssumptions[dist];
Wolfram Language code: Simplify[InverseCDF[dist, CDF[dist, x]] == x, assum && x > 0]
Wolfram Language code: Simplify[CDF[dist, InverseCDF[dist, q]] == q, assum && 0 < q < 1]

CDF 和 InverseCDF 的合成给出一个离散分布的阶梯函数：

Wolfram Language code: dist = PoissonDistribution[2];
Wolfram Language code: Plot[CDF[dist, InverseCDF[dist, q]], {q, 0, 1}]
Wolfram Language code: Plot[InverseCDF[dist, CDF[dist, y]], {y, 0, 20}]

CDF 和 Quantile 是连续分布的逆：

Wolfram Language code: dist = ExponentialDistribution[λ];
Wolfram Language code: Assuming[x > 0 && λ > 0, Simplify[Quantile[dist, CDF[dist, x]] == x]]
Wolfram Language code: Assuming[1 > q > 0 && λ > 0, Simplify[CDF[dist, Quantile[dist, q]] == q]]

累积分布函数和生存函数的和是1：

Wolfram Language code: CDF[UniformDistribution[], x]
Wolfram Language code: SurvivalFunction[UniformDistribution[], x]
Wolfram Language code: % + %%//Simplify

ProbabilityPlot 生成经验 CDF 相对于估计 CDF 的参数图：

Wolfram Language code: data = RandomVariate[ExponentialDistribution[1], 100];
Wolfram Language code: ProbabilityPlot[data, ExponentialDistribution[λ]]

CDF 是具有左限的右连续函数：

Wolfram Language code: DiscretePlot[CDF[BenfordDistribution[7], x], {x, 1, 8}, ExtentSize -> Right, ExtentMarkers -> {"Filled", "Empty"}]
Wolfram Language code: CDF[BenfordDistribution[7], x]//PiecewiseExpand

可能存在的问题  (2)

对于某些分布不存在符号式解析式：

Wolfram Language code: CDF[StableDistribution[0, 1.8, -0.5, 1, 2], x]

数值计算起作用：

Wolfram Language code: CDF[StableDistribution[0, 1.8, -0.5, 1, 2], 0.3]

把无效值代入符号公式给出无意义的结果：

Wolfram Language code: CDF[CauchyDistribution[2, 3], y] /. {y -> 1.I}

当 CDF 作为一个变量被赋予显式值，它能够完成检查，并且不产生无效的结果：

Wolfram Language code: CDF[CauchyDistribution[2, 3], 1.I]

巧妙范例  (1)

双变量删失分布的 CDF：

Wolfram Language code: 𝒟 = CensoredDistribution[{{1 / 3, 1 / 3}, {1 / 3, 1 / 4}}, DirichletDistribution[{3, 2, 4}]];
Wolfram Language code: Plot3D[{CDF[DirichletDistribution[{3, 2, 4}], {x, y}], CDF[𝒟, {x, y}]}//Evaluate, {x, -1 / 10, 3 / 4}, {y, -1 / 10, 4 / 5}, ExclusionsStyle -> Red, ImageSize -> Small, PlotPoints -> 35, ViewPoint -> #]& /@ {{2, 0, 1}, {-2, -2, 1}}
Wolfram Research (2007)，CDF，Wolfram 语言函数，https://reference.wolfram.com/language/ref/CDF.html （更新于 2010 年）.

文本

Wolfram Research (2007)，CDF，Wolfram 语言函数，https://reference.wolfram.com/language/ref/CDF.html （更新于 2010 年）.

CMS

Wolfram 语言. 2007. "CDF." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2010. https://reference.wolfram.com/language/ref/CDF.html.

APA

Wolfram 语言. (2007). CDF. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/CDF.html 年

BibTeX

@misc{reference.wolfram_2026_cdf, author="Wolfram Research", title="{CDF}", year="2010", howpublished="\url{https://reference.wolfram.com/language/ref/CDF.html}", note=[Accessed: 10-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_cdf, organization={Wolfram Research}, title={CDF}, year={2010}, url={https://reference.wolfram.com/language/ref/CDF.html}, note=[Accessed: 10-August-2026]}