WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

CarlsonRG[x,y,z]

Carlsonの楕円積分 TemplateBox[{x, y, z}, CarlsonRG]を与える．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
数値評価  
特定の値  
微分と積分  
関数表現  
関数の恒等式と簡約  
アプリケーション  
特性と関係  
関連項目
関連するガイド
履歴
引用書式

CarlsonRG

CarlsonRG[x,y,z]

Carlsonの楕円積分 TemplateBox[{x, y, z}, CarlsonRG]を与える．

詳細

  • 記号操作・数値操作の両方に適した数学関数である．
  • 非負の引数について TemplateBox[{x, y, z}, CarlsonRG]=1/4int_0^infty(t+x)^(-1/2)(t+y)^(-1/2)(t+z)^(-1/2)((x t)/(t+x)+(y t)/(t+y)+(z t)/(t+z))dt である．
  • CarlsonRG[x,y,z]は に不連続な分枝切断線を持つ．
  • 特別な引数の場合，CarlsonRGは自動的に厳密値を計算する．
  • CarlsonRGは任意の数値精度で評価できる．
  • CarlsonRGは自動的にリストに縫い込まれる．
  • CarlsonRGは，IntervalオブジェクトおよびCenteredIntervalオブジェクトに使うことができる． »

例題

すべて開く すべて閉じる

例  (3)

数値的に評価する：

Wolfram Language code: CarlsonRG[3., 5., 11.]

引数の範囲でプロットする：

Wolfram Language code: Plot[{CarlsonRG[t, 2, 3], CarlsonRG[1, t, 3], CarlsonRG[1, 2, t]}, {t, 0, 6}, PlotLegends -> "Expressions"]

CarlsonRGは，についてルジャンドル(Legendre)の第2種楕円積分 TemplateBox[{phi, m}, EllipticE2]に関連している：

Wolfram Language code: 2 Sin[ϕ]CarlsonRG[Cos[ϕ]^2, 1 - m Sin[ϕ]^2, 1] /. {m -> 0.3, ϕ -> Pi / 5.}
Wolfram Language code: Sin[ϕ]^2EllipticE[ϕ, m] + Cos[ϕ]^2EllipticF[ϕ, m] + Sqrt[1 - m Sin[ϕ]^2]Sin[ϕ]Cos[ϕ] /. {m -> 0.3, ϕ -> Pi / 5}

スコープ  (17)

数値評価  (6)

数値的に評価する：

Wolfram Language code: CarlsonRG[5, 1.0, 7]

高精度で評価する：

Wolfram Language code: N[CarlsonRG[3 / 4, 4, 5], 50]

出力精度は入力精度に従う：

Wolfram Language code: CarlsonRG[4, 7, 1.234567890123456789012345]
Wolfram Language code: CarlsonRG[4, 7, 1.2345678901234567890123456789012345]

複素引数について評価する：

Wolfram Language code: CarlsonRG[I, 1 - 2I, 3. + I]

高精度で効率的に評価する：

Wolfram Language code: Timing[CarlsonRG[2, 3, 7`500]]
Wolfram Language code: Timing[Precision[CarlsonRG[2, 3, 7`100000]]]

CarlsonRGは要素単位でリストに縫い込まれる：

Wolfram Language code: CarlsonRG[{1., 2., 3.}, {2., 3., 1.}, {3., 1., 2.}]

CarlsonRGは，IntervalオブジェクトおよびCenteredIntervalオブジェクトに使うことができる：

Wolfram Language code: CarlsonRG[Interval[{1.23, 1.24}], Interval[{2.34, 2.35}], Interval[{3.45, 3.46}]]
Wolfram Language code: CarlsonRG[CenteredInterval[3 / 2, 1 / 100], CenteredInterval[5 / 4, 1 / 100], CenteredInterval[7 / 6, 1 / 100]]

特定の値  (4)

単純な厳密値は自動的に生成される：

Wolfram Language code: CarlsonRG[x, x, x]
Wolfram Language code: CarlsonRG[x, x, y]

CarlsonRGの一つの引数が0のとき，CarlsonRGは完全楕円積分CarlsonREに変換される：

Wolfram Language code: CarlsonRG[0, x, y]

CarlsonRGの2つの引数が等しくかつ負の実軸上にはないとき，CarlsonRGはCarlsonRCによって表すことができる：

Wolfram Language code: CarlsonRG[x, 2 + 3I, 2 + 3I]

CarlsonRGの引数がすべて等しくかつ負の実軸上にはないとき，CarlsonRGは初等関数に変換される：

Wolfram Language code: CarlsonRG[2 + 3I, 2 + 3I, 2 + 3I]

微分と積分  (2)

についてのTemplateBox[{x, y, z}, CarlsonRG]の導関数：

Wolfram Language code: D[CarlsonRG[x, y, z], z]

TemplateBox[{x, y, z}, CarlsonRG]の についての不定積分：

Wolfram Language code: Integrate[CarlsonRG[x, y, z], z]

関数表現  (1)

TraditionalFormによる表示：

Wolfram Language code: CarlsonRG[x, y, z]//TraditionalForm

関数の恒等式と簡約  (4)

CarlsonRG，CarlsonRF，CarlsonRDを関連付ける等式：

Wolfram Language code: 2CarlsonRG[x, y, z] == z CarlsonRF[x, y, z] + (Sqrt[x]Sqrt[y]/Sqrt[z]) - (1/3)(z - x)(z - y)CarlsonRD[x, y, z]//FullSimplify

CarlsonRGは．オイラー・ポアソン(Euler–Poisson)の偏微分方程式を満足する：

Wolfram Language code: (x - y)Subscript[∂, x⁣y]CarlsonRG[x, y, z] + (1/2) Subscript[∂, y]CarlsonRG[x, y, z] - (1/2)Subscript[∂, x]CarlsonRG[x, y, z] == 0//FunctionExpand//FullSimplify

CarlsonRGは，オイラーの同次関係を満足する：

Wolfram Language code: x Subscript[∂, x]CarlsonRG[x, y, z] + y Subscript[∂, y]CarlsonRG[x, y, z] + z Subscript[∂, z]CarlsonRG[x, y, z] == (1/2)CarlsonRG[x, y, z]//FunctionExpand//FullSimplify

CarlsonRGが満足する偏微分方程式：

Wolfram Language code: Subscript[∂, x]CarlsonRG[x, y, z] + Subscript[∂, y]CarlsonRG[x, y, z] + Subscript[∂, z]CarlsonRG[x, y, z] == (1/2)CarlsonRF[x, y, z]//FunctionExpand//FullSimplify

アプリケーション  (2)

三軸楕円体の表面積を計算する：

Wolfram Language code: area[a_, b_, c_] := 4π a b c CarlsonRG[(1/a^2), (1/b^2), (1/c^2)];

半軸が3, 2, 1の楕円体の表面積を求める：

Wolfram Language code: area[3, 2, 1]//N

RegionMeasureを使って楕円体の表面積を計算する：

Wolfram Language code: RegionMeasure[RegionBoundary[Ellipsoid[{0, 0, 0}, {3, 2, 1}]], WorkingPrecision -> MachinePrecision]

正規分布上のReciprocal Square Root of a Quadratic Form（二次形式の平方根の逆数）の期待値：

Wolfram Language code: MatrixForm[mat = HilbertMatrix[3]]
Wolfram Language code: NExpectation[Sqrt[(1/2){u, v, w}.mat.{u, v, w}], {u, v, w}ProductDistribution[{NormalDistribution[], 3}], Method -> "MonteCarlo"]//Quiet

CarlsonRGによる閉じた形の結果と比較する：

Wolfram Language code: N[(Gamma[(3 - 1/2)]/Gamma[(3/2)])(CarlsonRG@@Eigenvalues[mat]), 25]

特性と関係  (1)

CarlsonRGは，その引数を並べ替えても変わらない：

Wolfram Language code: CarlsonRG[x, y, z] == CarlsonRG[z, x, y]
Wolfram Research (2021), CarlsonRG, Wolfram言語関数， https://reference.wolfram.com/language/ref/CarlsonRG.html （2023年に更新）.

テキスト

Wolfram Research (2021), CarlsonRG, Wolfram言語関数， https://reference.wolfram.com/language/ref/CarlsonRG.html （2023年に更新）.

CMS

Wolfram Language. 2021. "CarlsonRG." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2023. https://reference.wolfram.com/language/ref/CarlsonRG.html.

APA

Wolfram Language. (2021). CarlsonRG. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/CarlsonRG.html

BibTeX

@misc{reference.wolfram_2026_carlsonrg, author="Wolfram Research", title="{CarlsonRG}", year="2023", howpublished="\url{https://reference.wolfram.com/language/ref/CarlsonRG.html}", note=[Accessed: 15-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_carlsonrg, organization={Wolfram Research}, title={CarlsonRG}, year={2023}, url={https://reference.wolfram.com/language/ref/CarlsonRG.html}, note=[Accessed: 15-August-2026]}