WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

ChebyshevT[n,x]

第1種チェビシェフ(Chebyshev)多項式 TemplateBox[{n, x}, ChebyshevT]を与える．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
数値評価  
特定の値  
可視化  
Show More Show More
関数の特性  
微分  
積分  
級数展開  
関数の恒等式と簡約  
一般化と拡張  
アプリケーション  
特性と関係  
考えられる問題  
おもしろい例題  
関連項目
テクニカルノート
関連するガイド
関連リンク
履歴
引用書式

ChebyshevT

ChebyshevT[n,x]

第1種チェビシェフ(Chebyshev)多項式 TemplateBox[{n, x}, ChebyshevT]を与える．

詳細

  • 記号操作・数値操作の両方に適した数学関数である．
  • 整数 n について具体的な多項式が与えられる．
  • TemplateBox[{n, {cos, , theta}}, ChebyshevT]=cos(ntheta).
  • 特別な引数の場合，ChebyshevTは，自動的に厳密値を計算する．
  • ChebyshevTは，任意の数値精度で評価することができる．
  • ChebyshevTは，リストに対して自動的に縫い込まれる．
  • ChebyshevT[n,z]は，n が整数ではなければ，複素 z 平面上の〜の範囲で不連続な分枝切断線を持つ．
  • ChebyshevTはIntervalオブジェクトおよびCenteredIntervalオブジェクトに使うことができる． »

例題

すべて開く すべて閉じる

例  (7)

数値的に評価する：

Wolfram Language code: ChebyshevT[2, 3]

十次チェビシェフ多項式を計算する：

Wolfram Language code: ChebyshevT[10, x]

実数の部分集合上でプロットする：

Wolfram Language code: Plot[ChebyshevT[10, x], {x, -1, 1}]

複素数の部分集合上でプロットする：

Wolfram Language code: ComplexPlot3D[ChebyshevT[5, z], {z, -2 - 2I, 2 + 2I}, PlotLegends -> Automatic]

原点における級数展開：

Wolfram Language code: Series[ChebyshevT[5, x], {x, 0, 5}]

Infinityにおける漸近展開：

Wolfram Language code: Series[ChebyshevT[1 / 3, x], {x, ∞, 3}]//Normal//FullSimplify

特異点における漸近展開：

Wolfram Language code: Series[ChebyshevT[1 / 3, x], {x, -1, 2}]//FullSimplify

スコープ  (44)

数値評価  (6)

数値的に評価する：

Wolfram Language code: ChebyshevT[2, 5]
Wolfram Language code: ChebyshevT[12, 2.5]

高精度で評価する：

Wolfram Language code: N[ChebyshevT[1 / 7, 1 / 3], 50]

出力精度は入力精度に従う：

Wolfram Language code: ChebyshevT[0.3000000000000000000, 0]

複素数入力：

Wolfram Language code: N[ChebyshevT[98 + I, I]]

高精度で効率的に評価する：

Wolfram Language code: ChebyshevT[-1.5, -2.4`100]//Timing
Wolfram Language code: ChebyshevT[84, 63`10000000];//Timing

IntervalオブジェクトとCenteredInterval オブジェクトを使用して，最悪の場合の保証区間を計算する：

Wolfram Language code: ChebyshevT[2, Interval[{1.9, 2.1}]]
Wolfram Language code: ChebyshevT[2, CenteredInterval[2, 1 / 100]]

平均的なケースの統計間隔をAroundを使って計算することもできる：

Wolfram Language code: ChebyshevT[2, Around[2, 0.01]]

配列の要素ごとの値を計算する：

Wolfram Language code: ChebyshevT[2, {{1, 2}, {3, 4}}]

MatrixFunctionを使って行列のChebyshevT関数を計算することもできる：

Wolfram Language code: MatrixFunction[ChebyshevT[2, #]&, {{1, 2}, {3, 4}}]

特定の値  (7)

固定点におけるChebyshevTの値：

Wolfram Language code: Table[ChebyshevT[n, Pi / 2], {n, 0, 3}]

記号的な n についてのChebyshevT：

Wolfram Language code: ChebyshevT[n, 0]

ゼロにおける値：

Wolfram Language code: ChebyshevT[0, 0]

無限大における値：

Wolfram Language code: ChebyshevT[0, Infinity]
Wolfram Language code: ChebyshevT[Infinity, 0][[1, 1]]

ChebyshevT[5,x]の最初の正の最大値を求める：

Wolfram Language code: xmax = x /. Solve[D[ChebyshevT[5, x], x] == 0 && 0 < x < π, x][[1]]
Wolfram Language code: Plot[ChebyshevT[5, x], {x, -1, 1}, Epilog -> Style[Point[{xmax, ChebyshevT[5, xmax]}], PointSize[Large], Red]]

陪多項式ChebyshevT[7,x]を計算する：

Wolfram Language code: ChebyshevT[7, x]

半整数 n について陪多項式ChebyshevT[1/2,x]を計算する：

Wolfram Language code: ChebyshevT[1 / 2, x]

可視化  (3)

ChebyshevT関数をさまざまな次数で計算する：

Wolfram Language code: Plot[{ChebyshevT[1, x], ChebyshevT[2, x], ChebyshevT[3, x], ChebyshevT[4, x]}, {x, -1, 1}]

TemplateBox[{3, z}, ChebyshevT]の実部をプロットする：

Wolfram Language code: ComplexContourPlot[Re[ChebyshevT[3, z]], {z, -3 - 3 I, 3 + 3 I}, IconizedObject[«PlotOptions»]]

TemplateBox[{3, z}, ChebyshevT]の虚部をプロットする：

Wolfram Language code: ComplexContourPlot[Im[ChebyshevT[3, z]], {z, -3 - 3 I, 3 + 3 I}, IconizedObject[«PlotOptions»]]

チェビシェフ多項式を2変数の関数としてプロットする：

Wolfram Language code: Plot3D[ChebyshevT[n, z], {n, 0, 5}, {z, -1, 1}]

関数の特性  (14)

ChebyshevTは，区間[-1,∞]からのすべての実数値について定義される：

Wolfram Language code: FunctionDomain[ChebyshevT[n, x], x]

ChebyshevTは，すべての複素値について定義される：

Wolfram Language code: FunctionDomain[ChebyshevT[n, z], z, Complexes]

TemplateBox[{1, x}, ChebyshevT]はすべての実数値と複素数値に達する：

Wolfram Language code: FunctionRange[ChebyshevT[1, x], x, y]
Wolfram Language code: FunctionRange[ChebyshevT[1, z], z, y, Complexes]

TemplateBox[{2, x}, ChebyshevT]の実数範囲：

Wolfram Language code: FunctionRange[ChebyshevT[2, x], x, y]

すべての複素数値に達する：

Wolfram Language code: FunctionRange[ChebyshevT[2, z], z, y, Complexes]

奇次元のチェビシェフ多項式は奇多項式である：

Wolfram Language code: ChebyshevT[1, -x] == -ChebyshevT[1, x]

偶次数のチェビシェフ多項式は偶多項式である：

Wolfram Language code: ChebyshevT[2, -x] == ChebyshevT[2, x]

ChebyshevTは要素単位でリストに縫い込まれる：

Wolfram Language code: ChebyshevT[{1, 2, 3}, x]

チェビシェフ多項式は解析的である：

Wolfram Language code: FunctionAnalytic[ChebyshevT[n, x], x, Assumptions -> n∈ℤ]

一般に，ChebyshevTは解析的でも有理型でもない：

Wolfram Language code: FunctionAnalytic[ChebyshevT[1 / 3, x], x, ℂ]
Wolfram Language code: FunctionMeromorphic[ChebyshevT[1 / 3, x], x]

TemplateBox[{2, x}, ChebyshevT]は非減少でも非増加でもない：

Wolfram Language code: FunctionMonotonicity[ChebyshevT[2, x], x]

TemplateBox[{2, x}, ChebyshevT]は単射ではない：

Wolfram Language code: FunctionInjective[ChebyshevT[2, x], x]

TemplateBox[{1, x}, ChebyshevT]は単射である：

Wolfram Language code: FunctionInjective[ChebyshevT[1, x], x]
Wolfram Language code: Plot[{ChebyshevT[1, x], ChebyshevT[2, x], 2}, {x, -2, 2}]

TemplateBox[{2, x}, ChebyshevT]は全射ではない：

Wolfram Language code: FunctionSurjective[ChebyshevT[2, x], x]

TemplateBox[{1, x}, ChebyshevT]は全射である：

Wolfram Language code: FunctionSurjective[ChebyshevT[1, x], x]
Wolfram Language code: Plot[{ChebyshevT[1, x], ChebyshevT[2, x], 2}, {x, -2, 2}]

TemplateBox[{2, x}, ChebyshevT]は非負でも非正でもない：

Wolfram Language code: FunctionSign[ChebyshevT[2, x], x]

で が整数ではないとき，TemplateBox[{n, x}, ChebyshevT]は特異点と不連続点を持つ：

Wolfram Language code: FunctionSingularities[ChebyshevT[n, x], x]
Wolfram Language code: FunctionDiscontinuities[ChebyshevT[n, x], x]

TemplateBox[{2, x}, ChebyshevT]は凸である：

Wolfram Language code: FunctionConvexity[ChebyshevT[2, x], x]

TraditionalFormによる表示：

Wolfram Language code: ChebyshevT[n, x]//TraditionalForm

微分  (3)

x についての一次導関数：

Wolfram Language code: D[ChebyshevT[n, x] , x]

x についての高次導関数：

Wolfram Language code: Table[D[ChebyshevT[n, x], {x, k}], {k, 1, 3}]//Simplify

n=5のときの x についての高次導関数をプロットする：

Wolfram Language code: Plot[Evaluate[% /. n -> 5], {x, -1, 1}, PlotLegends -> {"First Derivative", "Second Derivative", "Third Derivative"}]

x についての 次導関数の式：

Wolfram Language code: D[ChebyshevT[n, x], {x, k}]// FullSimplify

積分  (4)

Integrateを使って不定積分を計算する：

Wolfram Language code: Integrate[ChebyshevT[n, x], x]

不定積分を確認する：

Wolfram Language code: FullSimplify[D[%, x]]

定積分：

Wolfram Language code: Integrate[ChebyshevT[n, x], {x, 0, 4}]

奇整数についての1周期のChebyshevTの定積分は0である：

Wolfram Language code: Integrate[ChebyshevT[2n - 1, x], {x, -5, 5}]
Wolfram Language code: Table[%, {n, 3, 11, 2}]//FullSimplify

その他の積分例：

Wolfram Language code: Integrate[ChebyshevT[3, x]ChebyshevT[5, x], x]//FullSimplify
Wolfram Language code: Integrate[Exp[x] ChebyshevT[5, x], {x, 0, 5}]//FullSimplify

級数展開  (3)

Seriesを使ってテイラー(Taylor)展開を求める：

Wolfram Language code: Series[ChebyshevT[n, x], {x, 0, 3}]

の周りの最初の3つの近似のプロット：

Wolfram Language code: terms = Normal@Table[Series[ChebyshevT[10, x], {x, 0, m}], {m, 1, 5, 2}]; Plot[{ChebyshevT[10, x], terms}, {x, -1, 1}, PlotRange -> {-3, 3}]

SeriesCoefficientを使った級数展開における一般項：

Wolfram Language code: SeriesCoefficient[ChebyshevT[n, x], {x, 0, n}]

生成点におけるテイラー展開：

Wolfram Language code: Series[ChebyshevT[n, x], {x, x0, 2}]

関数の恒等式と簡約  (4)

ChebyshevTは恒等式を通して定義される：

Wolfram Language code: ChebyshevT[n, Cos[θ]] == Cos[n θ]//FullSimplify

ChebyshevTの通常の母関数：

Wolfram Language code: Sum[ChebyshevT[n, x]t^n, {n, 0, Infinity}]

ChebyshevTの指数型母関数：

Wolfram Language code: Sum[ChebyshevT[n, x]t^n / n!, {n, 0, Infinity}]

漸化式：

Wolfram Language code: ChebyshevT[n, z] == 2 z ChebyshevT[n + 1, z] - ChebyshevT[n + 2, z]//FullSimplify
Wolfram Language code: ChebyshevT[n - 1, z] + ChebyshevT[n + 1, z] == 2 z ChebyshevT[n, z]//FullSimplify

一般化と拡張  (2)

ChebyshevTはベキ級数に適用できる：

Wolfram Language code: ChebyshevT[1 / 3, Sin[x] + O[x] ^ 3]

ChebyshevTはIntervalに適用できる：

Wolfram Language code: ChebyshevT[10, Interval[{-1, 1}]]

アプリケーション  (4)

はじめの10個のチェビシェフ多項式をプロットする：

Wolfram Language code: Plot[Evaluate[Table[ChebyshevT[n, x], {n, 0, 5}]], {x, -1, 1}]

関数Clip[4 x]のミニマックス近似を求める：

Wolfram Language code: c = Table[(2/π)Subsuperscript[∫, -1, 1]Clip[4 x](ChebyshevT[n, x]/Sqrt[1 - x^2])ⅆx, {n, 0, 5}]
Wolfram Language code: Plot[ {Clip[4 x], -First[c] / 2 + Evaluate[c . Table[ChebyshevT[n - 1, x], {n, Length[c]}]]}, {x, -1, 1}]

チェビシェフ多項式の関数の展開を得る：

Wolfram Language code: f[x_] := 1 / (1 + (5x) ^ 2);

チェビシェフノードにおける関数の値：

Wolfram Language code: n = 47; cnodes = N[Cos[Pi Range[0, n] / n]]; fc = Map[f, cnodes]; pf = ListPlot[Transpose[{cnodes, fc}], PlotRange -> All]

チェビシェフ係数を求める：

Wolfram Language code: cc = FourierDCT[fc, 1] * Sqrt[2 / n]; cc[[{1, -1}]] /= 2;

誤差を示す：

Wolfram Language code: Plot[f[x] - Sum[ChebyshevT[i - 1, x] * cc[[i]], {i, Length[cc]}], {x, -1, 1}, PlotRange -> All]

ChebyshevT関数を不均一部分として微分方程式を解く：

Wolfram Language code: DSolve[y''[x] + ChebyshevT[n, x] == 0, y[x], x]

特性と関係  (7)

FullSimplifyをChebyshevTに使う：

Wolfram Language code: FullSimplify[ChebyshevT[10, Cos[x]]]

展開された三角関数の式をChebyshevTと比較する：

Wolfram Language code: FunctionExpand[Cos[10ArcCos[x]]]//Expand
Wolfram Language code: ChebyshevT[10, x]

ChebyshevTの導関数はChebyshevUについて表現される：

Wolfram Language code: D[ChebyshevT[n, x], x]

ChebyshevTはDifferenceRootとして表すことができる：

Wolfram Language code: DifferenceRootReduce[ChebyshevT[k, z], k]

ChebyshevTの級数展開における一般項：

Wolfram Language code: SeriesCoefficient[ChebyshevT[a, x], {x, 0, n}]

ChebyshevTの母関数：

Wolfram Language code: GeneratingFunction[ChebyshevT[n, k], n, x]

ChebyshevTの指数母関数：

Wolfram Language code: ExponentialGeneratingFunction[ChebyshevT[n, k], n, x]

考えられる問題  (1)

多項式の簡約を行うと，数値結果が不正確になることがある：

Wolfram Language code: ChebyshevT[60, x] /. x -> N[2 / 3, 16]

関数を直接評価する：

Wolfram Language code: ChebyshevT[60, N[2 / 3, 16] ]

おもしろい例題  (1)

最初のいくつかのBanchoff–Chmutov曲面をプロットする：

Wolfram Language code: Table[ContourPlot3D[ChebyshevT[2k, x] + ChebyshevT[2k, y] + ChebyshevT[2k, z] == 0, {x, -5 / 4, 5 / 4}, {y, -5 / 4, 5 / 4}, {z, -5 / 4, 5 / 4}, Axes -> None, Boxed -> False], {k, 4}]//GraphicsRow
Wolfram Research (1988), ChebyshevT, Wolfram言語関数， https://reference.wolfram.com/language/ref/ChebyshevT.html （2022年に更新）.

テキスト

Wolfram Research (1988), ChebyshevT, Wolfram言語関数， https://reference.wolfram.com/language/ref/ChebyshevT.html （2022年に更新）.

CMS

Wolfram Language. 1988. "ChebyshevT." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2022. https://reference.wolfram.com/language/ref/ChebyshevT.html.

APA

Wolfram Language. (1988). ChebyshevT. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/ChebyshevT.html

BibTeX

@misc{reference.wolfram_2026_chebyshevt, author="Wolfram Research", title="{ChebyshevT}", year="2022", howpublished="\url{https://reference.wolfram.com/language/ref/ChebyshevT.html}", note=[Accessed: 04-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_chebyshevt, organization={Wolfram Research}, title={ChebyshevT}, year={2022}, url={https://reference.wolfram.com/language/ref/ChebyshevT.html}, note=[Accessed: 04-September-2026]}