WOLFRAM

Wolfram 语言与系统参考资料中心

ChebyshevT[n,x]

给出了第一类切比雪夫多项式 TemplateBox[{n, x}, ChebyshevT].

更多信息
Details and Options Details and Options
范例  
基本范例  
范围  
数值计算  
特殊值  
可视化  
Show More Show More
函数属性  
微分  
积分  
级数展开  
函数恒等式与化简  
推广和延伸  
应用  
属性和关系  
可能存在的问题  
巧妙范例  
参见
技术笔记
相关指南
相关链接
历史
按以下格式引用：

ChebyshevT

ChebyshevT[n,x]

给出了第一类切比雪夫多项式 TemplateBox[{n, x}, ChebyshevT].

更多信息

  • 数学函数，适宜于符号和数值计算.
  • 对于整数 n 给出了显式多项式.
  • TemplateBox[{n, {cos, , theta}}, ChebyshevT]=cos(ntheta).
  • 对于某些特殊参数，ChebyshevT 自动计算出精确值.
  • ChebyshevT 可以计算到任意数值精度.
  • ChebyshevT 自动逐项作用于列表的各个元素.
  • ChebyshevT[n,z] 在复平面 z 上有分支切割，从 到 ，如果 n 不是整数.
  • ChebyshevT 可与 Interval 和 CenteredInterval 对象一起使用. »

范例

打开所有单元 关闭所有单元

基本范例  (7)

数值化计算：

Wolfram Language code: ChebyshevT[2, 3]

计算 10 次切比雪夫多项式：

Wolfram Language code: ChebyshevT[10, x]

在实数的子集上绘图：

Wolfram Language code: Plot[ChebyshevT[10, x], {x, -1, 1}]

在复数的子集上绘图：

Wolfram Language code: ComplexPlot3D[ChebyshevT[5, z], {z, -2 - 2I, 2 + 2I}, PlotLegends -> Automatic]

在原点的级数展开式：

Wolfram Language code: Series[ChebyshevT[5, x], {x, 0, 5}]

在 Infinity 处的渐近展开式：

Wolfram Language code: Series[ChebyshevT[1 / 3, x], {x, ∞, 3}]//Normal//FullSimplify

在奇点处的渐近展开式：

Wolfram Language code: Series[ChebyshevT[1 / 3, x], {x, -1, 2}]//FullSimplify

范围  (44)

数值计算  (6)

数值化计算：

Wolfram Language code: ChebyshevT[2, 5]
Wolfram Language code: ChebyshevT[12, 2.5]

高精度计算：

Wolfram Language code: N[ChebyshevT[1 / 7, 1 / 3], 50]

输出的精度与输入的精度一致：

Wolfram Language code: ChebyshevT[0.3000000000000000000, 0]

复数输入：

Wolfram Language code: N[ChebyshevT[98 + I, I]]

高精度的高效计算：

Wolfram Language code: ChebyshevT[-1.5, -2.4`100]//Timing
Wolfram Language code: ChebyshevT[84, 63`10000000];//Timing

用 Interval 和 CenteredInterval 对象计算最坏情况下的区间：

Wolfram Language code: ChebyshevT[2, Interval[{1.9, 2.1}]]
Wolfram Language code: ChebyshevT[2, CenteredInterval[2, 1 / 100]]

或用 Around 计算一般情况下的统计区间：

Wolfram Language code: ChebyshevT[2, Around[2, 0.01]]

计算数组中每个元素的值：

Wolfram Language code: ChebyshevT[2, {{1, 2}, {3, 4}}]

或用 MatrixFunction 计算矩阵形式的 ChebyshevT 函数：

Wolfram Language code: MatrixFunction[ChebyshevT[2, #]&, {{1, 2}, {3, 4}}]

特殊值  (7)

在固定点的 ChebyshevT 的值：

Wolfram Language code: Table[ChebyshevT[n, Pi / 2], {n, 0, 3}]

符号 n 的 ChebyshevT:

Wolfram Language code: ChebyshevT[n, 0]

零处的值：

Wolfram Language code: ChebyshevT[0, 0]

无穷处的值：

Wolfram Language code: ChebyshevT[0, Infinity]
Wolfram Language code: ChebyshevT[Infinity, 0][[1, 1]]

求 ChebyshevT[5,x] 的第一个正极大值：

Wolfram Language code: xmax = x /. Solve[D[ChebyshevT[5, x], x] == 0 && 0 < x < π, x][[1]]
Wolfram Language code: Plot[ChebyshevT[5, x], {x, -1, 1}, Epilog -> Style[Point[{xmax, ChebyshevT[5, xmax]}], PointSize[Large], Red]]

计算相关的 ChebyshevT[7,x] 多项式：

Wolfram Language code: ChebyshevT[7, x]

计算 n 为半整数的 ChebyshevT[1/2,x] 多项式：

Wolfram Language code: ChebyshevT[1 / 2, x]

可视化  (3)

绘制各个阶数的 ChebyshevT 函数：

Wolfram Language code: Plot[{ChebyshevT[1, x], ChebyshevT[2, x], ChebyshevT[3, x], ChebyshevT[4, x]}, {x, -1, 1}]

绘制 TemplateBox[{3, z}, ChebyshevT] 实部：

Wolfram Language code: ComplexContourPlot[Re[ChebyshevT[3, z]], {z, -3 - 3 I, 3 + 3 I}, IconizedObject[«PlotOptions»]]

绘制 TemplateBox[{3, z}, ChebyshevT] 虚部：

Wolfram Language code: ComplexContourPlot[Im[ChebyshevT[3, z]], {z, -3 - 3 I, 3 + 3 I}, IconizedObject[«PlotOptions»]]

将切比雪夫多项式绘制成两个变量的函数：

Wolfram Language code: Plot3D[ChebyshevT[n, z], {n, 0, 5}, {z, -1, 1}]

函数属性  (14)

ChebyshevT 对区间 [-1,∞] 内的所有实数有定义：

Wolfram Language code: FunctionDomain[ChebyshevT[n, x], x]

ChebyshevT 对所有复数都有定义：

Wolfram Language code: FunctionDomain[ChebyshevT[n, z], z, Complexes]

TemplateBox[{1, x}, ChebyshevT] 的值域是所有实数和复数：

Wolfram Language code: FunctionRange[ChebyshevT[1, x], x, y]
Wolfram Language code: FunctionRange[ChebyshevT[1, z], z, y, Complexes]

TemplateBox[{2, x}, ChebyshevT] 的实数值域：

Wolfram Language code: FunctionRange[ChebyshevT[2, x], x, y]

值域是所有复数：

Wolfram Language code: FunctionRange[ChebyshevT[2, z], z, y, Complexes]

奇数阶的 Chebyshev 多项式是奇函数：

Wolfram Language code: ChebyshevT[1, -x] == -ChebyshevT[1, x]

偶数阶的 Chebyshev 多项式是偶函数：

Wolfram Language code: ChebyshevT[2, -x] == ChebyshevT[2, x]

ChebyshevT 逐项作用于列表的各个元素：

Wolfram Language code: ChebyshevT[{1, 2, 3}, x]

Chebyshev 多项式是解析的：

Wolfram Language code: FunctionAnalytic[ChebyshevT[n, x], x, Assumptions -> n∈ℤ]

一般情况下 ChebyshevT 既不是解析函数也不是亚纯函数：

Wolfram Language code: FunctionAnalytic[ChebyshevT[1 / 3, x], x, ℂ]
Wolfram Language code: FunctionMeromorphic[ChebyshevT[1 / 3, x], x]

TemplateBox[{2, x}, ChebyshevT] 既不是非递增，也不是非递减：

Wolfram Language code: FunctionMonotonicity[ChebyshevT[2, x], x]

TemplateBox[{2, x}, ChebyshevT] 不是单射函数：

Wolfram Language code: FunctionInjective[ChebyshevT[2, x], x]

TemplateBox[{1, x}, ChebyshevT] 是单射函数：

Wolfram Language code: FunctionInjective[ChebyshevT[1, x], x]
Wolfram Language code: Plot[{ChebyshevT[1, x], ChebyshevT[2, x], 2}, {x, -2, 2}]

TemplateBox[{2, x}, ChebyshevT] 不是满射函数：

Wolfram Language code: FunctionSurjective[ChebyshevT[2, x], x]

TemplateBox[{1, x}, ChebyshevT] 是：

Wolfram Language code: FunctionSurjective[ChebyshevT[1, x], x]
Wolfram Language code: Plot[{ChebyshevT[1, x], ChebyshevT[2, x], 2}, {x, -2, 2}]

TemplateBox[{2, x}, ChebyshevT] 既不是非负，也不是非正：

Wolfram Language code: FunctionSign[ChebyshevT[2, x], x]

不是整数时，对于 ，TemplateBox[{n, x}, ChebyshevT] 有奇点和断点：

Wolfram Language code: FunctionSingularities[ChebyshevT[n, x], x]
Wolfram Language code: FunctionDiscontinuities[ChebyshevT[n, x], x]

TemplateBox[{2, x}, ChebyshevT] 是凸函数：

Wolfram Language code: FunctionConvexity[ChebyshevT[2, x], x]

TraditionalForm 格式：

Wolfram Language code: ChebyshevT[n, x]//TraditionalForm

微分  (3)

关于 x 的一阶导数：

Wolfram Language code: D[ChebyshevT[n, x] , x]

关于 x 的高阶导数：

Wolfram Language code: Table[D[ChebyshevT[n, x], {x, k}], {k, 1, 3}]//Simplify

绘制 n=5 时关于 x 的高阶导数：

Wolfram Language code: Plot[Evaluate[% /. n -> 5], {x, -1, 1}, PlotLegends -> {"First Derivative", "Second Derivative", "Third Derivative"}]

关于 x 的 阶导数的公式：

Wolfram Language code: D[ChebyshevT[n, x], {x, k}]// FullSimplify

积分  (4)

用 Integrate 计算不定积分：

Wolfram Language code: Integrate[ChebyshevT[n, x], x]

验证反导数：

Wolfram Language code: FullSimplify[D[%, x]]

定积分：

Wolfram Language code: Integrate[ChebyshevT[n, x], {x, 0, 4}]

奇整数阶数的 ChebyshevT 在一个周期内的定积分是 0：

Wolfram Language code: Integrate[ChebyshevT[2n - 1, x], {x, -5, 5}]
Wolfram Language code: Table[%, {n, 3, 11, 2}]//FullSimplify

更多积分：

Wolfram Language code: Integrate[ChebyshevT[3, x]ChebyshevT[5, x], x]//FullSimplify
Wolfram Language code: Integrate[Exp[x] ChebyshevT[5, x], {x, 0, 5}]//FullSimplify

级数展开  (3)

用 Series 求泰勒展开式：

Wolfram Language code: Series[ChebyshevT[n, x], {x, 0, 3}]

绘制 附近的前三个近似：

Wolfram Language code: terms = Normal@Table[Series[ChebyshevT[10, x], {x, 0, m}], {m, 1, 5, 2}]; Plot[{ChebyshevT[10, x], terms}, {x, -1, 1}, PlotRange -> {-3, 3}]

用 SeriesCoefficient 给出级数展开式的通项：

Wolfram Language code: SeriesCoefficient[ChebyshevT[n, x], {x, 0, n}]

普通点的泰勒展开：

Wolfram Language code: Series[ChebyshevT[n, x], {x, x0, 2}]

函数恒等式与化简  (4)

通过恒等定义 ChebyshevT：

Wolfram Language code: ChebyshevT[n, Cos[θ]] == Cos[n θ]//FullSimplify

ChebyshevT 的普通母函数：

Wolfram Language code: Sum[ChebyshevT[n, x]t^n, {n, 0, Infinity}]

ChebyshevT 的指数母函数：

Wolfram Language code: Sum[ChebyshevT[n, x]t^n / n!, {n, 0, Infinity}]

递归关系：

Wolfram Language code: ChebyshevT[n, z] == 2 z ChebyshevT[n + 1, z] - ChebyshevT[n + 2, z]//FullSimplify
Wolfram Language code: ChebyshevT[n - 1, z] + ChebyshevT[n + 1, z] == 2 z ChebyshevT[n, z]//FullSimplify

推广和延伸  (2)

可将 ChebyshevT 用于幂级数：

Wolfram Language code: ChebyshevT[1 / 3, Sin[x] + O[x] ^ 3]

ChebyshevT 可用于 Interval:

Wolfram Language code: ChebyshevT[10, Interval[{-1, 1}]]

应用  (4)

绘制前 10 个切比雪夫多项式：

Wolfram Language code: Plot[Evaluate[Table[ChebyshevT[n, x], {n, 0, 5}]], {x, -1, 1}]

求函数 Clip[4 x] 极小化的极大近似值：

Wolfram Language code: c = Table[(2/π)Subsuperscript[∫, -1, 1]Clip[4 x](ChebyshevT[n, x]/Sqrt[1 - x^2])ⅆx, {n, 0, 5}]
Wolfram Language code: Plot[ {Clip[4 x], -First[c] / 2 + Evaluate[c . Table[ChebyshevT[n - 1, x], {n, Length[c]}]]}, {x, -1, 1}]

获取切比雪夫多项式中的函数展开式：

Wolfram Language code: f[x_] := 1 / (1 + (5x) ^ 2);

切比雪夫节点上的函数值：

Wolfram Language code: n = 47; cnodes = N[Cos[Pi Range[0, n] / n]]; fc = Map[f, cnodes]; pf = ListPlot[Transpose[{cnodes, fc}], PlotRange -> All]

求切比雪夫系数：

Wolfram Language code: cc = FourierDCT[fc, 1] * Sqrt[2 / n]; cc[[{1, -1}]] /= 2;

显示误差：

Wolfram Language code: Plot[f[x] - Sum[ChebyshevT[i - 1, x] * cc[[i]], {i, Length[cc]}], {x, -1, 1}, PlotRange -> All]

用 ChebyshevT 函数作为非齐次部分，解微分方程：

Wolfram Language code: DSolve[y''[x] + ChebyshevT[n, x] == 0, y[x], x]

属性和关系  (7)

ChebyshevT 与 FullSimplify 联合使用：

Wolfram Language code: FullSimplify[ChebyshevT[10, Cos[x]]]

比较展开的三角函数表达式与 ChebyshevT：

Wolfram Language code: FunctionExpand[Cos[10ArcCos[x]]]//Expand
Wolfram Language code: ChebyshevT[10, x]

用 ChebyshevU 来表示 ChebyshevT 的导数：

Wolfram Language code: D[ChebyshevT[n, x], x]

可以用 DifferenceRoot 来表示 ChebyshevT：

Wolfram Language code: DifferenceRootReduce[ChebyshevT[k, z], k]

ChebyshevT 级数展开式中的一般项：

Wolfram Language code: SeriesCoefficient[ChebyshevT[a, x], {x, 0, n}]

ChebyshevT 的母函数：

Wolfram Language code: GeneratingFunction[ChebyshevT[n, k], n, x]

ChebyshevT 的指数母函数：

Wolfram Language code: ExponentialGeneratingFunction[ChebyshevT[n, k], n, x]

可能存在的问题  (1)

多项式形式中的相约可能导致不准确的数值结果：

Wolfram Language code: ChebyshevT[60, x] /. x -> N[2 / 3, 16]

直接计算函数：

Wolfram Language code: ChebyshevT[60, N[2 / 3, 16] ]

巧妙范例  (1)

绘制前几个 Banchoff–Chmutov 曲面：

Wolfram Language code: Table[ContourPlot3D[ChebyshevT[2k, x] + ChebyshevT[2k, y] + ChebyshevT[2k, z] == 0, {x, -5 / 4, 5 / 4}, {y, -5 / 4, 5 / 4}, {z, -5 / 4, 5 / 4}, Axes -> None, Boxed -> False], {k, 4}]//GraphicsRow
Wolfram Research (1988)，ChebyshevT，Wolfram 语言函数，https://reference.wolfram.com/language/ref/ChebyshevT.html （更新于 2022 年）.

文本

Wolfram Research (1988)，ChebyshevT，Wolfram 语言函数，https://reference.wolfram.com/language/ref/ChebyshevT.html （更新于 2022 年）.

CMS

Wolfram 语言. 1988. "ChebyshevT." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2022. https://reference.wolfram.com/language/ref/ChebyshevT.html.

APA

Wolfram 语言. (1988). ChebyshevT. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/ChebyshevT.html 年

BibTeX

@misc{reference.wolfram_2026_chebyshevt, author="Wolfram Research", title="{ChebyshevT}", year="2022", howpublished="\url{https://reference.wolfram.com/language/ref/ChebyshevT.html}", note=[Accessed: 13-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_chebyshevt, organization={Wolfram Research}, title={ChebyshevT}, year={2022}, url={https://reference.wolfram.com/language/ref/ChebyshevT.html}, note=[Accessed: 13-August-2026]}