WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

Checkbox[x]

x がTrueのときは，x がFalseのときはと表示されるように x を設定したチェックボックスを表す．

Checkbox[Dynamic[x]]

x の動的に更新された現行値を設定値にする．x の値はチェックボックスがクリックされると切り換えられる．

Checkbox[x,{val1,val2}]

値 val1 と val2 を切り換え，それぞれととして表すチェックボックスを表す．

Checkbox[x,{val1,val2,val3,…}]

値 vali を巡回し，i>2であるすべての vali についてを表示するチェックボックスを表す．

詳細とオプション
Details and Options Details and Options
例題  
例  
スコープ  
オプション  
Appearance  
AutoAction  
BaselinePosition  
Enabled  
ImageMargins  
アプリケーション  
特性と関係  
関連項目
テクニカルノート
関連するガイド
関連するワークフロー
履歴
引用書式

Checkbox

Checkbox[x]

x がTrueのときは，x がFalseのときはと表示されるように x を設定したチェックボックスを表す．

Checkbox[Dynamic[x]]

x の動的に更新された現行値を設定値にする．x の値はチェックボックスがクリックされると切り換えられる．

Checkbox[x,{val1,val2}]

値 val1 と val2 を切り換え，それぞれととして表すチェックボックスを表す．

Checkbox[x,{val1,val2,val3,…}]

値 vali を巡回し，i>2であるすべての vali についてを表示するチェックボックスを表す．

詳細とオプション

例題

すべて開く すべて閉じる

例  (2)

Checkboxのデフォルト状態：

Wolfram Language code: {Checkbox[False], Checkbox[True]}

状態で異なる値を使う：

Wolfram Language code: {Checkbox[1, {1, 2, 3}], Checkbox[2, {1, 2, 3}], Checkbox[3, {1, 2, 3}]}

スコープ  (3)

Dynamic変数をCheckbox内で使うと，変数の状態が動的に更新される：

Wolfram Language code: {Checkbox[Dynamic[x]], Dynamic[x]}

以下では，xの値がリスト{1,2,3,4}を循環する：

Wolfram Language code: {Checkbox[Dynamic[x], {1, 2, 3, 4}], Dynamic[x]}

複数のチェックボックスが同じ状態変数を共有することができる：

Wolfram Language code: {Checkbox[Dynamic[x], {2, 1}], Checkbox[Dynamic[x], {1, 2}], Dynamic[x]}

オプション  (8)

Appearance  (2)

チェックボックスの外観を制御する：

Wolfram Language code: Table[Checkbox[Appearance -> a], {a, {Tiny, Small, Medium, Large}}]

動的に変更される外観：

Wolfram Language code: {Checkbox[Dynamic[x], {Tiny, Large}, Appearance -> Dynamic[x]], Dynamic[x]}

AutoAction  (2)

デフォルト設定では，クリックされるまではチェックボックスの状態は変化しない：

Wolfram Language code: Checkbox[]

AutoActionに設定すると，マウスが上に来るとチェックボックスの状態が変化する：

Wolfram Language code: Checkbox[AutoAction -> True]

カーソルがクリック可能なエリアを移動すると値が変化する：

Wolfram Language code: Checkbox[Dynamic[x], AutoAction -> True]

BaselinePosition  (1)

周囲のテキストと揃える：

Wolfram Language code: Row[Table[Checkbox[BaselinePosition -> b], {b, {Bottom, Center, Top}}], "xxx"]

Enabled  (2)

Enabledオプションによってチェックボックスが変更できるようになる：

Wolfram Language code: {Checkbox[Dynamic[x], Enabled -> False], Checkbox[Dynamic[x], Enabled -> True]}

アプリケーション内での使用でEnabledオプションを動的に変更することができる：

Wolfram Language code: {Checkbox[Dynamic[x]], Checkbox[Dynamic[y], Enabled -> Dynamic[x]]}

ImageMargins  (1)

画像周囲の余白を変更する：

Wolfram Language code: Table[Framed@Checkbox[ImageMargins -> m], {m, {0, 5, 10, 30}}]

アプリケーション  (4)

Checkboxを使って三段階の灯りのスイッチに対応する変数を設定する：

Wolfram Language code: Row[{Checkbox[Dynamic[x]], Checkbox[Dynamic[y]], Checkbox[Dynamic[z]], "⟹", Dynamic[Xor[x, y, z]]}]

チェックボックスでオプションを制御する：

Wolfram Language code: {AxesLabel -> {Checkbox[Dynamic[xlab], {"", "x"}, Enabled -> Dynamic[axes]], Checkbox[Dynamic[ylab], {"", "y"}, Enabled -> Dynamic[axes]]}, Axes -> Checkbox[Dynamic[axes], {False, True}]}
Wolfram Language code: Graphics[{Opacity[.5], Table[{Hue[RandomReal[]], Rectangle[RandomReal[2, 2]]}, {20}]}, AxesLabel -> {Dynamic[xlab], Dynamic[ylab]}, Axes -> Dynamic[axes]]

チェックボックスを使って動的な真理値表を構築する：

Wolfram Language code: DynamicTruthTable[f_, vars_] := DynamicModule[{v, arr, e, tt}, (* localize *) v = Array[arr, {Length[vars]}]; e = Function[Evaluate[f /. Thread[vars -> Array[Slot, {Length[vars]}]]]]; (* truth table *) tt = Grid[{Append[vars, TraditionalForm[f]], Append[Map[Composition[Checkbox, Dynamic], v], Apply[Composition[Dynamic, Evaluate[e]], v]]}, Dividers -> {All, All}]; (* initialize *) Do[arr[i] = False, {i, Length[vars]}]; tt ]
Wolfram Language code: DynamicTruthTable[And[Or[a, b], b, c], {a, b, c}]

Checkbox内でクリックされた回数を数える：

Wolfram Language code: DynamicModule[{x = False, changeCount = 0}, Column[{Checkbox[Dynamic[x, (x = #;changeCount++)&], {False, True}], Row[{"xは", Dynamic[x]}], Row[{"xは", Dynamic[changeCount], "回変更された．"}]}]]

特性と関係  (1)

CheckboxはTogglerの特殊なケースである：

Wolfram Language code: {Toggler[Dynamic[x], {False, True}], Dynamic[x]}
Wolfram Language code: {Checkbox[Dynamic[y]], Dynamic[y]}
Wolfram Research (2007), Checkbox, Wolfram言語関数， https://reference.wolfram.com/language/ref/Checkbox.html.

テキスト

Wolfram Research (2007), Checkbox, Wolfram言語関数， https://reference.wolfram.com/language/ref/Checkbox.html.

CMS

Wolfram Language. 2007. "Checkbox." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/Checkbox.html.

APA

Wolfram Language. (2007). Checkbox. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/Checkbox.html

BibTeX

@misc{reference.wolfram_2026_checkbox, author="Wolfram Research", title="{Checkbox}", year="2007", howpublished="\url{https://reference.wolfram.com/language/ref/Checkbox.html}", note=[Accessed: 10-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_checkbox, organization={Wolfram Research}, title={Checkbox}, year={2007}, url={https://reference.wolfram.com/language/ref/Checkbox.html}, note=[Accessed: 10-September-2026]}