WOLFRAM

Wolfram 语言与系统参考资料中心

Checkbox[x]

表示设置 x 的复选框，当 x 为 True 时显示为 ，当 x 为 False 时显示为 .

Checkbox[Dynamic[x]]

取动态更新的 x 当前值，若单击复选框，则切换 x 的值.

Checkbox[x,{val1,val2}]

表示在值 val1 和 val2 之间切换的复选框，并分别显示为 和 .

Checkbox[x,{val1,val2,val3,…}]

表示循环贯穿值 vali 的复选框，且对所有 i>2 的 vali 显示为 .

更多信息和选项
Details and Options Details and Options
范例  
基本范例  
范围  
选项  
Appearance  
AutoAction  
BaselinePosition  
Enabled  
ImageMargins  
应用  
属性和关系  
参见
技术笔记
相关指南
相关的工作流程
历史
按以下格式引用：

Checkbox

Checkbox[x]

表示设置 x 的复选框，当 x 为 True 时显示为 ，当 x 为 False 时显示为 .

Checkbox[Dynamic[x]]

取动态更新的 x 当前值，若单击复选框，则切换 x 的值.

Checkbox[x,{val1,val2}]

表示在值 val1 和 val2 之间切换的复选框，并分别显示为 和 .

Checkbox[x,{val1,val2,val3,…}]

表示循环贯穿值 vali 的复选框，且对所有 i>2 的 vali 显示为 .

更多信息和选项

范例

打开所有单元 关闭所有单元

基本范例  (2)

Checkbox 的缺省状态：

Wolfram Language code: {Checkbox[False], Checkbox[True]}

用不同的状态值：

Wolfram Language code: {Checkbox[1, {1, 2, 3}], Checkbox[2, {1, 2, 3}], Checkbox[3, {1, 2, 3}]}

范围  (3)

通过在 Checkbox 内使用 Dynamic 变量，可动态更新状态变量：

Wolfram Language code: {Checkbox[Dynamic[x]], Dynamic[x]}

在这里，x 的值循环贯穿列表 {1,2,3,4}：

Wolfram Language code: {Checkbox[Dynamic[x], {1, 2, 3, 4}], Dynamic[x]}

几个复选框可共享同一个状态变量：

Wolfram Language code: {Checkbox[Dynamic[x], {2, 1}], Checkbox[Dynamic[x], {1, 2}], Dynamic[x]}

选项  (8)

Appearance  (2)

控制复选框的外观：

Wolfram Language code: Table[Checkbox[Appearance -> a], {a, {Tiny, Small, Medium, Large}}]

动态改变外观：

Wolfram Language code: {Checkbox[Dynamic[x], {Tiny, Large}, Appearance -> Dynamic[x]], Dynamic[x]}

AutoAction  (2)

缺省情况下，复选框在没有被点击时不会改变状态：

Wolfram Language code: Checkbox[]

设置 AutoAction 后，当鼠标移至复选框上，复选框改变状态：

Wolfram Language code: Checkbox[AutoAction -> True]

当光标移至可点击区域，值会改变：

Wolfram Language code: Checkbox[Dynamic[x], AutoAction -> True]

BaselinePosition  (1)

与周围文本对齐：

Wolfram Language code: Row[Table[Checkbox[BaselinePosition -> b], {b, {Bottom, Center, Top}}], "xxx"]

Enabled  (2)

Enabled 选项允许复选框被改变：

Wolfram Language code: {Checkbox[Dynamic[x], Enabled -> False], Checkbox[Dynamic[x], Enabled -> True]}

在应用中，Enabled 选项可被动态改变：

Wolfram Language code: {Checkbox[Dynamic[x]], Checkbox[Dynamic[y], Enabled -> Dynamic[x]]}

ImageMargins  (1)

改变图像周围的边幅：

Wolfram Language code: Table[Framed@Checkbox[ImageMargins -> m], {m, {0, 5, 10, 30}}]

应用  (4)

用 Checkbox 对应一个三向灯开关设置变量：

Wolfram Language code: Row[{Checkbox[Dynamic[x]], Checkbox[Dynamic[y]], Checkbox[Dynamic[z]], "⟹", Dynamic[Xor[x, y, z]]}]

通过复选框控制选项：

Wolfram Language code: {AxesLabel -> {Checkbox[Dynamic[xlab], {"", "x"}, Enabled -> Dynamic[axes]], Checkbox[Dynamic[ylab], {"", "y"}, Enabled -> Dynamic[axes]]}, Axes -> Checkbox[Dynamic[axes], {False, True}]}
Wolfram Language code: Graphics[{Opacity[.5], Table[{Hue[RandomReal[]], Rectangle[RandomReal[2, 2]]}, {20}]}, AxesLabel -> {Dynamic[xlab], Dynamic[ylab]}, Axes -> Dynamic[axes]]

用复选框建立一个动态真值表：

Wolfram Language code: DynamicTruthTable[f_, vars_] := DynamicModule[{v, arr, e, tt}, (* localize *) v = Array[arr, {Length[vars]}]; e = Function[Evaluate[f /. Thread[vars -> Array[Slot, {Length[vars]}]]]]; (* truth table *) tt = Grid[{Append[vars, TraditionalForm[f]], Append[Map[Composition[Checkbox, Dynamic], v], Apply[Composition[Dynamic, Evaluate[e]], v]]}, Dividers -> {All, All}]; (* initialize *) Do[arr[i] = False, {i, Length[vars]}]; tt ]
Wolfram Language code: DynamicTruthTable[And[Or[a, b], b, c], {a, b, c}]

计算一个Checkbox中的点击次数：

Wolfram Language code: DynamicModule[{x = False, changeCount = 0}, Column[{Checkbox[Dynamic[x, (x = #;changeCount++)&], {False, True}], Row[{"x is ", Dynamic[x]}], Row[{"x has been changed ", Dynamic[changeCount], " times."}]}]]

属性和关系  (1)

Checkbox 是 Toggler 的一个特例：

Wolfram Language code: {Toggler[Dynamic[x], {False, True}], Dynamic[x]}
Wolfram Language code: {Checkbox[Dynamic[y]], Dynamic[y]}
Wolfram Research (2007)，Checkbox，Wolfram 语言函数，https://reference.wolfram.com/language/ref/Checkbox.html.

文本

Wolfram Research (2007)，Checkbox，Wolfram 语言函数，https://reference.wolfram.com/language/ref/Checkbox.html.

CMS

Wolfram 语言. 2007. "Checkbox." Wolfram 语言与系统参考资料中心. Wolfram Research. https://reference.wolfram.com/language/ref/Checkbox.html.

APA

Wolfram 语言. (2007). Checkbox. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/Checkbox.html 年

BibTeX

@misc{reference.wolfram_2026_checkbox, author="Wolfram Research", title="{Checkbox}", year="2007", howpublished="\url{https://reference.wolfram.com/language/ref/Checkbox.html}", note=[Accessed: 07-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_checkbox, organization={Wolfram Research}, title={Checkbox}, year={2007}, url={https://reference.wolfram.com/language/ref/Checkbox.html}, note=[Accessed: 07-September-2026]}