WOLFRAM

Wolfram 语言与系统参考资料中心

ClearAll[s1,s2,…]

清除符号 si 的所有值、定义、属性、默认值、选项和信息.

ClearAll[patt1,patt2,…]

清除所有名称在文字上匹配任意字符串模式 patti 的符号.

ClearAll[{spec1,spec,…}]

清除任何等于或其名称与任何 speci 相匹配的符号.

更多信息
Details and Options Details and Options
范例  
基本范例  
范围  
符号输入  
使用模式  
应用  
属性和关系  
可能存在的问题  
参见
技术笔记
相关指南
相关的工作流程
历史
按以下格式引用：

ClearAll

ClearAll[s1,s2,…]

清除符号 si 的所有值、定义、属性、默认值、选项和信息.

ClearAll[patt1,patt2,…]

清除所有名称在文字上匹配任意字符串模式 patti 的符号.

ClearAll[{spec1,spec,…}]

清除任何等于或其名称与任何 speci 相匹配的符号.

更多信息

范例

打开所有单元 关闭所有单元

基本范例  (1)

定义符号的值和属性：

Wolfram Language code: SetAttributes[f, Listable]; f[x_] := x ^ 2
Wolfram Language code: Definition[f]

清除值和属性：

Wolfram Language code: ClearAll[f]
Wolfram Language code: Definition[f]

范围  (16)

符号输入  (11)

清除所有变量的值(ownvalues)：

Wolfram Language code: x = 5;
Wolfram Language code: x
Wolfram Language code: ClearAll[x]
Wolfram Language code: x

清除函数（下值（downvalue）集）：

Wolfram Language code: fact[1] = 1; fact[n_] := n fact[n - 1]
Wolfram Language code: fact[3]
Wolfram Language code: ClearAll[fact]
Wolfram Language code: fact[3]

清除上值（upvalue）集：

Wolfram Language code: h/:f[h[x_]] := hf[x]
Wolfram Language code: f[h[x]]
Wolfram Language code: ClearAll[h]
Wolfram Language code: f[h[x]]

清除子值：

Wolfram Language code: f[x_][y_] := h[x, y]
Wolfram Language code: f[x][y]
Wolfram Language code: ClearAll[f]
Wolfram Language code: f[x][y]

清除格式：

Wolfram Language code: Format[kappa] := κ
Wolfram Language code: kappa
Wolfram Language code: ClearAll[kappa]
Wolfram Language code: kappa

清除属性：

Wolfram Language code: SetAttributes[f, Listable];
Wolfram Language code: f[{x, y}]
Wolfram Language code: ClearAll[f]
Wolfram Language code: f[{x, y}]

清除默认值：

Wolfram Language code: Default[f] = 0; f[x_.] := x ^ 2
Wolfram Language code: f[]
Wolfram Language code: ClearAll[f]
Wolfram Language code: f[]

清除选项：

Wolfram Language code: Options[f] = {opt1 -> def1, opt2 -> def2};
Wolfram Language code: OptionValue[f, opt1]
Wolfram Language code: ClearAll[f]
Wolfram Language code: OptionValue[f, opt1]

清除消息：

Wolfram Language code: f::usage = "f[x] gives (x - 1)(x + 1)";
Wolfram Language code: Message[f::usage]
Wolfram Language code: ClearAll[f]
Wolfram Language code: Message[f::usage]

清除若干符号：

Wolfram Language code: a = 5; f[x_] := x ^ 3
Wolfram Language code: f[a]
Wolfram Language code: ClearAll[a, f]
Wolfram Language code: f[a]

使用符号和符号名称的组合：

Wolfram Language code: x1 = 1;x2 = 3;x3 = 5;
Wolfram Language code: ClearAll[{x1, "x2"}]

仅有 x3 还有定义：

Wolfram Language code: {x1, x2, x3}

使用模式  (5)

指明符号，以字符串模式的形式清除：

Wolfram Language code: x1 = 1;x2 = 3;y = 5;
Wolfram Language code: ClearAll["x*"]
Wolfram Language code: {x1, x2, y}

清除当前上下文中的所有符号：

Wolfram Language code: x1 = 1;x2 = 3;y = 5;
Wolfram Language code: ClearAll["`*"]
Wolfram Language code: {x1, x2, y}

清除给定上下文中的所有符号：

Wolfram Language code: abc`x1 = 1;abc`x2 = 3;abc`y = 5;
Wolfram Language code: ClearAll["abc`*"]
Wolfram Language code: {abc`x1, abc`x2, abc`y}

使用 StringExpression 清除当前环境中的所有 2 个字符的符号：

Wolfram Language code: x1 = 1;x2 = 3;y = 5;
Wolfram Language code: ClearAll["`" ~~ _ ~~ _]

符号 x1 和 x2 已被清除，但是 y 不受影响：

Wolfram Language code: {x1, x2, y}

使用 RegularExpression 清除当前环境中的所有 3 个字符的符号：

Wolfram Language code: x = 1;yy = 3;zzz = 5;
Wolfram Language code: ClearAll[RegularExpression["`..."]]
Wolfram Language code: {x, yy, zzz}

应用  (2)

在生成一个新定义前，清除以前的任何定义：

Wolfram Language code: ClearAll[fib]
Wolfram Language code: fib[1] = fib[2] = 1; fib[n_] := fib[n] = fib[n - 1] + fib[n - 2]
Wolfram Language code: fib[5]

对软件包中的所有符号取消保护并清除， 以便使它被读取两次：

Wolfram Language code: Begin["`Private`"];
Wolfram Language code: Unprotect["`*"]; ClearAll["`*"];
Wolfram Language code: f[x_] := x ^ 2
Wolfram Language code: Protect[f];
Wolfram Language code: End[];

属性和关系  (6)

ClearAll[pattern] 与 ClearAll/@Names[pattern] 清除相同的符号：

Wolfram Language code: x = 1;y = 2; xy = 3; ClearAll["x*"]; {x, y, xy}
Wolfram Language code: x = 1;y = 2; xy = 3; ClearAll /@ Names["x*"]; {x, y, xy}

Clear 不删除属性, 缺省值或选项：

Wolfram Language code: SetAttributes[f, Listable]; Default[f] = 0; Options[f] = {opt1 -> def1, opt2 -> def2}; f[x_.] := x ^ 2
Wolfram Language code: Clear[f]
Wolfram Language code: Definition[f]

利用 ClearAll 清除一切：

Wolfram Language code: ClearAll[f]
Wolfram Language code: Definition[f]

Clear 不会删除消息：

Wolfram Language code: f::usage = "f[x] gives (x - 1)(x + 1)";
Wolfram Language code: Clear[f]
Wolfram Language code: Message[f::usage]

使用 ClearAll 可清除消息：

Wolfram Language code: ClearAll[f]
Wolfram Language code: Message[f::usage]

ClearAll 删除所有的属性和定义，但保留符号：

Wolfram Language code: SetAttributes[f, Listable]; f[x_] := x ^ 2
Wolfram Language code: ClearAll[f]
Wolfram Language code: ? f

Remove 彻底删除该符号：

Wolfram Language code: Remove[f]
Wolfram Language code: ? f

利用 Unset (=.) 清除特定左手边的定义：

Wolfram Language code: SetAttributes[fact, Listable]; fact[0] = 1; fact[n_Integer] /; n > 0 := n fact[n - 1] fact[n_Integer] /; n < 0 := -∞
Wolfram Language code: fact[0]=.
Wolfram Language code: Definition[fact]

清除所有的定义和属性：

Wolfram Language code: ClearAll[fact]
Wolfram Language code: Definition[fact]

ClearAll 有属性 HoldAll：

Wolfram Language code: Definition[ClearAll]

以下运算清除 symbol 本身：

Wolfram Language code: symbol = {"x", "y", "z"};x = 1;y = 3;z = 5;
Wolfram Language code: ClearAll[symbol]
Wolfram Language code: {symbol, x, y, z}

以下运算清除其值：

Wolfram Language code: symbol = {"x", "y", "z"};
Wolfram Language code: ClearAll[Evaluate[symbol]]
Wolfram Language code: {symbol, x, y, z}

可能存在的问题  (3)

受保护的符号不能被清除：

Wolfram Language code: x = 5; Protect[x];
Wolfram Language code: ClearAll[x]

利用 Unprotect 清除受保护符号的定义：

Wolfram Language code: Unprotect[x]; ClearAll[x]

Clear 可以清除锁定符号的值和定义：

Wolfram Language code: f[x_] := x ^ 2; SetAttributes[f, Locked]
Wolfram Language code: Definition[f]
Wolfram Language code: Clear[f]
Wolfram Language code: Definition[f]

ClearAll 不影响锁定的符号：

Wolfram Language code: f[x_] := x ^ 2
Wolfram Language code: ClearAll[f]
Wolfram Language code: Definition[f]

当使用没有上下文标记的模式时，$ContextPath 上的所有匹配符号被清除：

Wolfram Language code: x = 1;y = 2;xy = 3; ClearAll[_ ~~ _]

符号 xy 被清除，顺带尝试清除数个系统符号：

Wolfram Language code: xy

使用带有明确上下文标记的模式，避免与系统或其他上下文中的符号潜在匹配：

Wolfram Language code: ClearAll["`" ~~ _]
Wolfram Research (1988)，ClearAll，Wolfram 语言函数，https://reference.wolfram.com/language/ref/ClearAll.html （更新于 2022 年）.

文本

Wolfram Research (1988)，ClearAll，Wolfram 语言函数，https://reference.wolfram.com/language/ref/ClearAll.html （更新于 2022 年）.

CMS

Wolfram 语言. 1988. "ClearAll." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2022. https://reference.wolfram.com/language/ref/ClearAll.html.

APA

Wolfram 语言. (1988). ClearAll. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/ClearAll.html 年

BibTeX

@misc{reference.wolfram_2026_clearall, author="Wolfram Research", title="{ClearAll}", year="2022", howpublished="\url{https://reference.wolfram.com/language/ref/ClearAll.html}", note=[Accessed: 18-July-2026]}

BibLaTeX

@online{reference.wolfram_2026_clearall, organization={Wolfram Research}, title={ClearAll}, year={2022}, url={https://reference.wolfram.com/language/ref/ClearAll.html}, note=[Accessed: 18-July-2026]}