WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

CoefficientRules[poly,{x1,x2,…}]

poly 中の xiについての単項式の指数ベクトルと係数のリスト{{e11,e12,…}c1,{e21,…}c2,…}を返す．

CoefficientRules[poly,{x1,x2,…},order]

order で指定された単項式の順序付けで結果を返す．

詳細とオプション
Details and Options Details and Options
例題  
例  
スコープ  
オプション  
Modulus  
特性と関係  
考えられる問題  
おもしろい例題  
関連項目
テクニカルノート
関連するガイド
履歴
引用書式

CoefficientRules

CoefficientRules[poly,{x1,x2,…}]

poly 中の xiについての単項式の指数ベクトルと係数のリスト{{e11,e12,…}c1,{e21,…}c2,…}を返す．

CoefficientRules[poly,{x1,x2,…},order]

order で指定された単項式の順序付けで結果を返す．

詳細とオプション

例題

すべて開く すべて閉じる

例  (1)

単項式の指数と係数を求める：

Wolfram Language code: CoefficientRules[(x + y) ^ 3]

スコープ  (1)

"DegreeReverseLexicographic"単項式順序を使う：

Wolfram Language code: CoefficientRules[a x y ^ 2 + b x ^ 2 z, {x, y, z}, "DegreeReverseLexicographic"]

重み行列を使って同じ順序を指定する：

Wolfram Language code: CoefficientRules[a x y ^ 2 + b x ^ 2 z, {x, y, z}, {{1, 1, 1}, {0, 0, -1}, {0, -1, 0}}]

オプション  (1)

Modulus  (1)

係数を2を法として簡約する：

Wolfram Language code: CoefficientRules[(x + 1) ^ 5, x, Modulus -> 2]

特性と関係  (2)

FromCoefficientRulesはもとの多項式を再構築する：

Wolfram Language code: CoefficientRules[a x ^ 2 + b x y + c y ^ 2, {x, y}]
Wolfram Language code: FromCoefficientRules[%, {x, y}]

MonomialListは別の表現を与える：

Wolfram Language code: MonomialList[a x ^ 2 + b x y + c y ^ 2, {x, y}]

二変数では"DegreeLexicographic"と"DegreeReverseLexicographic"は一致する：

Wolfram Language code: poly = Sum[RandomInteger[{-10, 10}]x ^ RandomInteger[10]y ^ RandomInteger[10], {20}]
Wolfram Language code: CoefficientRules[poly, {x, y}, "DegreeLexicographic"] === CoefficientRules[poly, {x, y}, "DegreeReverseLexicographic"]

考えられる問題  (1)

Variables[poly]に与えられたこのリストは常に保存される訳ではない：

Wolfram Language code: Variables[y + x z]
Wolfram Language code: CoefficientRules[y + x z]
Wolfram Language code: FromCoefficientRules[%, {y, x, z}]

おもしろい例題  (2)

単項式順序を二次元で可視化する：

Wolfram Language code: MonomialOrderPlot[poly_, {x1_, x2_}, ord_ : "Lexicographic", o : OptionsPattern[]] := Graphics[{Blue, Arrow /@ Partition[CoefficientRules[poly, {x1, x2}, ord][[All, 1]], 2, 1]}, Sequence@@FilterRules[{o}, Options[Graphics]]]

標準組込み順序：

Wolfram Language code: orders = {"Lexicographic", "DegreeLexicographic", "DegreeReverseLexicographic", "NegativeLexicographic", "NegativeDegreeLexicographic", "NegativeDegreeReverseLexicographic"};

二次元では，区別できない順序がある：

Wolfram Language code: Table[MonomialOrderPlot[Sum[x ^ i y ^ j, {i, 0, 5}, {j, 0, 5}], {x, y}, o, PlotLabel -> Style[o, Small]], {o, orders}]

単項式順序を三次元で可視化する：

Wolfram Language code: MonomialOrderPlot3D[poly_, {x1_, x2_, x3_}, ord_ : "Lexicographic", o : OptionsPattern[]] := Graphics3D[{Arrowheads[.06], Arrow[Tube[#, .02]]& /@ Partition[CoefficientRules[poly, {x1, x2, x3}, ord][[All, 1]], 2, 1]}, Sequence@@FilterRules[{o}, Options[Graphics3D]]]
Wolfram Language code: orders = {"Lexicographic", "DegreeLexicographic", "DegreeReverseLexicographic", "NegativeLexicographic", "NegativeDegreeLexicographic", "NegativeDegreeReverseLexicographic"};

三次元では順序の違いがよく分かる：

Wolfram Language code: Table[MonomialOrderPlot3D[Sum[x ^ i y ^ j z ^ k, {i, 0, 2}, {j, 0, 2}, {k, 0, 2}], {x, y, z}, o, PlotLabel -> Style[o, Small]], {o, orders}]
Wolfram Research (2008), CoefficientRules, Wolfram言語関数， https://reference.wolfram.com/language/ref/CoefficientRules.html.

テキスト

Wolfram Research (2008), CoefficientRules, Wolfram言語関数， https://reference.wolfram.com/language/ref/CoefficientRules.html.

CMS

Wolfram Language. 2008. "CoefficientRules." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/CoefficientRules.html.

APA

Wolfram Language. (2008). CoefficientRules. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/CoefficientRules.html

BibTeX

@misc{reference.wolfram_2026_coefficientrules, author="Wolfram Research", title="{CoefficientRules}", year="2008", howpublished="\url{https://reference.wolfram.com/language/ref/CoefficientRules.html}", note=[Accessed: 12-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_coefficientrules, organization={Wolfram Research}, title={CoefficientRules}, year={2008}, url={https://reference.wolfram.com/language/ref/CoefficientRules.html}, note=[Accessed: 12-September-2026]}