WOLFRAM

Wolfram 语言与系统参考资料中心

CoefficientRules[poly,{x1,x2,…}]

给出 poly 中关于 xi 的单项式的指数向量和系数的列表 {{e11,e12,…}c1,{e21,…}c2,…}.

CoefficientRules[poly,{x1,x2,…},order]

给出由 order 指定的单项式排序结果.

更多信息和选项
Details and Options Details and Options
范例  
基本范例  
范围  
选项  
Modulus  
属性和关系  
可能存在的问题  
巧妙范例  
参见
技术笔记
相关指南
历史
按以下格式引用：

CoefficientRules

CoefficientRules[poly,{x1,x2,…}]

给出 poly 中关于 xi 的单项式的指数向量和系数的列表 {{e11,e12,…}c1,{e21,…}c2,…}.

CoefficientRules[poly,{x1,x2,…},order]

给出由 order 指定的单项式排序结果.

更多信息和选项

范例

打开所有单元 关闭所有单元

基本范例  (1)

给出单项式的指数和系数：

Wolfram Language code: CoefficientRules[(x + y) ^ 3]

范围  (1)

单项序 "DegreeReverseLexicographic"：

Wolfram Language code: CoefficientRules[a x y ^ 2 + b x ^ 2 z, {x, y, z}, "DegreeReverseLexicographic"]

用权矩阵指定相同的序：

Wolfram Language code: CoefficientRules[a x y ^ 2 + b x ^ 2 z, {x, y, z}, {{1, 1, 1}, {0, 0, -1}, {0, -1, 0}}]

选项  (1)

Modulus  (1)

化简模除 2 的系数：

Wolfram Language code: CoefficientRules[(x + 1) ^ 5, x, Modulus -> 2]

属性和关系  (2)

FromCoefficientRules 重构原多项式：

Wolfram Language code: CoefficientRules[a x ^ 2 + b x y + c y ^ 2, {x, y}]
Wolfram Language code: FromCoefficientRules[%, {x, y}]

MonomialList 给出不同的表示：

Wolfram Language code: MonomialList[a x ^ 2 + b x y + c y ^ 2, {x, y}]

对于二个变量，"DegreeLexicographic" 和 "DegreeReverseLexicographic" 一致：

Wolfram Language code: poly = Sum[RandomInteger[{-10, 10}]x ^ RandomInteger[10]y ^ RandomInteger[10], {20}]
Wolfram Language code: CoefficientRules[poly, {x, y}, "DegreeLexicographic"] === CoefficientRules[poly, {x, y}, "DegreeReverseLexicographic"]

可能存在的问题  (1)

Variables[poly] 给出的列表不总是排序的：

Wolfram Language code: Variables[y + x z]
Wolfram Language code: CoefficientRules[y + x z]
Wolfram Language code: FromCoefficientRules[%, {y, x, z}]

巧妙范例  (2)

显示二维图形中的单项序：

Wolfram Language code: MonomialOrderPlot[poly_, {x1_, x2_}, ord_ : "Lexicographic", o : OptionsPattern[]] := Graphics[{Blue, Arrow /@ Partition[CoefficientRules[poly, {x1, x2}, ord][[All, 1]], 2, 1]}, Sequence@@FilterRules[{o}, Options[Graphics]]]

标准的内置序：

Wolfram Language code: orders = {"Lexicographic", "DegreeLexicographic", "DegreeReverseLexicographic", "NegativeLexicographic", "NegativeDegreeLexicographic", "NegativeDegreeReverseLexicographic"};

在二维图形中，不能区分某些序：

Wolfram Language code: Table[MonomialOrderPlot[Sum[x ^ i y ^ j, {i, 0, 5}, {j, 0, 5}], {x, y}, o, PlotLabel -> Style[o, Small]], {o, orders}]

显示三维图形中的多项式序：

Wolfram Language code: MonomialOrderPlot3D[poly_, {x1_, x2_, x3_}, ord_ : "Lexicographic", o : OptionsPattern[]] := Graphics3D[{Arrowheads[.06], Arrow[Tube[#, .02]]& /@ Partition[CoefficientRules[poly, {x1, x2, x3}, ord][[All, 1]], 2, 1]}, Sequence@@FilterRules[{o}, Options[Graphics3D]]]
Wolfram Language code: orders = {"Lexicographic", "DegreeLexicographic", "DegreeReverseLexicographic", "NegativeLexicographic", "NegativeDegreeLexicographic", "NegativeDegreeReverseLexicographic"};

在三维图形中，所有序是不相同的：

Wolfram Language code: Table[MonomialOrderPlot3D[Sum[x ^ i y ^ j z ^ k, {i, 0, 2}, {j, 0, 2}, {k, 0, 2}], {x, y, z}, o, PlotLabel -> Style[o, Small]], {o, orders}]
Wolfram Research (2008)，CoefficientRules，Wolfram 语言函数，https://reference.wolfram.com/language/ref/CoefficientRules.html.

文本

Wolfram Research (2008)，CoefficientRules，Wolfram 语言函数，https://reference.wolfram.com/language/ref/CoefficientRules.html.

CMS

Wolfram 语言. 2008. "CoefficientRules." Wolfram 语言与系统参考资料中心. Wolfram Research. https://reference.wolfram.com/language/ref/CoefficientRules.html.

APA

Wolfram 语言. (2008). CoefficientRules. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/CoefficientRules.html 年

BibTeX

@misc{reference.wolfram_2026_coefficientrules, author="Wolfram Research", title="{CoefficientRules}", year="2008", howpublished="\url{https://reference.wolfram.com/language/ref/CoefficientRules.html}", note=[Accessed: 15-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_coefficientrules, organization={Wolfram Research}, title={CoefficientRules}, year={2008}, url={https://reference.wolfram.com/language/ref/CoefficientRules.html}, note=[Accessed: 15-September-2026]}