WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

Complex

複素数に使われる頭部である．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
アプリケーション  
特性と関係  
考えられる問題  
関連項目
テクニカルノート
関連するガイド
履歴
引用書式

Complex

Complex

複素数に使われる頭部である．

詳細

  • x+Iy の形式で複素数を入力することができる．
  • _Complexは，パターンにおける複素数を表すのに使用することができる．
  • 複素数Complexの部分を抽出する場合，ReやImを使用しなければならない．

例題

すべて開く すべて閉じる

例  (1)

複素数を入力する：

Wolfram Language code: 1 + 2 I

Complexは複素数の頭部(Head)である：

Wolfram Language code: Head[%]

スコープ  (9)

純粋な虚数を入力する：

Wolfram Language code: 4 I

実部がないにもかかわらず，この数は頭部(Head)としてComplexを持つ：

Wolfram Language code: Head[%]

複素数x+Iy の完全形(FullForm)はComplex[x,y]である：

Wolfram Language code: FullForm[1 + 2 I]

FullFormを使って複素数を入力する：

Wolfram Language code: Complex[2, 1]

虚部が厳密に零の場合，結果はComplexではない：

Wolfram Language code: Complex[2, 0]
Wolfram Language code: Head[%]

複素(Complex)数の部分抽出にはReおよびImを使う必要がある：

Wolfram Language code: x = 1 + 2 I;
Wolfram Language code: {Re[x], Im[x]}

Partではうまくいかない：

Wolfram Language code: x[[1]]

複素数のどちらかの部分が機械精度の場合は，数全体が機械精度になる：

Wolfram Language code: 2. + I
Wolfram Language code: 1 + 2.I

結果が実際に機械数であることを確認する：

Wolfram Language code: MachineNumberQ[%]

実部が厳密数で虚部が任意精度である複素数を入力する：

Wolfram Language code: x = 2`20 + I

可能な場合は現実さが保持される：

Wolfram Language code: I x

しかし，これは一般的に可能な訳ではない：

Wolfram Language code: x ^ 2

任意精度の実部と虚部を持つ複素数を入力する：

Wolfram Language code: 1`20 + 2`30 I

精度は複素平面における誤差に基づく：

Wolfram Language code: Precision[%]

_Complexを使ってパターンにおける複素数を表すことができる：

Wolfram Language code: MatchQ[1 + 2 I, _Complex]

実部と虚部を入れ換える規則：

Wolfram Language code: rule = x_Complex -> Im[x] + I Re[x];
Wolfram Language code: f[1 + 2 I, 3 + 4 I, 5] /. rule

別の定義：

Wolfram Language code: f[1 + 2 I, 3 + 4 I, 5] /. Complex[r_, i_] :> Complex[i, r]

アプリケーション  (2)

実数上で定義された関数を使って複素数上で関数を定義する：

Wolfram Language code: cosine[x_Complex] := Cos[Re[x]]Cosh[Im[x]] - I Sin[Re[x]]Sinh[Im[x]]
Wolfram Language code: cosine[x_Real] := Cos[x]
Wolfram Language code: Plot3D[Abs[cosine[x + I y]], {x, -3, 3}, {y, -1, 1}]

式の中の純粋な虚数すべてに定数を掛ける：

Wolfram Language code: {(1 + (I x) / Y), (1 - (I x) / Y), 2 I x} /. Complex[0, y_] -> a y I

Ia Iのような単純な置き換えはI===Complex[0,1]のところしか乗算しない点に注意のこと：

Wolfram Language code: {(1 + (I x) / Y), (1 - (I x) / Y), 2 I x} /. I -> a I

特性と関係  (5)

複素数は数である：

Wolfram Language code: 1 + 2 I
Wolfram Language code: NumberQ[%]

複素数は部分式を持たない原子オブジェクトである：

Wolfram Language code: AtomQ[1 + 2 I]

Complexesを使って領域条件についての仮定を示す：

Wolfram Language code: Reduce[z Conjugate[z] < 1, z, Complexes]

複素数の実部と虚部は異なる精度でもよい：

Wolfram Language code: 3.64`10 + I

算術演算ではこれらが混在することが多い：

Wolfram Language code: % ^ 4

しかし，それでも，実部と虚部が異なる精度である点には注意が必要である：

Wolfram Language code: Precision /@ ReIm[%]

数全体の精度はこれら2つの精度の間になる：

Wolfram Language code: Precision[%%]

純粋な虚数を機械精度で評価すると実部が近似ゼロになる：

Wolfram Language code: N[ISqrt[5]]

任意精度の評価は厳密にゼロの実部を返す：

Wolfram Language code: N[ISqrt[5], 10]

考えられる問題  (2)

x+Iy の形で入力された数は評価に際してのみ複素(Complex)数となる：

Wolfram Language code: SetAttributes[f, HoldAll]; f[x_Complex] := Re[x] - Im[x]
Wolfram Language code: f[1 + 2 I]
Wolfram Language code: f[Evaluate[1 + 2 I]]

未評価の形はPlusとTimesで表される：

Wolfram Language code: FullForm[HoldForm[1 + 2 I]]

評価された複素数は原子オブジェクトで明示的にはIを含まない：

Wolfram Language code: FullForm[2 + I]
Wolfram Language code: MatchQ[2 + I, _ + I]
Wolfram Language code: Position[{2 + I, 1 + 2I}, I]

Complex[x_,y_]の形式のパターンを使って複素数全体をマッチすることができる：

Wolfram Language code: MatchQ[2 + I, Complex[_, 1]]
Wolfram Language code: Position[{2 + I, 1 + 2I}, Complex[_, 1]]
Wolfram Research (1988), Complex, Wolfram言語関数， https://reference.wolfram.com/language/ref/Complex.html.

テキスト

Wolfram Research (1988), Complex, Wolfram言語関数， https://reference.wolfram.com/language/ref/Complex.html.

CMS

Wolfram Language. 1988. "Complex." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/Complex.html.

APA

Wolfram Language. (1988). Complex. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/Complex.html

BibTeX

@misc{reference.wolfram_2026_complex, author="Wolfram Research", title="{Complex}", year="1988", howpublished="\url{https://reference.wolfram.com/language/ref/Complex.html}", note=[Accessed: 10-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_complex, organization={Wolfram Research}, title={Complex}, year={1988}, url={https://reference.wolfram.com/language/ref/Complex.html}, note=[Accessed: 10-September-2026]}