WOLFRAM

Wolfram 语言与系统参考资料中心

Cone[{{x1,y1,z1},{x2,y2,z2}},r]

表示一个圆锥体，其底部半径 r，中心为 (x1,y1,z1)，并且顶点为 (x2,y2,z2).

Cone[{{x1,y1,z1},{x2,y2,z2}}]

表示底部半径为 1 的圆锥体.

更多信息和选项
Details and Options Details and Options
范例  
基本范例  
范围  
图形  
规范  
样式化  
坐标  
区域  
应用  
属性和关系  
巧妙范例  
参见
相关指南
相关链接
历史
按以下格式引用：

Cone

Cone[{{x1,y1,z1},{x2,y2,z2}},r]

表示一个圆锥体，其底部半径 r，中心为 (x1,y1,z1)，并且顶点为 (x2,y2,z2).

Cone[{{x1,y1,z1},{x2,y2,z2}}]

表示底部半径为 1 的圆锥体.

更多信息和选项

  • Cone 可用作几何区域和图形基元.
  • Cone[] 等价于 Cone[{{0,0,-1},{0,0,1}}].
  • Cone 表示一个填充的圆锥区域，其中 ，向量 与 TemplateBox[{{v, _, 1}}, Norm]=TemplateBox[{{v, _, 2}}, Norm]=1 正交，且 和 .
  • Cone 可用于 Graphics3D.
  • 在图形中，点 pi 和半径 r 可以是 Scaled 和 Dynamic 表达式.
  • 图形渲染受诸如 EdgeForm、FaceForm、 Specularity、Opacity 和颜色等指令的影响.
  • Cone[{spec1,spec2,…},{r1,r2,…}] 表示具有规范 speci 和基底半径 ri 的一个锥的集合.

范例

打开所有单元 关闭所有单元

基本范例  (4)

一个单位半径和两个单位高度圆锥：

Wolfram Language code: Graphics3D[Cone[]]

从原点到 {1,1,1}，底部半径为 1/2 的一个圆锥：

Wolfram Language code: Graphics3D[Cone[{{0, 0, 0}, {1, 1, 1}}, 1 / 2]]

不同样式的圆锥：

Wolfram Language code: {Graphics3D[{Yellow, Cone[]}], Graphics3D[{EdgeForm[Thick], Cone[]}], Graphics3D[{EdgeForm[Dashed], Cone[]}], Graphics3D[{EdgeForm[Directive[Thick, Dashed, Blue]], Orange, Cone[]}]}

体积和质心：

Wolfram Language code: Volume[Cone[{{Subscript[x, 1], Subscript[y, 1], Subscript[z, 1]}, {Subscript[x, 2], Subscript[y, 2], Subscript[z, 2]}}, r]]
Wolfram Language code: RegionCentroid[Cone[{{Subscript[x, 1], Subscript[y, 1], Subscript[z, 1]}, {Subscript[x, 2], Subscript[y, 2], Subscript[z, 2]}}, r]]

范围  (22)

图形  (12)

规范  (5)

如果不指定半径，则默认为1：

Wolfram Language code: Graphics3D[Cone[{{0, 0, 0}, {0, 0, 1}}]]

不同半径的锥：

Wolfram Language code: Graphics3D[{Cone[{{0, 0, 3}, {0, 0, -3}}, 1], Cone[{{5, 0, 3}, {5, 0, -3}}, 3]}]

不同方向的锥：

Wolfram Language code: Graphics3D[{Cone[{{0, 0, 0}, {1, 0, 0}}], Cone[{{1, 1, 1}, {2, 3, 1}}]}]

以原点为中心、基底半径为1的锥的简写形式：

Wolfram Language code: Graphics3D[Cone[], Axes -> True]

多个锥：

Wolfram Language code: s = {{0, 0, 0}, {0, 0, 2}};
Wolfram Language code: Graphics3D[Cone[{s, s + 2}]]

样式化  (5)

颜色指令指定锥的表面颜色：

Wolfram Language code: Table[Graphics3D[{c, Cone[]}], {c, {Red, Green, Blue, Yellow}}]

FaceForm 和 EdgeForm 可用于指定表面和边的样式：

Wolfram Language code: Graphics3D[{FaceForm[Pink], EdgeForm[Directive[Dashed, Thick, Blue]], Cone[]}]

使用 FaceForm 可以指定前面和后面的不同属性：

Wolfram Language code: Graphics3D[{FaceForm[Yellow, Blue], Cone[]}, PlotRange -> {{-1, 1}, {-.2, 1}, {-1, 1}}]

具有不同镜面指数的锥：

Wolfram Language code: Table[Graphics3D[{Orange, Specularity[White, n], Cone[]}, Lighting -> {{"Point", White, Scaled[{2, -1, 1.2}]}}], {n, {5, 20, 100}}]

发红光的白色锥：

Wolfram Language code: Graphics3D[{Glow[Red], Black, Cone[]}]

Opacity 指定表面不透明度：

Wolfram Language code: Table[Graphics3D[{Opacity[o], Cone[]}], {o, {0.3, 0.5, 0.9}}]

坐标  (2)

使用 Scaled 坐标：

Wolfram Language code: Graphics3D[Cone[{Scaled[{.5, .5, .2}], Scaled[{.5, .5, .8}]}, 3], PlotRange -> {{0, 10}, {0, 10}, {0, 10}}, Axes -> True]

使用 Scaled 半径：

Wolfram Language code: Graphics3D[Cone[{{0, 0, -1}, {0, 0, 1}}, Scaled[0.25]], Axes -> True, PlotRange -> 1]

区域  (10)

嵌入维度是锥所在的空间维度：

Wolfram Language code: ℛ = Cone[{{0, 0, 0}, {1, 1, 1}}, 2];
Wolfram Language code: RegionEmbeddingDimension[ℛ]

几何维度是形状自身的维度：

Wolfram Language code: RegionDimension[ℛ]

成员检验：

Wolfram Language code: ℛ = Cone[{{0, 0, 0}, {1, 1, 1}}, 2];
Wolfram Language code: {RegionMember[ℛ, {(1/3), (1/3), (1/3)}], RegionMember[ℛ, {5, 5, 5}]}

获取成员条件：

Wolfram Language code: RegionMember[ℛ, {x, y, z}]

体积：

Wolfram Language code: ℛ = Cone[{{0, 0, 0}, {1, 1, 1}}, 2];
Wolfram Language code: {Volume[ℛ], RegionMeasure[ℛ]}

质心：

Wolfram Language code: c = RegionCentroid[ℛ]
Wolfram Language code: Graphics3D[{{Opacity[0.5], LightBlue, ℛ}, {PointSize[Large], Red, Point[c]}}]

距一个点的距离：

Wolfram Language code: ℛ = Cone[{{0, 0, 0}, {1, 1, 1}}, 2];
Wolfram Language code: {RegionDistance[ℛ, {1, 2, 3}], RegionDistance[ℛ, {(1/3), (1/4), (1/5)}]}

锥的等距轮廓：

Wolfram Language code: ContourPlot3D[Evaluate@RegionDistance[ℛ, {x, y, z}], {x, -3, 3}, {y, -3, 2.5}, {z, -2.5, 3}, Mesh -> None, Contours -> {0.25, 0.5, 1}, ContourStyle -> ColorData[94, "ColorList"], Lighting -> "Neutral", BaseStyle -> Opacity[0.5], BoxRatios -> Automatic]

距一个点的带符号距离：

Wolfram Language code: ℛ = Cone[{{0, 0, 0}, {1, 1, 1}}, 2];
Wolfram Language code: {SignedRegionDistance[ℛ, {1, 2, 3}], SignedRegionDistance[ℛ, {(1/3), (1/4), (1/5)}]}

区域中的最近点：

Wolfram Language code: ℛ = Cone[{{0, 0, 0}, {1, 1, 1}}, 2];
Wolfram Language code: {RegionNearest[ℛ, {1, 2, 3}], RegionNearest[ℛ, {(1/3), (1/4), (1/5)}]}

到一个封闭球的最近点：

Wolfram Language code: spherePoints[{n_, m_}, c_, r_] := Flatten[Table[c + r{Cos[k 2π / n]Sin[l π / m], Sin[k 2π / n]Sin[l π / m], Cos[l π / m]}, {k, 0., n - 1}, {l, 0., m - 1}], 1];
Wolfram Language code: pl = spherePoints[{16, 8}, RegionCentroid[ℛ], 3]; npl = Table[RegionNearest[ℛ, p], {p, pl}];
Wolfram Language code: Legended[Graphics3D[{ℛ, {Thin, Gray, Line[Transpose[{pl, npl}]]}, {Red, Point[pl]}, {PointSize[Medium], Blue, Point[npl]}}, Lighting -> "Neutral", Boxed -> False], PointLegend[{Red, Blue}, {"start", "nearest"}]]

锥是有界的：

Wolfram Language code: ℛ = Cone[{{0, 0, 0}, {1, 1, 1}}, 1];
Wolfram Language code: BoundedRegionQ[ℛ]

求范围：

Wolfram Language code: r = RegionBounds[ℛ]
Wolfram Language code: Graphics3D[{{EdgeForm[White], Opacity[0.2, Yellow], Cuboid@@Transpose[r]}, ℛ}, Boxed -> False]

在锥区域上积分：

Wolfram Language code: ℛ = Cone[{{0, 0, 0}, {1, 1, 1}}, 2];
Wolfram Language code: Integrate[x + y + z, {x, y, z}∈ℛ]

在锥区域上最优化：

Wolfram Language code: ℛ = Cone[{{0, 0, 0}, {1, 1, 1}}, 2];
Wolfram Language code: MinValue[{x y z - x y, {x, y, z}∈ℛ}, {x, y, z}]

求解锥区域上的方程：

Wolfram Language code: ℛ = Cone[{{0, 0, 0}, {1, 1, 1}}, 2];
Wolfram Language code: Reduce[x^2 + y^2 + z^2 == 1 && x - y - z == -1 && z^2 == x y && {x, y, z}∈ℛ, {x, y, z}]

应用  (5)

求体积为 的锥的最小表面积：

Wolfram Language code: ℛ = Cone[{{0, 0, 0}, {0, 0, h}}, r];
Wolfram Language code: Minimize[{Area[RegionBoundary[ℛ]], Volume[ℛ] == π / 3 && r > 0 && h > 0}, {r, h}, Reals]

与具有相同体积的其他锥比较：

Wolfram Language code: Graphics3D[#, PlotLabel -> Area[RegionBoundary[#]]]& /@ Diagonal@Table[ℛ, {r, {1 / (4Sqrt[2]), 1 / Sqrt[2], 2 / Sqrt[2]}}, {h, {8, 2, 1 / 2}}]

根据锥和平面的相交部分定义一个区域：

Wolfram Language code: Subscript[ℛ, 1] = Cone[{{0, 0, 0}, {0, 0, 2}}, 2]; Subscript[ℛ, 2] = InfinitePlane[{0, 0, 0}, {{1, 1, 1}, {0, 1, 1}}];
Wolfram Language code: i = RegionIntersection[Subscript[ℛ, 1], Subscript[ℛ, 2]]//DiscretizeRegion

可视化相交部分：

Wolfram Language code: g = Graphics3D[{{Opacity[0.3], Darker@Green, Subscript[ℛ, 1]}, {Opacity[0.5], LightRed, Subscript[ℛ, 2]}}, Boxed -> False, Lighting -> "Neutral"];
Wolfram Language code: Show[g, i]

一个简单的三维箭头图：

Wolfram Language code: data = RandomReal[{1, 10}, {12, 4}];
Wolfram Language code: Graphics3D[MapIndexed[{Hue[(Last[#2] - 1) / 4], Cylinder[{Append[{1, 2}#2, 0], Append[{1, 2}#2, #1]}, .4], Cone[{Append[{1, 2}#2, #1], Append[{1, 2}#2, #1 + 2]}, .6]}&, data, {2}], Axes -> {False, False, True}, Lighting -> "Neutral"]

定义基于 Cone 的一个 ChartElementFunction：

Wolfram Language code: ConeBar[{{xmin_, xmax_}, {ymin_, ymax_}, {zmin_, zmax_}}, ___] := Cone[{{(xmin + xmax) / 2, (ymin + ymax) / 2, zmin}, {(xmin + xmax) / 2, (ymin + ymax) / 2, zmax}}, Min[(xmax - xmin) / 2, (ymax - ymin) / 2]]
Wolfram Language code: data = RandomReal[1, {2, 5}];
Wolfram Language code: BarChart3D[data, ChartElementFunction -> ConeBar]

BarChart3D 用 Cone 产生三维条形图：

Wolfram Language code: BarChart3D[data, ChartElementFunction -> "Cone"]

Histogram3D 可以类似地使用 Cone：

Wolfram Language code: Histogram3D[RandomReal[NormalDistribution[0, 1], {500, 2}], 10, ChartElementFunction -> "Cone"]

用 Cone 显示 BubbleChart3D 中的气泡：

Wolfram Language code: BubbleChart3D[RandomReal[1, {3, 10, 4}], ChartElements -> Graphics3D[Cone[]]]

属性和关系  (6)

用 Scale 获得椭圆圆锥：

Wolfram Language code: Graphics3D[Scale[Cone[], {2, 4, 3}, {0, 0, 0}], Axes -> True]

Cone 可以用作 Arrow 中的一个三维箭头：

Wolfram Language code: Graphics3D[{Arrowheads[.4], Blue, Arrow[Tube[{{0, 0, 0}, {2, 1, 1}}, 0.1, VertexColors -> {Red, Blue}]]}]

Cone 是 Tube 的一个特例：

Wolfram Language code: {Graphics3D[Cone[{{0, 0, 0}, {1, 1, 1}}, 1]], Graphics3D[{CapForm["Butt"], Tube[{{0, 0, 0}, {1, 1, 1}}, {1, 0}]}]}

通过在 Tube 中指定不同的半径，获得一个截断的圆锥：

Wolfram Language code: Graphics3D[{CapForm["Butt"], Tube[{{0, 0, 0}, {1, 1, 1}}, {1, 1 / 2}]}]

用 ParametricPlot3D 产生一个参数锥形壳：

Wolfram Language code: ParametricPlot3D[{Cos[θ] z, Sin[θ]z, z}, {θ, 0, 2 π}, {z, -1, 0}, Mesh -> None]

由 ContourPlot3D 产生锥形壳的隐式指定：

Wolfram Language code: ContourPlot3D[x ^ 2 + y ^ 2 == z ^ 2, {x, -1, 1}, {y, -1, 1}, {z, -1, 0}, Mesh -> None]

ImplicitRegion 可以表示任何 Cone 区域：

Wolfram Language code: Subscript[ℛ, 1] = ImplicitRegion[0 ≤ Subscript[t, 1] + Subscript[t, 2] + Subscript[t, 3] ≤ 3 && Subsuperscript[t, 1, 2] + Subsuperscript[t, 2, 2] + Subscript[t, 2] (12 - 7 Subscript[t, 3]) + Subscript[t, 1] (12 - 7 Subscript[t, 2] - 7 Subscript[t, 3]) + Subscript[t, 3] (12 + Subscript[t, 3]) ≤ 18, {Subscript[t, 1], Subscript[t, 2], Subscript[t, 3]}]; Subscript[ℛ, 2] = Cone[{{0, 0, 0}, {1, 1, 1}}, 2];
Wolfram Language code: RegionEqual[Subscript[ℛ, 1], Subscript[ℛ, 2]]

巧妙范例  (3)

随机的单位圆锥：

Wolfram Language code: Graphics3D[Table[{EdgeForm[Opacity[.3]], Hue[RandomReal[]], Cone[RandomReal[10, {2, 3}]]}, {20}]]

绕轴扫过一个锥：

Wolfram Language code: Graphics3D[{Opacity[0.3], EdgeForm[], Table[{ColorData["Rainbow"][Rescale[c, {0, 2Pi}]], GeometricTransformation[Cone[], RotationTransform[c, {-1, 2, -6}, {1, 0, 0}]]}, {c, 0, 2Pi, 2Pi / 18}]}]

嵌套透明圆锥：

Wolfram Language code: Graphics3D[{Opacity[.3], EdgeForm[Opacity[.3]], Table[Cone[{{0, 0, 0}, {0, 0, 2r}}, r], {r, 1, 5}]}, Boxed -> False]
Wolfram Research (2008)，Cone，Wolfram 语言函数，https://reference.wolfram.com/language/ref/Cone.html （更新于 2014 年）.

文本

Wolfram Research (2008)，Cone，Wolfram 语言函数，https://reference.wolfram.com/language/ref/Cone.html （更新于 2014 年）.

CMS

Wolfram 语言. 2008. "Cone." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2014. https://reference.wolfram.com/language/ref/Cone.html.

APA

Wolfram 语言. (2008). Cone. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/Cone.html 年

BibTeX

@misc{reference.wolfram_2026_cone, author="Wolfram Research", title="{Cone}", year="2014", howpublished="\url{https://reference.wolfram.com/language/ref/Cone.html}", note=[Accessed: 14-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_cone, organization={Wolfram Research}, title={Cone}, year={2014}, url={https://reference.wolfram.com/language/ref/Cone.html}, note=[Accessed: 14-September-2026]}