ConnectSystemModelController

ConnectSystemModelController[model,controller]

コントローラのデータ controller に従ってシステムモデル model とコントローラを接続する．

詳細

ConnectSystemModelControllerは，通常，コントローラをSystemModelプラントモデルに接続し，閉ループ系を与えるために使われる．結果のシステムについて，現実世界で使用するためのシミュレーションや分析が行える．
model は，SystemModelオブジェクト，完全なモデル名の文字列，あるいはSystemModelで使用可能な短縮モデル名でよい．
ConnectSystemModelController["NewModel",…]は作成されたモデルに名前"NewModel"を与える．
controller は制御設計関数によって作成されたSystemsModelControllerDataオブジェクトである．

model からの状態フィードバックを持つ制御設計関数には以下が含まれる．

	StateFeedbackGains	極配置状態フィードバック
	LQRegulatorGains	線形二次最適制御
	DiscreteLQRegulatorGains	離散時間線形二次最適制御
	ModelPredictiveController	制約付きモデルの予測コントローラ

model からの出力フィードバックを持つ制御設計関数には以下が含まれる．

	EstimatorRegulator	状態フィードバックと状態推定器を組み立てる
	LQGRegulator	線形二次制御と推定器
	PIDTune	自動的に調整されたPIDコントローラ

ConnectSystemModelControllerはSystemModelを返す．

例題

すべて開くすべて閉じる

例 (1)

DCモーターのモデルから始める：

Wolfram Language code: model = [image];

平衡点周囲でこれを線形化し，コントローラを作成する：

Wolfram Language code: ctrl = PIDTune[SystemModelLinearize[model], Automatic, "Data"]

制御モデルのための閉ループ系を生成する：

Wolfram Language code: csys = ConnectSystemModelController[model, ctrl]

基準入力を与えて出力をプロットする：

Wolfram Language code:

SystemModelPlot[csys, {"out"}, 10, <|"Inputs" -> {"ref" -> Function[2], "ctrlDist" -> Cos, "sensNoise" -> Sin}|>, PlotRange -> All]

スコープ (16)

StateFeedbackGains (3)

潜水し始めた潜水艦のモデルから始める：

Wolfram Language code: model = [image];

平衡点の周囲で線形化する：

Wolfram Language code: lin = SystemModelLinearize[model]

コントローラを設計する：

Wolfram Language code: ctrl = StateFeedbackGains[<|"InputModel" -> lin, "FeedbackInputs" -> {1}|>, {-2 + I, -2 - I}, "Data"]

制御モデルの閉ループ系を生成する：

Wolfram Language code: csys = ConnectSystemModelController[model, ctrl]

鉛直力で潜水艦に摂動を与える：

Wolfram Language code:

simModel = SystemModelSimulate[model, 10, <|"Inputs" -> {"f" -> Function[t, 10^8(UnitStep[t] - UnitStep[t - 1])], "deltarho" -> Function[0]}|>]

同じ撹乱を使って閉ループ系のシミュレーションを行う：

Wolfram Language code:

simCsys = SystemModelSimulate[csys, 10, <|"Inputs" -> {"f" -> Function[t, 10^8(UnitStep[t] - UnitStep[t - 1])], "deltarho" -> Function[0]}|>]

もとのモデルにおける潜水艦の深度をプロットする：

Wolfram Language code: SystemModelPlot[simModel, {"y"}]

閉ループ系では，潜水艦は深度を保つために密度を変える：

Wolfram Language code: SystemModelPlot[simCsys, {"y"}]

円軌道の宇宙船についてのモデルから始める：

Wolfram Language code: model = [image];

平衡点の周囲で線形化する：

Wolfram Language code: lin = SystemModelLinearize[model]

コントローラを設計する：

Wolfram Language code: ctrl = StateFeedbackGains[lin, {-0.5, -1.5, -1, -2.5}, "Data"]

制御モデルについて閉ループ系を生成する：

Wolfram Language code: csys = ConnectSystemModelController[model, ctrl]

初期速度を使って元のモデルのシミュレーションを行う：

Wolfram Language code: simModel = SystemModelSimulate[model, 20, <|"InitialValues" -> {"keplerDynamics.vx" -> 0.1}|>]

同じ初期速度で閉ループ系のシミュレーションを行う：

Wolfram Language code: simCsys = SystemModelSimulate[csys, 20, <|"InitialValues" -> {"eSys.sys.keplerDynamics.vx" -> 0.1}|>]

もとのモデルの円軌道からの偏差をプロットする：

Wolfram Language code:

Row[Table[SystemModelPlot[simModel, {var}, TargetUnits -> {"Seconds", Automatic}, PlotRange -> All, PlotLabel -> var, ImageSize -> 225], {var, {"dphi", "dr"}}]]

閉ループ系は宇宙船を円軌道に戻す：

Wolfram Language code:

Row[Table[SystemModelPlot[simCsys, {var}, TargetUnits -> {"Seconds", Automatic}, PlotRange -> All, PlotLabel -> var, ImageSize -> 225], {var, {"dphi", "dr"}}]]

倒立振子のモデルから始める：

Wolfram Language code: model = \!\(\*GraphicsBox[«8»]\);

平衡点の周囲で線形化する：

Wolfram Language code: lin = SystemModelLinearize[model]

コントローラを設計する：

Wolfram Language code: ctrl = StateFeedbackGains[<|"InputModel" -> lin, "FeedbackInputs" -> {2}|>, {-9 + 9I, -9 - 9I, -10, -10.5}, "Data"]

制御モデルについて閉ループ系を生成する：

Wolfram Language code: csys = ConnectSystemModelController[model, ctrl]

振子に接線力を適用してシミュレーションを行う：

Wolfram Language code:

simModel = SystemModelSimulate[model, 5, <|"Inputs" -> {"d" -> Function[t, 0.1(UnitStep[t] - UnitStep[t - 1])], "f" -> Function[0]}|>]

同じ撹乱を使って閉ループ系のシミュレーションを行う：

Wolfram Language code:

simCsys = SystemModelSimulate[csys, 5, <|"Inputs" -> {"d" -> Function[t, 0.1(UnitStep[t] - UnitStep[t - 1])], "f" -> Function[0]}|>]

もとのモデルにおける振子の角度をプロットする：

Wolfram Language code: SystemModelPlot[simModel, {"phi"}, PlotRange -> All]

閉ループ系は水平力を適用し，振子を垂直位置に戻す：

Wolfram Language code: SystemModelPlot[simCsys, {"phi"}, PlotRange -> All]

LQRegulatorGains (2)

連続攪拌槽型反応器のモデルから始める：

Wolfram Language code: model = [image];

平衡点の周囲で線形化する：

Wolfram Language code: lin = SystemModelLinearize[model]

コントローラを設計する：

Wolfram Language code:

ctrl = LQRegulatorGains[lin, {(⁠|   |   |   |
| - | - | - |
| 1 | 0 | 0 |
| 0 | 1 | 0 |
| 0 | 0 | 1 |⁠), {{1}}}, "Data"]

閉ループ系を生成する：

Wolfram Language code: csys = ConnectSystemModelController[model, ctrl]

平衡値からの反応物の濃度の不足を使ってもとのモデルのシミュレーションを行う：

Wolfram Language code: simModel = SystemModelSimulate[model, Quantity[1, "Hours"], <|"InitialValues" -> {"x1" -> -1000}|>]

同じ初期条件で閉ループ系のシミュレーションを行う：

Wolfram Language code: simCsys = SystemModelSimulate[csys, Quantity[1, "Hours"], <|"InitialValues" -> {"eSys.sys.x1" -> -1000}|>]

もとのモデルで反応物濃度の変化をプロットする：

Wolfram Language code: SystemModelPlot[simModel, {"deltaCA"}, PlotRange -> All, TargetUnits -> {"Hours", None}]

閉ループ系は流量を制御し，濃度を平衡値に戻す：

Wolfram Language code: SystemModelPlot[simCsys, {"deltaCA"}, PlotRange -> All, TargetUnits -> {"Hours", None}]

重心の周りを回転できる梁の上に置かれたボールのモデルから始める：

Wolfram Language code: model = SystemModel[[image], <|"ParameterValues" -> {"world.enableAnimation" -> False}|>];

平衡点の周囲で線形化する：

Wolfram Language code: lin = SystemModelLinearize[model]

コントローラを設計する：

Wolfram Language code:

ctrl = LQRegulatorGains[lin, {(⁠|   |   |   |   |
| - | - | - | - |
| 1 | 0 | 0 | 0 |
| 0 | 1 | 0 | 0 |
| 0 | 0 | 1 | 0 |
| 0 | 0 | 0 | 1 |⁠), (⁠1⁠)}, "Data"]

閉ループ系を生成する：

Wolfram Language code: csys = ConnectSystemModelController[model, ctrl]

もとのモデルで梁の端にボールを置いてシミュレーションを行う：

Wolfram Language code: simModel = SystemModelSimulate[model, 10, <|"InitialValues" -> {"ballAndBeamDynamics.rs" -> 0.4}|>]

同じ初期条件で閉ループ系のシミュレーションを行う：

Wolfram Language code: simCsys = SystemModelSimulate[csys, 10, <|"InitialValues" -> {"eSys.sys.ballAndBeamDynamics.rs" -> 0.4}|>]

もとのモデルで梁の中央から計測したボールの位置をプロットする：

Wolfram Language code: SystemModelPlot[simModel, {"ballAndBeamDynamics.rs"}]

閉ループ系はトルクを適用し，ボールを梁の中央位置に戻す：

Wolfram Language code: SystemModelPlot[simCsys, {"eSys.sys.ballAndBeamDynamics.rs"}, PlotRange -> All]

DiscreteLQRegulatorGains (2)

連続撹拌槽型反応器のモデルから始める：

Wolfram Language code: model = [image];

平衡点の周囲で線形化する：

Wolfram Language code: lin = SystemModelLinearize[model]

コントローラを設計する：

Wolfram Language code:

ctrl = DiscreteLQRegulatorGains[lin, {(⁠|   |   |   |
| - | - | - |
| 1 | 0 | 0 |
| 0 | 1 | 0 |
| 0 | 0 | 1 |⁠), {{1}}}, 60, "Data"]

閉ループ系を生成する：

Wolfram Language code: csys = ConnectSystemModelController[model, ctrl]

平衡値からの反応物の濃度が不足しているもとのモデルのシミュレーションを行う：

Wolfram Language code: simModel = SystemModelSimulate[model, Quantity[4, "Hours"], <|"InitialValues" -> {"x1" -> -1000}|>]

同じ初期条件で閉ループ系のシミュレーションを行う：

Wolfram Language code: simCsys = SystemModelSimulate[csys, Quantity[4, "Hours"], <|"InitialValues" -> {"eSys.sys.x1" -> -1000}|>]

もとのモデルにおける反応物濃度の変化をプロットする：

Wolfram Language code: SystemModelPlot[simModel, {"deltaCA"}, PlotRange -> All, TargetUnits -> {"Hours", None}]

閉ループ系は流量を制御し，濃度を平衡値に戻す：

Wolfram Language code: SystemModelPlot[simCsys, {"deltaCA"}, PlotRange -> All, TargetUnits -> {"Hours", None}]

重心の周りを回転できる梁の上に置かれたボールのモデルから始める：

Wolfram Language code: model = SystemModel[[image], <|"ParameterValues" -> {"world.enableAnimation" -> False}|>];

平衡点の周囲で線形化する：

Wolfram Language code: lin = SystemModelLinearize[model]

コントローラを設計する：

Wolfram Language code:

ctrl = DiscreteLQRegulatorGains[lin, {(⁠|   |   |   |   |
| - | - | - | - |
| 1 | 0 | 0 | 0 |
| 0 | 1 | 0 | 0 |
| 0 | 0 | 1 | 0 |
| 0 | 0 | 0 | 1 |⁠), (⁠1⁠)}, 0.1, "Data"]

閉ループ系を生成する：

Wolfram Language code: csys = ConnectSystemModelController[model, ctrl]

もとのモデルで梁の端にボールを置いてシミュレーションを行う：

Wolfram Language code: simModel = SystemModelSimulate[model, 10, <|"InitialValues" -> {"ballAndBeamDynamics.rs" -> 0.4}|>]

同じ初期条件で閉ループ系のシミュレーションを行う：

Wolfram Language code: simCsys = SystemModelSimulate[csys, 10, <|"InitialValues" -> {"eSys.sys.ballAndBeamDynamics.rs" -> 0.4}|>]

もとのモデルで梁の中央から計測したボールの位置をプロットする：

Wolfram Language code: SystemModelPlot[simModel, {"ballAndBeamDynamics.rs"}]

閉ループ系はトルクを適用し，ボールを梁の中央位置に戻す：

Wolfram Language code: SystemModelPlot[simCsys, {"eSys.sys.ballAndBeamDynamics.rs"}, PlotRange -> All]

EstimatorRegulator (2)

円軌道の宇宙船についてのモデルから始める：

Wolfram Language code: model = [image];

平衡点の周囲で線形化する：

Wolfram Language code: lin = SystemModelLinearize[model]

コントローラと観測器を設計し，それらをEstimatorRegulatorに入れる：

Wolfram Language code: k = StateFeedbackGains[lin, {-0.5, -1.5, -1, -2.5}];

Wolfram Language code: l = EstimatorGains[lin, 3 {-0.5, -1.5, -1, -2.5}];

Wolfram Language code: ctrl = EstimatorRegulator[lin, {l, k}, "Data"]

制御モデルについて閉ループ系を生成する：

Wolfram Language code: csys = ConnectSystemModelController[model, ctrl]

初期速度で閉ループ系のシミュレーションを行う：

Wolfram Language code: simCSys = SystemModelSimulate[csys, 12, <|"InitialValues" -> {"sys.keplerDynamics.vx" -> 0.1}|>]

閉ループ系は宇宙船を円軌道に戻す：

Wolfram Language code: SystemModelPlot[simCSys, {"dr"}, PlotRange -> All]

倒立振子のモデルから始める：

Wolfram Language code: model = \!\(\*GraphicsBox[«8»]\);

平衡点の周囲で線形化する：

Wolfram Language code: lin = SystemModelLinearize[model]

コントローラと観測器を設計し，それらをEstimatorRegulatorに入れる：

Wolfram Language code: sysSpec = <|"InputModel" -> lin, "FeedbackInputs" -> {2}|>;

Wolfram Language code: k = StateFeedbackGains[sysSpec, {-1 + 1.5I, -1 - 1.5I, -5, -5.5}];

Wolfram Language code: l = EstimatorGains[lin, {-9 + 9I, -9 - 9I, -10, -10.5}];

Wolfram Language code: ctrl = EstimatorRegulator[sysSpec, {l, k}, "Data"]

制御モデルについて閉ループ系を生成する：

Wolfram Language code: csys = ConnectSystemModelController[model, ctrl]

平衡点から離れる初期角度で閉ループ系のシミュレーションを行う：

Wolfram Language code: simCsys = SystemModelSimulate[csys, 10, <|"InitialValues" -> {"sys.pendulumDamper.phi_rel" -> 0.1}|>]

閉ループ系は力を適用して振子を垂直位置に戻す：

Wolfram Language code: SystemModelPlot[simCsys, {"sys.pendulumDamper.phi_rel"}, PlotRange -> All]

LQGRegulator (2)

連続撹拌槽型反応器のモデルから始める：

Wolfram Language code: model = [image];

平衡点の周囲で線形化する：

Wolfram Language code: lin = SystemModelLinearize[model]

コントローラを設計する：

Wolfram Language code:

ctrl = LQGRegulator[lin, {{{}}, (⁠|   |   |   |
| - | - | - |
| 1 | 0 | 0 |
| 0 | 1 | 0 |
| 0 | 0 | 1 |⁠)}, {(⁠|   |   |   |
| - | - | - |
| 1 | 0 | 0 |
| 0 | 1 | 0 |
| 0 | 0 | 1 |⁠), (⁠1⁠)}, "Data"]

制御モデルについて閉ループ系を生成する：

Wolfram Language code: csys = ConnectSystemModelController[model, ctrl]

平衡値からの反応物の濃度が不足しているもとのモデルのシミュレーションを行う：

Wolfram Language code: simCsys = SystemModelSimulate[csys, Quantity[8, "Hours"], <|"InitialValues" -> {"sys.x1" -> -1000}|>]

閉ループ系は流量を制御し，濃度を平衡値に戻す：

Wolfram Language code: SystemModelPlot[simCsys, {"deltaCA"}, PlotRange -> All, TargetUnits -> {"Hours", None}]

重心の周りを回転できる梁の上に置かれたボールのモデルから始め，回転減衰を加える：

Wolfram Language code: model = SystemModel[[image], <|"ParameterValues" -> {"b" -> 1, "world.enableAnimation" -> False}|>];

平衡点の周囲で線形化する：

Wolfram Language code: lin = SystemModelLinearize[model]

コントローラを設計する：

Wolfram Language code:

ctrl = LQGRegulator[lin, {{{}}, (⁠|       |       |
| ----- | ----- |
| 10^-6 | 0     |
| 0     | 10^-6 |⁠)}, {(⁠|      |      |      |      |
| ---- | ---- | ---- | ---- |
| 10^4 | 0    | 0    | 0    |
| 0    | 10^4 | 0    | 0    |
| 0    | 0    | 10^4 | 0    |
| 0    | 0    | 0    | 10^4 |⁠), (⁠1⁠)}, "Data"]

制御モデルについて閉ループ系を生成する：

Wolfram Language code: csys = ConnectSystemModelController[model, ctrl]

梁の中央からボールを離す閉ループ系のシミュレーションを行う：

Wolfram Language code: simCsys = SystemModelSimulate[csys, 20, <|"InitialValues" -> {"sys.ballAndBeamDynamics.rs" -> 0.4}|>]

閉ループ系はトルクを適用し，ボールを梁の中央に戻す：

Wolfram Language code: SystemModelPlot[simCsys, {"sys.ballAndBeamDynamics.rs"}, PlotRange -> All]

PIDTune (1)

RLC回路のモデルから始める：

Wolfram Language code: model = [image];

平衡点の周囲で線形化する：

Wolfram Language code: lin = SystemModelLinearize[model]

コントローラを設計する：

Wolfram Language code: ctrl = PIDTune[lin, Automatic, "Data"]

制御モデルについて閉ループ系を生成する：

Wolfram Language code: csys = ConnectSystemModelController[model, ctrl]

基準入力を与えて出力をプロットする：

Wolfram Language code:

SystemModelPlot[csys, {"out"}, 0.1, <|"Inputs" -> {"ref" -> Function[2], "ctrlDist" -> Cos, "sensNoise" -> Sin}|>, PlotRange -> All]

ModelPredictiveController (2)

カメラスタビライザのためのモデルから始める：

Wolfram Language code: model = \!\(\*GraphicsBox[«8»]\);

平衡点の周囲でこれを線形化する：

Wolfram Language code: SystemModelLinearize[model]

コントローラを作成する：

Wolfram Language code:

sspec = <|"InputModel" -> model, "SamplingPeriod" -> 0.05, "SamplingMethod" -> "ForwardRectangularRule", "FeedbackInputs" -> {"fa"}|>;

Wolfram Language code:

cost = <|"Horizon" -> 3, "StateWeight" -> (⁠|   |      |   |   |      |   |
| - | ---- | - | - | ---- | - |
| 1 | 0    | 0 | 0 | 0    | 0 |
| 0 | 10^6 | 0 | 0 | 0    | 0 |
| 0 | 0    | 1 | 0 | 0    | 0 |
| 0 | 0    | 0 | 1 | 0    | 0 |
| 0 | 0    | 0 | 0 | 10^6 | 0 |
| 0 | 0    | 0 | 0 | 0    | 1 |⁠), "InputWeight" -> (⁠1⁠)|>;

Wolfram Language code: cons = {-0.1 <= "xce" <= 0.1};

Wolfram Language code: ctrl = ModelPredictiveController[sspec, cost, cons]

制御されたモデルの閉ループ系を生成する：

Wolfram Language code: csys = ConnectSystemModelController["CLSMPC", model, ctrl]

鉛直力で系に摂動を与える：

Wolfram Language code: bumpInputs = <|"Inputs" -> {"fa" -> Function[t, 0], "fw" -> Function[t, 2000(UnitStep[t] - UnitStep[t - 0.25])]}|>;

Wolfram Language code: simModel = SystemModelSimulate[model, 10, bumpInputs]

同じ外乱を使って閉ループ系のシミュレーションを行う：

Wolfram Language code: simCsys = SystemModelSimulate[csys, 10, bumpInputs]

下のモデルのカメラの位置をプロットする：

Wolfram Language code: SystemModelPlot[simModel, {"xce"}, PlotRange -> {-0.025, 0.025}]

閉ループ系では，カメラの位置はほとんど変わらない：

Wolfram Language code: SystemModelPlot[simCsys, {"eSys.sys.xce"}, PlotRange -> {-0.025, 0.025}]

連続攪拌槽型反応器のモデルから始める：

Wolfram Language code: model = [image];

平衡点の周りで線形化する：

Wolfram Language code: SystemModelLinearize[model]

コントローラを作成する：

Wolfram Language code: sspec = <|"InputModel" -> model, "SamplingPeriod" -> 60, "SamplingMethod" -> "ForwardRectangularRule"|>;

Wolfram Language code:

cost = <|"Horizon" -> ∞, "StateWeight" -> (⁠|   |   |   |
| - | - | - |
| 1 | 0 | 0 |
| 0 | 1 | 0 |
| 0 | 0 | 1 |⁠), "InputWeight" -> (⁠1⁠)|>;

Wolfram Language code: cons = {-50 ≤ "deltaCA" ≤ 50};

Wolfram Language code: ctrl = ModelPredictiveController[sspec, cost, cons]

制御モデルの閉ループ系を生成する：

Wolfram Language code: csys = ConnectSystemModelController["CLSMPC", model, ctrl]

平衡値からの反応物の濃度が不足しているもとのモデルのシミュレーションを行う：

Wolfram Language code: simModel = SystemModelSimulate[model, Quantity[4, "Hours"], <|"InitialValues" -> {"x1" -> -20}|>]

同じ初期条件で閉ループ系のシミュレーションを行う：

Wolfram Language code: simCsys = SystemModelSimulate[csys, Quantity[4, "Hours"], <|"InitialValues" -> {"eSys.sys.x1" -> -20}|>]

もとのモデルにおける反応物濃度の変化をプロットする：

Wolfram Language code: SystemModelPlot[simModel, {"x1"}, PlotRange -> All, TargetUnits -> {"Hours", Automatic}]

閉ループ系は流量を制御し，濃度を平衡値に戻す：

Wolfram Language code: SystemModelPlot[simCsys, {"eSys.sys.x1"}, PlotRange -> All, TargetUnits -> {"Hours", Automatic}]

Tracking (2)

潜水艦のモデルから始める：

Wolfram Language code: model = [image];

これを平衡点の周りで線形化する：

Wolfram Language code: lin = SystemModelLinearize[model]

潜水艦の深度を追跡するコントローラを設計する：

Wolfram Language code: sspec = <|"InputModel" -> lin, "FeedbackInputs" -> {1}, "TrackedOutputs" -> {1}|>;

Wolfram Language code: ctrl = StateFeedbackGains[sspec, {-2 + I, -2 - I, -2}, "Data"]

制御されたモデルのための閉ループ系を生成する：

Wolfram Language code: csys = ConnectSystemModelController[model, ctrl]

深度とノイズの参照信号を与える閉ループ系のシミュレーションを行う：

Wolfram Language code:

sim = SystemModelSimulate[csys, 100, <|"Inputs" -> {"refY" -> Function[t, -10Tanh[t / 10]], "f" -> RandomFunction[WienerProcess[0, 10^6], {0, 100, 0.1}]}|>]

参照と出力をプロットする：

Wolfram Language code: SystemModelPlot[sim, {"refY", "y"}, PlotRange -> All]

参照を再生産するために必要な密度の変化をプロットする：

Wolfram Language code: SystemModelPlot[sim, {"eSys.sys.deltarho"}, PlotRange -> All]

重心の周りを回転できるビームの上に置かれたボールのモデルから始める：

Wolfram Language code: model = SystemModel[[image], <|"ParameterValues" -> {"world.enableAnimation" -> False}|>];

これを平衡点の周りで線形化する：

Wolfram Language code: lin = SystemModelLinearize[model]

ボールの位置を追跡するコントローラを設計する：

Wolfram Language code: sspec = <|"InputModel" -> lin, "TrackedOutputs" -> {1}|>;

Wolfram Language code:

ctrl = LQGRegulator[sspec, {{{}}, (⁠|       |       |
| ----- | ----- |
| 10^-5 | 0     |
| 0     | 10^-5 |⁠)}, {10^4(⁠|   |   |   |   |   |
| - | - | - | - | - |
| 1 | 0 | 0 | 0 | 0 |
| 0 | 1 | 0 | 0 | 0 |
| 0 | 0 | 1 | 0 | 0 |
| 0 | 0 | 0 | 1 | 0 |
| 0 | 0 | 0 | 0 | 1 |⁠), (⁠1⁠)}, "Data"]

制御されたモデルのための閉ループ系を生成する：

Wolfram Language code: csys = ConnectSystemModelController[model, ctrl]

位置とノイズの参照を与える閉ループ系のシミュレーションを行う：

Wolfram Language code:

sim = Quiet[SystemModelSimulate[csys, 100, <|"Inputs" -> {"refRs" -> Function[t, 1 / 2 E ^ (-(1 / 8) (-10 + t) ^ 2)], "noiseRs" -> RandomFunction[WienerProcess[0, 0.0001], {0, 100, 0.01}], "noiseThetab" -> RandomFunction[WienerProcess[0, 0.00001], {0, 100, 0.01}]}|>], {General::munfl}]

参照と出力をプロットする：

Wolfram Language code: SystemModelPlot[sim, {"rs", "refRs"}, PlotRange -> All]

参照の再生産に必要な入力のトルクをプロットする：

Wolfram Language code: SystemModelPlot[sim, {"sys.T"}, PlotRange -> All]

Top

その他のラーニングリソース

テクニカルサポート

データサイエンス，金融，ビジネス

工学

科学とテクノロジー

教育のためのテクノロジー

教育イニシアチブ

使い始める

Grow Your Skills

Wolframと繋がる

大人用の教育プログラム

若者のための教育プログラム

読む

ConnectSystemModelController

詳細

例題

例 (1)

スコープ (16)

StateFeedbackGains (3)

LQRegulatorGains (2)

DiscreteLQRegulatorGains (2)

EstimatorRegulator (2)

LQGRegulator (2)

PIDTune (1)

ModelPredictiveController (2)

Tracking (2)

テキスト

CMS

APA

BibTeX

BibLaTeX

ConnectSystemModelController

詳細

例題

例 (1)

スコープ (16)

StateFeedbackGains (3)

LQRegulatorGains (2)

DiscreteLQRegulatorGains (2)

EstimatorRegulator (2)

LQGRegulator (2)

PIDTune (1)

ModelPredictiveController (2)

Tracking (2)

関連項目

関連するガイド

関連リンク

履歴

テキスト

CMS

APA

BibTeX

BibLaTeX