Wolfram 语言与系统参考资料中心

ConnectSystemModelController

ConnectSystemModelController[model,controller]

根据控制器数据 controller 将系统模型 model 与控制器相连.

范例

打开所有单元关闭所有单元

基本范例 (1)

从直流电机的模型开始：

Wolfram Language code: model = [image];

在平衡点附近进行线性化：

Wolfram Language code: ctrl = PIDTune[SystemModelLinearize[model], Automatic, "Data"]

生成受控模型的闭环系统：

Wolfram Language code: csys = ConnectSystemModelController[model, ctrl]

提供参考输入并绘制输出：

Wolfram Language code:

SystemModelPlot[csys, {"out"}, 10, <|"Inputs" -> {"ref" -> Function[2], "ctrlDist" -> Cos, "sensNoise" -> Sin}|>, PlotRange -> All]

范围 (16)

StateFeedbackGains (3)

从下沉潜艇的模型开始：

Wolfram Language code: model = [image];

在平衡点附近进行线性化：

Wolfram Language code: lin = SystemModelLinearize[model]

设计一个控制器：

Wolfram Language code: ctrl = StateFeedbackGains[<|"InputModel" -> lin, "FeedbackInputs" -> {1}|>, {-2 + I, -2 - I}, "Data"]

生成受控模型的闭环系统：

Wolfram Language code: csys = ConnectSystemModelController[model, ctrl]

用垂直力扰动潜艇：

Wolfram Language code:

simModel = SystemModelSimulate[model, 10, <|"Inputs" -> {"f" -> Function[t, 10^8(UnitStep[t] - UnitStep[t - 1])], "deltarho" -> Function[0]}|>]

模拟有相同扰动情况下的闭环系统：

Wolfram Language code:

simCsys = SystemModelSimulate[csys, 10, <|"Inputs" -> {"f" -> Function[t, 10^8(UnitStep[t] - UnitStep[t - 1])], "deltarho" -> Function[0]}|>]

绘制原始模型中潜艇的深度：

Wolfram Language code: SystemModelPlot[simModel, {"y"}]

在闭环系统中，潜艇改变其密度以保持其深度：

Wolfram Language code: SystemModelPlot[simCsys, {"y"}]

从圆形轨道上的航天器模型开始：

Wolfram Language code: model = [image];

在平衡点附近进行线性化：

Wolfram Language code: lin = SystemModelLinearize[model]

设计一个控制器：

Wolfram Language code: ctrl = StateFeedbackGains[lin, {-0.5, -1.5, -1, -2.5}, "Data"]

生成受控模型的闭环系统：

Wolfram Language code: csys = ConnectSystemModelController[model, ctrl]

模拟有一定初始速度的原始模型：

Wolfram Language code: simModel = SystemModelSimulate[model, 20, <|"InitialValues" -> {"keplerDynamics.vx" -> 0.1}|>]

模拟同样初始速度下的闭环系统：

Wolfram Language code: simCsys = SystemModelSimulate[csys, 20, <|"InitialValues" -> {"eSys.sys.keplerDynamics.vx" -> 0.1}|>]

绘制与原始模型中圆形轨迹的偏差：

Wolfram Language code:

Row[Table[SystemModelPlot[simModel, {var}, TargetUnits -> {"Seconds", Automatic}, PlotRange -> All, PlotLabel -> var, ImageSize -> 225], {var, {"dphi", "dr"}}]]

闭环系统将航天器带回其圆形轨道：

Wolfram Language code:

Row[Table[SystemModelPlot[simCsys, {var}, TargetUnits -> {"Seconds", Automatic}, PlotRange -> All, PlotLabel -> var, ImageSize -> 225], {var, {"dphi", "dr"}}]]

从倒立摆的模型开始：

Wolfram Language code: model = \!\(\*GraphicsBox[«8»]\);

在平衡点附近进行线性化：

Wolfram Language code: lin = SystemModelLinearize[model]

设计一个控制器：

Wolfram Language code: ctrl = StateFeedbackGains[<|"InputModel" -> lin, "FeedbackInputs" -> {2}|>, {-9 + 9I, -9 - 9I, -10, -10.5}, "Data"]

生成受控模型的闭环系统：

Wolfram Language code: csys = ConnectSystemModelController[model, ctrl]

对摆施加切向力并进行仿真：

Wolfram Language code:

simModel = SystemModelSimulate[model, 5, <|"Inputs" -> {"d" -> Function[t, 0.1(UnitStep[t] - UnitStep[t - 1])], "f" -> Function[0]}|>]

模拟有同样扰动情况下的闭环系统：

Wolfram Language code:

simCsys = SystemModelSimulate[csys, 5, <|"Inputs" -> {"d" -> Function[t, 0.1(UnitStep[t] - UnitStep[t - 1])], "f" -> Function[0]}|>]

绘制原始模型中摆的角度：

Wolfram Language code: SystemModelPlot[simModel, {"phi"}, PlotRange -> All]

闭环系统施加水平力并使摆回到垂直位置：

Wolfram Language code: SystemModelPlot[simCsys, {"phi"}, PlotRange -> All]

LQRegulatorGains (2)

从连续搅拌釜式反应器的模型开始：

Wolfram Language code: model = [image];

在平衡点附近进行线性化：

Wolfram Language code: lin = SystemModelLinearize[model]

设计一个控制器：

Wolfram Language code:

ctrl = LQRegulatorGains[lin, {(⁠|   |   |   |
| - | - | - |
| 1 | 0 | 0 |
| 0 | 1 | 0 |
| 0 | 0 | 1 |⁠), {{1}}}, "Data"]

生成闭环系统：

Wolfram Language code: csys = ConnectSystemModelController[model, ctrl]

模拟原始模型，其中反应物的浓度与其平衡值相比存在不足：

Wolfram Language code: simModel = SystemModelSimulate[model, Quantity[1, "Hours"], <|"InitialValues" -> {"x1" -> -1000}|>]

模拟同样初始条件下的闭环系统：

Wolfram Language code: simCsys = SystemModelSimulate[csys, Quantity[1, "Hours"], <|"InitialValues" -> {"eSys.sys.x1" -> -1000}|>]

绘制原始模型中反应物浓度的变化：

Wolfram Language code: SystemModelPlot[simModel, {"deltaCA"}, PlotRange -> All, TargetUnits -> {"Hours", None}]

闭环系统控制流速并使浓度回到平衡值：

Wolfram Language code: SystemModelPlot[simCsys, {"deltaCA"}, PlotRange -> All, TargetUnits -> {"Hours", None}]

从放置在梁顶部的球的模型开始，该梁可以围绕其质心旋转：

Wolfram Language code: model = SystemModel[[image], <|"ParameterValues" -> {"world.enableAnimation" -> False}|>];

在平衡点附近进行线性化：

Wolfram Language code: lin = SystemModelLinearize[model]

设计一个控制器：

Wolfram Language code:

ctrl = LQRegulatorGains[lin, {(⁠|   |   |   |   |
| - | - | - | - |
| 1 | 0 | 0 | 0 |
| 0 | 1 | 0 | 0 |
| 0 | 0 | 1 | 0 |
| 0 | 0 | 0 | 1 |⁠), (⁠1⁠)}, "Data"]

生成闭环系统：

Wolfram Language code: csys = ConnectSystemModelController[model, ctrl]

模拟将球放置在梁边缘的原始模型：

Wolfram Language code: simModel = SystemModelSimulate[model, 10, <|"InitialValues" -> {"ballAndBeamDynamics.rs" -> 0.4}|>]

模拟同样初始条件下的闭环系统：

Wolfram Language code: simCsys = SystemModelSimulate[csys, 10, <|"InitialValues" -> {"eSys.sys.ballAndBeamDynamics.rs" -> 0.4}|>]

绘制球在原始模型中的位置（距梁的中间位置的距离）：

Wolfram Language code: SystemModelPlot[simModel, {"ballAndBeamDynamics.rs"}]

闭环系统施加扭矩并将球带回梁的中间：

Wolfram Language code: SystemModelPlot[simCsys, {"eSys.sys.ballAndBeamDynamics.rs"}, PlotRange -> All]

DiscreteLQRegulatorGains (2)

从连续搅拌釜式反应器的模型开始：

Wolfram Language code: model = [image];

在平衡点附近进行线性化：

Wolfram Language code: lin = SystemModelLinearize[model]

设计一个控制器：

Wolfram Language code:

ctrl = DiscreteLQRegulatorGains[lin, {(⁠|   |   |   |
| - | - | - |
| 1 | 0 | 0 |
| 0 | 1 | 0 |
| 0 | 0 | 1 |⁠), {{1}}}, 60, "Data"]

生成闭环系统：

Wolfram Language code: csys = ConnectSystemModelController[model, ctrl]

模拟原始模型，其中反应物的浓度与其平衡值相比存在不足：

Wolfram Language code: simModel = SystemModelSimulate[model, Quantity[4, "Hours"], <|"InitialValues" -> {"x1" -> -1000}|>]

模拟同样初始条件下的闭环系统：

Wolfram Language code: simCsys = SystemModelSimulate[csys, Quantity[4, "Hours"], <|"InitialValues" -> {"eSys.sys.x1" -> -1000}|>]

绘制原始模型中反应物浓度的变化：

Wolfram Language code: SystemModelPlot[simModel, {"deltaCA"}, PlotRange -> All, TargetUnits -> {"Hours", None}]

闭环系统控制流速并使浓度回到平衡值：

Wolfram Language code: SystemModelPlot[simCsys, {"deltaCA"}, PlotRange -> All, TargetUnits -> {"Hours", None}]

从放置在梁顶部的球的模型开始，该梁可以围绕其质心旋转：

Wolfram Language code: model = SystemModel[[image], <|"ParameterValues" -> {"world.enableAnimation" -> False}|>];

在平衡点附近进行线性化：

Wolfram Language code: lin = SystemModelLinearize[model]

设计一个控制器：

Wolfram Language code:

ctrl = DiscreteLQRegulatorGains[lin, {(⁠|   |   |   |   |
| - | - | - | - |
| 1 | 0 | 0 | 0 |
| 0 | 1 | 0 | 0 |
| 0 | 0 | 1 | 0 |
| 0 | 0 | 0 | 1 |⁠), (⁠1⁠)}, 0.1, "Data"]

生成闭环系统：

Wolfram Language code: csys = ConnectSystemModelController[model, ctrl]

模拟将球放置在梁边缘的原始模型：

Wolfram Language code: simModel = SystemModelSimulate[model, 10, <|"InitialValues" -> {"ballAndBeamDynamics.rs" -> 0.4}|>]

模拟同样初始条件下的闭环系统：

Wolfram Language code: simCsys = SystemModelSimulate[csys, 10, <|"InitialValues" -> {"eSys.sys.ballAndBeamDynamics.rs" -> 0.4}|>]

绘制球在原始模型中的位置（距梁的中间位置的距离）：

Wolfram Language code: SystemModelPlot[simModel, {"ballAndBeamDynamics.rs"}]

闭环系统施加扭矩并将球带回梁的中间：

Wolfram Language code: SystemModelPlot[simCsys, {"eSys.sys.ballAndBeamDynamics.rs"}, PlotRange -> All]

EstimatorRegulator (2)

从圆形轨道上的航天器模型开始：

Wolfram Language code: model = [image];

在平衡点附近进行线性化：

Wolfram Language code: lin = SystemModelLinearize[model]

设计一个控制器和观测器，把它们放在 EstimatorRegulator 中：

Wolfram Language code: k = StateFeedbackGains[lin, {-0.5, -1.5, -1, -2.5}];

Wolfram Language code: l = EstimatorGains[lin, 3 {-0.5, -1.5, -1, -2.5}];

Wolfram Language code: ctrl = EstimatorRegulator[lin, {l, k}, "Data"]

生成受控模型的闭环系统：

Wolfram Language code: csys = ConnectSystemModelController[model, ctrl]

模拟有一定初始速度的闭环系统：

Wolfram Language code: simCSys = SystemModelSimulate[csys, 12, <|"InitialValues" -> {"sys.keplerDynamics.vx" -> 0.1}|>]

闭环系统将航天器带回其圆形轨道：

Wolfram Language code: SystemModelPlot[simCSys, {"dr"}, PlotRange -> All]

从倒立摆的模型开始：

Wolfram Language code: model = \!\(\*GraphicsBox[«8»]\);

在平衡点附近进行线性化：

Wolfram Language code: lin = SystemModelLinearize[model]

设计一个控制器和观测器，把它们放在 EstimatorRegulator 中：

Wolfram Language code: sysSpec = <|"InputModel" -> lin, "FeedbackInputs" -> {2}|>;

Wolfram Language code: k = StateFeedbackGains[sysSpec, {-1 + 1.5I, -1 - 1.5I, -5, -5.5}];

Wolfram Language code: l = EstimatorGains[lin, {-9 + 9I, -9 - 9I, -10, -10.5}];

Wolfram Language code: ctrl = EstimatorRegulator[sysSpec, {l, k}, "Data"]

生成受控模型的闭环系统：

Wolfram Language code: csys = ConnectSystemModelController[model, ctrl]

模拟离平衡点有一定初始角度的闭环系统：

Wolfram Language code: simCsys = SystemModelSimulate[csys, 10, <|"InitialValues" -> {"sys.pendulumDamper.phi_rel" -> 0.1}|>]

闭环系统施加力并使摆回到垂直位置：

Wolfram Language code: SystemModelPlot[simCsys, {"sys.pendulumDamper.phi_rel"}, PlotRange -> All]

LQGRegulator (2)

从连续搅拌釜式反应器的模型开始：

Wolfram Language code: model = [image];

在平衡点附近进行线性化：

Wolfram Language code: lin = SystemModelLinearize[model]

设计一个控制器：

Wolfram Language code:

ctrl = LQGRegulator[lin, {{{}}, (⁠|   |   |   |
| - | - | - |
| 1 | 0 | 0 |
| 0 | 1 | 0 |
| 0 | 0 | 1 |⁠)}, {(⁠|   |   |   |
| - | - | - |
| 1 | 0 | 0 |
| 0 | 1 | 0 |
| 0 | 0 | 1 |⁠), (⁠1⁠)}, "Data"]

生成受控模型的闭环系统：

Wolfram Language code: csys = ConnectSystemModelController[model, ctrl]

模拟原始模型，其中反应物的浓度与其平衡值相比存在不足：

Wolfram Language code: simCsys = SystemModelSimulate[csys, Quantity[8, "Hours"], <|"InitialValues" -> {"sys.x1" -> -1000}|>]

闭环系统控制流速并使浓度回到平衡值：

Wolfram Language code: SystemModelPlot[simCsys, {"deltaCA"}, PlotRange -> All, TargetUnits -> {"Hours", None}]

从放置在梁顶部的球的模型开始，该梁可以围绕其质心旋转，并添加一些旋转阻尼：

Wolfram Language code: model = SystemModel[[image], <|"ParameterValues" -> {"b" -> 1, "world.enableAnimation" -> False}|>];

在平衡点附近进行线性化：

Wolfram Language code: lin = SystemModelLinearize[model]

设计一个控制器：

Wolfram Language code:

ctrl = LQGRegulator[lin, {{{}}, (⁠|       |       |
| ----- | ----- |
| 10^-6 | 0     |
| 0     | 10^-6 |⁠)}, {(⁠|      |      |      |      |
| ---- | ---- | ---- | ---- |
| 10^4 | 0    | 0    | 0    |
| 0    | 10^4 | 0    | 0    |
| 0    | 0    | 10^4 | 0    |
| 0    | 0    | 0    | 10^4 |⁠), (⁠1⁠)}, "Data"]

生成受控模型的闭环系统：

Wolfram Language code: csys = ConnectSystemModelController[model, ctrl]

将球放置在远离梁中间的位置，模拟闭环系统：

Wolfram Language code: simCsys = SystemModelSimulate[csys, 20, <|"InitialValues" -> {"sys.ballAndBeamDynamics.rs" -> 0.4}|>]

闭环系统施加扭矩并将球带回梁的中间：

Wolfram Language code: SystemModelPlot[simCsys, {"sys.ballAndBeamDynamics.rs"}, PlotRange -> All]

PIDTune (1)

从 RLC 电路的模型开始：

Wolfram Language code: model = [image];

在平衡点附近进行线性化：

Wolfram Language code: lin = SystemModelLinearize[model]

设计一个控制器：

Wolfram Language code: ctrl = PIDTune[lin, Automatic, "Data"]

生成受控模型的闭环系统：

Wolfram Language code: csys = ConnectSystemModelController[model, ctrl]

提供参考输入并绘制输出：

Wolfram Language code:

SystemModelPlot[csys, {"out"}, 0.1, <|"Inputs" -> {"ref" -> Function[2], "ctrlDist" -> Cos, "sensNoise" -> Sin}|>, PlotRange -> All]

ModelPredictiveController (2)

从相机稳定器的模型开始：

Wolfram Language code: model = \!\(\*GraphicsBox[«8»]\);

围绕平衡点对其进行线性化：

Wolfram Language code: SystemModelLinearize[model]

创建控制器：

Wolfram Language code:

sspec = <|"InputModel" -> model, "SamplingPeriod" -> 0.05, "SamplingMethod" -> "ForwardRectangularRule", "FeedbackInputs" -> {"fa"}|>;

Wolfram Language code:

cost = <|"Horizon" -> 3, "StateWeight" -> (⁠|   |      |   |   |      |   |
| - | ---- | - | - | ---- | - |
| 1 | 0    | 0 | 0 | 0    | 0 |
| 0 | 10^6 | 0 | 0 | 0    | 0 |
| 0 | 0    | 1 | 0 | 0    | 0 |
| 0 | 0    | 0 | 1 | 0    | 0 |
| 0 | 0    | 0 | 0 | 10^6 | 0 |
| 0 | 0    | 0 | 0 | 0    | 1 |⁠), "InputWeight" -> (⁠1⁠)|>;

Wolfram Language code: cons = {-0.1 <= "xce" <= 0.1};

Wolfram Language code: ctrl = ModelPredictiveController[sspec, cost, cons]

为受控模型生成闭环系统：

Wolfram Language code: csys = ConnectSystemModelController["CLSMPC", model, ctrl]

用垂直力扰动系统：

Wolfram Language code: bumpInputs = <|"Inputs" -> {"fa" -> Function[t, 0], "fw" -> Function[t, 2000(UnitStep[t] - UnitStep[t - 0.25])]}|>;

Wolfram Language code: simModel = SystemModelSimulate[model, 10, bumpInputs]

模拟具有相同扰动的闭环系统：

Wolfram Language code: simCsys = SystemModelSimulate[csys, 10, bumpInputs]

绘制相机在原始模型中的位置：

Wolfram Language code: SystemModelPlot[simModel, {"xce"}, PlotRange -> {-0.025, 0.025}]

在闭环系统中，相机的位置变化不大：

Wolfram Language code: SystemModelPlot[simCsys, {"eSys.sys.xce"}, PlotRange -> {-0.025, 0.025}]

从连续搅拌釜反应器的模型开始：

Wolfram Language code: model = [image];

围绕平衡点对其进行线性化：

Wolfram Language code: SystemModelLinearize[model]

创建控制器：

Wolfram Language code: sspec = <|"InputModel" -> model, "SamplingPeriod" -> 60, "SamplingMethod" -> "ForwardRectangularRule"|>;

Wolfram Language code:

cost = <|"Horizon" -> ∞, "StateWeight" -> (⁠|   |   |   |
| - | - | - |
| 1 | 0 | 0 |
| 0 | 1 | 0 |
| 0 | 0 | 1 |⁠), "InputWeight" -> (⁠1⁠)|>;

Wolfram Language code: cons = {-50 ≤ "deltaCA" ≤ 50};

Wolfram Language code: ctrl = ModelPredictiveController[sspec, cost, cons]

为受控模型生成闭环系统：

Wolfram Language code: csys = ConnectSystemModelController["CLSMPC", model, ctrl]

模拟原始模型，其中反应物浓度与其平衡值相比存在不足：

Wolfram Language code: simModel = SystemModelSimulate[model, Quantity[4, "Hours"], <|"InitialValues" -> {"x1" -> -20}|>]

模拟具有相同初始条件的闭环系统：

Wolfram Language code: simCsys = SystemModelSimulate[csys, Quantity[4, "Hours"], <|"InitialValues" -> {"eSys.sys.x1" -> -20}|>]

绘制原始模型中反应物浓度的变化：

Wolfram Language code: SystemModelPlot[simModel, {"x1"}, PlotRange -> All, TargetUnits -> {"Hours", Automatic}]

闭环系统控制流速并使浓度回到平衡值：

Wolfram Language code: SystemModelPlot[simCsys, {"eSys.sys.x1"}, PlotRange -> All, TargetUnits -> {"Hours", Automatic}]

Tracking (2)

从潜艇模型开始：

Wolfram Language code: model = [image];

围绕平衡点对其进行线性化：

Wolfram Language code: lin = SystemModelLinearize[model]

设计一个跟踪潜艇深度的控制器：

Wolfram Language code: sspec = <|"InputModel" -> lin, "FeedbackInputs" -> {1}, "TrackedOutputs" -> {1}|>;

Wolfram Language code: ctrl = StateFeedbackGains[sspec, {-2 + I, -2 - I, -2}, "Data"]

为受控模型生成闭环系统：

Wolfram Language code: csys = ConnectSystemModelController[model, ctrl]

模拟闭环系统，为深度和噪声提供参考信号：

Wolfram Language code:

sim = SystemModelSimulate[csys, 100, <|"Inputs" -> {"refY" -> Function[t, -10Tanh[t / 10]], "f" -> RandomFunction[WienerProcess[0, 10^6], {0, 100, 0.1}]}|>]

绘制参考信号和输出：

Wolfram Language code: SystemModelPlot[sim, {"refY", "y"}, PlotRange -> All]

绘制重现参考信号所需的密度变化：

Wolfram Language code: SystemModelPlot[sim, {"eSys.sys.deltarho"}, PlotRange -> All]

创建一个球体的模型，放置在可以围绕其质心旋转的梁的顶部：

Wolfram Language code: model = SystemModel[[image], <|"ParameterValues" -> {"world.enableAnimation" -> False}|>];

围绕平衡点对其进行线性化：

Wolfram Language code: lin = SystemModelLinearize[model]

设计一个跟踪球体位置的控制器：

Wolfram Language code: sspec = <|"InputModel" -> lin, "TrackedOutputs" -> {1}|>;

Wolfram Language code:

ctrl = LQGRegulator[sspec, {{{}}, (⁠|       |       |
| ----- | ----- |
| 10^-5 | 0     |
| 0     | 10^-5 |⁠)}, {10^4(⁠|   |   |   |   |   |
| - | - | - | - | - |
| 1 | 0 | 0 | 0 | 0 |
| 0 | 1 | 0 | 0 | 0 |
| 0 | 0 | 1 | 0 | 0 |
| 0 | 0 | 0 | 1 | 0 |
| 0 | 0 | 0 | 0 | 1 |⁠), (⁠1⁠)}, "Data"]

为受控模型生成闭环系统：

Wolfram Language code: csys = ConnectSystemModelController[model, ctrl]

模拟为位置和噪声提供参考信号的闭环系统：

Wolfram Language code:

sim = Quiet[SystemModelSimulate[csys, 100, <|"Inputs" -> {"refRs" -> Function[t, 1 / 2 E ^ (-(1 / 8) (-10 + t) ^ 2)], "noiseRs" -> RandomFunction[WienerProcess[0, 0.0001], {0, 100, 0.01}], "noiseThetab" -> RandomFunction[WienerProcess[0, 0.00001], {0, 100, 0.01}]}|>], {General::munfl}]

绘制参考信号和输出：

Wolfram Language code: SystemModelPlot[sim, {"rs", "refRs"}, PlotRange -> All]

绘制重现参考信号所需的输入扭矩：

Wolfram Language code: SystemModelPlot[sim, {"sys.T"}, PlotRange -> All]

Top

更多学习资源

技术支持

数据科学、金融与商业

工程

科学与技术

教育科技

教育举措

开始

提高你的技能

与我们合作

成人教育计划

青少年教育计划

欢迎阅读

ConnectSystemModelController

更多信息

范例

基本范例 (1)

范围 (16)

StateFeedbackGains (3)

LQRegulatorGains (2)

DiscreteLQRegulatorGains (2)

EstimatorRegulator (2)

LQGRegulator (2)

PIDTune (1)

ModelPredictiveController (2)

Tracking (2)

文本

CMS

APA

BibTeX

BibLaTeX

	StateFeedbackGains	极点放置状态反馈
	LQRegulatorGains	线性二次最优控制
	DiscreteLQRegulatorGains	离散时间线性二次最优控制
	ModelPredictiveController	约束模型预测控制器

	EstimatorRegulator	组合状态反馈和状态估计器
	LQGRegulator	线性二次控制和估计器
	PIDTune	自动调谐的 PID 控制器

ConnectSystemModelController

更多信息

范例

基本范例 (1)

范围 (16)

StateFeedbackGains (3)

LQRegulatorGains (2)

DiscreteLQRegulatorGains (2)

EstimatorRegulator (2)

LQGRegulator (2)

PIDTune (1)

ModelPredictiveController (2)

Tracking (2)

参见

相关指南

相关链接

历史

文本

CMS

APA

BibTeX

BibLaTeX