WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

ContainsExactly[list1,list2]

list1が list2と全く同じ要素を含む場合にTrueを返す．

ContainsExactly[list2]

適用されたオブジェクトが list2と全く同じ要素を含む場合にTrueを返す，この関数の演算子形である．

詳細とオプション
Details and Options Details and Options
例題  
例  
スコープ  
オプション  
SameTest  
アプリケーション  
特性と関係  
関連項目
関連するガイド
履歴
引用書式

ContainsExactly

ContainsExactly[list1,list2]

list1が list2と全く同じ要素を含む場合にTrueを返す．

ContainsExactly[list2]

適用されたオブジェクトが list2と全く同じ要素を含む場合にTrueを返す，この関数の演算子形である．

詳細とオプション

例題

すべて開く すべて閉じる

例  (2)

どちらのリストも厳密に同じ要素を含んでいる：

Wolfram Language code: ContainsExactly[{b, a, b, c}, {a, b, c}]

以下のリストは別の要素を含んでいる：

Wolfram Language code: ContainsExactly[{b, a, d, d}, {a, b, c}]

スコープ  (4)

ある化学物質が厳密に同じ要素を含んでいるかどうかを調べる：

Wolfram Language code: ContainsExactly[ChemicalData[Entity["Chemical", "Sucrose"], "ElementTypes"], {"C", "H", "O"}]
Wolfram Language code: ContainsExactly[ChemicalData[Entity["Chemical", "6Mercaptopurine9BetaDRibofuranoside"], "ElementTypes"], {"C", "H", "O"}]

ContainsExactlyの演算子形を使う：

Wolfram Language code: fullweekend = ContainsExactly[{Saturday, Sunday}]
Wolfram Language code: fullweekend[{Sunday, Saturday, Friday}]
Wolfram Language code: fullweekend[{Sunday, Saturday, Sunday}]

1982年にバーニー・トーピン(Bernie Taupin)とエルトン・ジョン(Elton John)によって作曲された音楽作品を求める：

Wolfram Language code: EntityList[EntityClass["MusicWork", {"FirstReleaseDate" -> DateObject[{1982}], "Composers" -> ContainsExactly[{Entity["Person", "BernieTaupin::g5988"], Entity["Person", "EltonJohn::8fg2d"]}]}]]

ContainsExactlyは連想に使うことができる：

Wolfram Language code: ContainsExactly[<|a -> x, b -> y, c -> x|>, {x, y}]
Wolfram Language code: ContainsExactly[<|a -> x, b -> y, c -> x|>, <|1 -> x, 2 -> y|>]

オプション  (2)

SameTest  (2)

デフォルトで，ContainsExactlyは要素が等しければ同じであるとみなす：

Wolfram Language code: list = Subdivide[Quantity[0, "Meters"], Quantity[1, "Meters"], 2]
Wolfram Language code: ContainsExactly[list, {Quantity[0, "Meters"], Quantity[1/2, "Meters"], Quantity[1, "Meters"]}]

両者が全く同じ量を表している場合は，単位の違いが考慮される：

Wolfram Language code: ContainsExactly[list, {Quantity[0, "Centimeters"], Quantity[50, "Centimeters"], Quantity[100, "Centimeters"]}]

近似された数値は同じオブジェクトとはみなされない：

Wolfram Language code: ContainsExactly[list, {Quantity[0., "Centimeters"], Quantity[50., "Centimeters"], Quantity[100., "Centimeters"]}]

Equalを比較関数として使って数値許容度を持たせる：

Wolfram Language code: ContainsExactly[list, {Quantity[0., "Centimeters"], Quantity[50., "Centimeters"], Quantity[100., "Centimeters"]}, SameTest -> Equal]

文字列の比較は，デフォルトで大文字小文字の違いに敏感である：

Wolfram Language code: ContainsExactly[{"A", "B", "C"}, {"a", "b", "c"}]

比較の前に小文字に変換する：

Wolfram Language code: ContainsExactly[{"A", "B", "C"}, {"a", "b", "c"}, SameTest -> (SameQ[ToLowerCase[#1], ToLowerCase[#2]]&)]

アプリケーション  (1)

同じ文字を含む2つのアナグラムの単語または語句：

Wolfram Language code: letters[string_] := DeleteCases[Characters[string], " "]
Wolfram Language code: anagramQ[string1_, string2_] := ContainsExactly[letters[string1], letters[string2]]

「parsley」という単語は「replays」という単語のアナグラムである：

Wolfram Language code: anagramQ["parsley", "replays"]

次に2つの語句は同じ文字を含んでいる：

Wolfram Language code: anagramQ["eleven plus two", "twelve plus one"]

特性と関係  (3)

ContainsExactly[list1,list2]は，等価性を集合として調べることに等しい：

Wolfram Language code: list1 = {2, 0, 0, 4, 3, 2, 4, 3, 2, 4};
Wolfram Language code: list2 = {3, 3, 1, 2, 0, 4, 1, 1, 3, 5};
Wolfram Language code: {ContainsExactly[list1, list2], SameQ[Union[list1], Union[list2]]}

ContainsExactlyは，その引数の対称関数である．つまり，ContainsExactly[list1,list2]==ContainsExactly[list2,list1]である：

Wolfram Language code: list1 = {2, 0, 0, 5, 0, 4, 0, 4, 4, 4};
Wolfram Language code: list2 = {0, 3, 3, 4, 2, 0, 5, 0, 1, 1};
Wolfram Language code: {ContainsExactly[list1, list2], ContainsExactly[list2, list1]}

ContainsExactly[list1,list2]はAnd[ContainsAll[list1,list2],ContainsOnly[list1,list2]]に等しい：

Wolfram Language code: list1 = {5, 1, 4, 4, 4, 2, 2, 0, 2, 3};
Wolfram Language code: list2 = {5, 4, 4, 3, 1, 0, 3, 0, 2, 2};
Wolfram Language code: {ContainsExactly[list1, list2], And[ContainsAll[list1, list2], ContainsOnly[list1, list2]]}
Wolfram Research (2015), ContainsExactly, Wolfram言語関数， https://reference.wolfram.com/language/ref/ContainsExactly.html.

テキスト

Wolfram Research (2015), ContainsExactly, Wolfram言語関数， https://reference.wolfram.com/language/ref/ContainsExactly.html.

CMS

Wolfram Language. 2015. "ContainsExactly." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/ContainsExactly.html.

APA

Wolfram Language. (2015). ContainsExactly. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/ContainsExactly.html

BibTeX

@misc{reference.wolfram_2026_containsexactly, author="Wolfram Research", title="{ContainsExactly}", year="2015", howpublished="\url{https://reference.wolfram.com/language/ref/ContainsExactly.html}", note=[Accessed: 09-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_containsexactly, organization={Wolfram Research}, title={ContainsExactly}, year={2015}, url={https://reference.wolfram.com/language/ref/ContainsExactly.html}, note=[Accessed: 09-September-2026]}