WOLFRAM

Wolfram 语言与系统参考资料中心

ContainsExactly[list1,list2]

如果 list1 含有和 list2 中完全相同的元素则产生 True.

ContainsExactly[list2]

当所应用的对象含有 list2 中完全相同的元素时产生 True 的运算符形式.

更多信息和选项
Details and Options Details and Options
范例  
基本范例  
范围  
选项  
SameTest  
应用  
属性和关系  
参见
相关指南
历史
按以下格式引用：

ContainsExactly

ContainsExactly[list1,list2]

如果 list1 含有和 list2 中完全相同的元素则产生 True.

ContainsExactly[list2]

当所应用的对象含有 list2 中完全相同的元素时产生 True 的运算符形式.

更多信息和选项

范例

打开所有单元 关闭所有单元

基本范例  (2)

两个列表含有的元素完全相同：

Wolfram Language code: ContainsExactly[{b, a, b, c}, {a, b, c}]

列表含有不同的元素：

Wolfram Language code: ContainsExactly[{b, a, d, d}, {a, b, c}]

范围  (4)

查看某化学品中是否含有一些特定元素：

Wolfram Language code: ContainsExactly[ChemicalData[Entity["Chemical", "Sucrose"], "ElementTypes"], {"C", "H", "O"}]
Wolfram Language code: ContainsExactly[ChemicalData[Entity["Chemical", "6Mercaptopurine9BetaDRibofuranoside"], "ElementTypes"], {"C", "H", "O"}]

在运算符形式中使用 ContainsExactly：

Wolfram Language code: fullweekend = ContainsExactly[{Saturday, Sunday}]
Wolfram Language code: fullweekend[{Sunday, Saturday, Friday}]
Wolfram Language code: fullweekend[{Sunday, Saturday, Sunday}]

找出 Bernie Taupin 和 Elton John 在 1982 年创作的音乐作品：

Wolfram Language code: EntityList[EntityClass["MusicWork", {"FirstReleaseDate" -> DateObject[{1982}], "Composers" -> ContainsExactly[{Entity["Person", "BernieTaupin::g5988"], Entity["Person", "EltonJohn::8fg2d"]}]}]]

ContainsExactly 作用于结合：

Wolfram Language code: ContainsExactly[<|a -> x, b -> y, c -> x|>, {x, y}]
Wolfram Language code: ContainsExactly[<|a -> x, b -> y, c -> x|>, <|1 -> x, 2 -> y|>]

选项  (2)

SameTest  (2)

默认情况下， ContainsExactly 认为同一的元素是相同的：

Wolfram Language code: list = Subdivide[Quantity[0, "Meters"], Quantity[1, "Meters"], 2]
Wolfram Language code: ContainsExactly[list, {Quantity[0, "Meters"], Quantity[1/2, "Meters"], Quantity[1, "Meters"]}]

只要所表示的数值相同，已考虑到单位换算：

Wolfram Language code: ContainsExactly[list, {Quantity[0, "Centimeters"], Quantity[50, "Centimeters"], Quantity[100, "Centimeters"]}]

数值近似不视为相同对象：

Wolfram Language code: ContainsExactly[list, {Quantity[0., "Centimeters"], Quantity[50., "Centimeters"], Quantity[100., "Centimeters"]}]

Equal 可以用作比较函数得到数值容忍度：

Wolfram Language code: ContainsExactly[list, {Quantity[0., "Centimeters"], Quantity[50., "Centimeters"], Quantity[100., "Centimeters"]}, SameTest -> Equal]

默认情况下字符串比较是区分大小写的：

Wolfram Language code: ContainsExactly[{"A", "B", "C"}, {"a", "b", "c"}]

比较前转换成小写：

Wolfram Language code: ContainsExactly[{"A", "B", "C"}, {"a", "b", "c"}, SameTest -> (SameQ[ToLowerCase[#1], ToLowerCase[#2]]&)]

应用  (1)

两个变异单词或短语包含相同的字母：

Wolfram Language code: letters[string_] := DeleteCases[Characters[string], " "]
Wolfram Language code: anagramQ[string1_, string2_] := ContainsExactly[letters[string1], letters[string2]]

单词 "parsley" 是单词 "replays" 的变位换音词：

Wolfram Language code: anagramQ["parsley", "replays"]

这两个短语包含相同的字母：

Wolfram Language code: anagramQ["eleven plus two", "twelve plus one"]

属性和关系  (3)

ContainsExactly[list1,list2] 等价于集合的相等测试：

Wolfram Language code: list1 = {2, 0, 0, 4, 3, 2, 4, 3, 2, 4};
Wolfram Language code: list2 = {3, 3, 1, 2, 0, 4, 1, 1, 3, 5};
Wolfram Language code: {ContainsExactly[list1, list2], SameQ[Union[list1], Union[list2]]}

ContainsExactly 是其自变量的对称方程. 即，ContainsExactly[list1,list2]==ContainsExactly[list2,list1]：

Wolfram Language code: list1 = {2, 0, 0, 5, 0, 4, 0, 4, 4, 4};
Wolfram Language code: list2 = {0, 3, 3, 4, 2, 0, 5, 0, 1, 1};
Wolfram Language code: {ContainsExactly[list1, list2], ContainsExactly[list2, list1]}

ContainsExactly[list1,list2] 等价于 And[ContainsAll[list1,list2],ContainsOnly[list1,list2]]:

Wolfram Language code: list1 = {5, 1, 4, 4, 4, 2, 2, 0, 2, 3};
Wolfram Language code: list2 = {5, 4, 4, 3, 1, 0, 3, 0, 2, 2};
Wolfram Language code: {ContainsExactly[list1, list2], And[ContainsAll[list1, list2], ContainsOnly[list1, list2]]}
Wolfram Research (2015)，ContainsExactly，Wolfram 语言函数，https://reference.wolfram.com/language/ref/ContainsExactly.html.

文本

Wolfram Research (2015)，ContainsExactly，Wolfram 语言函数，https://reference.wolfram.com/language/ref/ContainsExactly.html.

CMS

Wolfram 语言. 2015. "ContainsExactly." Wolfram 语言与系统参考资料中心. Wolfram Research. https://reference.wolfram.com/language/ref/ContainsExactly.html.

APA

Wolfram 语言. (2015). ContainsExactly. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/ContainsExactly.html 年

BibTeX

@misc{reference.wolfram_2026_containsexactly, author="Wolfram Research", title="{ContainsExactly}", year="2015", howpublished="\url{https://reference.wolfram.com/language/ref/ContainsExactly.html}", note=[Accessed: 15-October-2026]}

BibLaTeX

@online{reference.wolfram_2026_containsexactly, organization={Wolfram Research}, title={ContainsExactly}, year={2015}, url={https://reference.wolfram.com/language/ref/ContainsExactly.html}, note=[Accessed: 15-October-2026]}