WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

ConvexHullMesh[{p1,p2,…}]

点 p1, p2, …からの凸包を表すBoundaryMeshRegionを与える．

ConvexHullMesh[mreg]

メッシュ領域 mreg の凸包を与える．

詳細とオプション
Details and Options Details and Options
例題  
例  
スコープ  
オプション  
MeshCellHighlight  
MeshCellLabel  
MeshCellMarker  
MeshCellShapeFunction  
MeshCellStyle  
PlotTheme  
アプリケーション  
特性と関係  
考えられる問題  
関連項目
関連するガイド
履歴
引用書式

ConvexHullMesh

ConvexHullMesh[{p1,p2,…}]

点 p1, p2, …からの凸包を表すBoundaryMeshRegionを与える．

ConvexHullMesh[mreg]

メッシュ領域 mreg の凸包を与える．

詳細とオプション

  • ConvexHullMeshは，凸包絡あるいは凸包としても知られている．
  • 凸包メッシュは，点を piを含む最小の凸集合である．
  • 凸包の境界は，1Dの点，2Dの線分，3Dの凸多角形からなる．
  • ConvexHullMeshはBoundaryMeshRegionと同じオプションを取る．

例題

すべて開く すべて閉じる

例  (3)

1D凸包メッシュ：

Wolfram Language code: pts = RandomReal[{-1, 1}, {5, 1}];
Wolfram Language code: ConvexHullMesh[pts]

この領域は，点を含む最小の凸領域である：

Wolfram Language code: Show[%, Show[%, Graphics[Point[Append[#, 0]& /@ pts]]]]

2D凸包メッシュ：

Wolfram Language code: pts = RandomReal[{-1, 1}, {50, 2}];
Wolfram Language code: ConvexHullMesh[pts]

この領域は，点を含む最小の凸領域である：

Wolfram Language code: Show[%, Graphics[Point[pts]]]

3D凸包メッシュ：

Wolfram Language code: pts = RandomReal[{-1, 1}, {50, 3}];
Wolfram Language code: ConvexHullMesh[pts]

この領域は，点を含む最小の凸領域である：

Wolfram Language code: Show[HighlightMesh[%, Style[2, Opacity[0.5]]], Graphics3D[Point[pts]]]

スコープ  (3)

点集合から1D凸包メッシュを作る：

Wolfram Language code: pts = RandomReal[{-1, 1}, {50, 1}];
Wolfram Language code: ℛ = ConvexHullMesh[pts]

基本的な特性：

Wolfram Language code: {RegionQ[ℛ], BoundaryMeshRegionQ[ℛ]}

凸包メッシュは有界である：

Wolfram Language code: {BoundedRegionQ[ℛ], RegionBounds[ℛ]}

凸包メッシュは全次元である：

Wolfram Language code: {RegionDimension[ℛ], RegionEmbeddingDimension[ℛ]}

面積と重心を求める：

Wolfram Language code: {RegionMeasure[ℛ], RegionCentroid[ℛ]}

点の帰属判定：

Wolfram Language code: RegionMember[ℛ, {0}]

最近点とその距離を求める：

Wolfram Language code: {RegionDistance[ℛ, {2}], RegionNearest[ℛ, {2}]}

点集合から2D凸包メッシュを作る：

Wolfram Language code: pts = RandomReal[{-1, 1}, {50, 2}];
Wolfram Language code: ℛ = ConvexHullMesh[pts]

基本的な特性：

Wolfram Language code: {RegionQ[ℛ], BoundaryMeshRegionQ[ℛ]}

凸包メッシュは有界である：

Wolfram Language code: {BoundedRegionQ[ℛ], RegionBounds[ℛ]}

凸包メッシュは全次元である：

Wolfram Language code: {RegionDimension[ℛ], RegionEmbeddingDimension[ℛ]}

その面積と重心を求める：

Wolfram Language code: {RegionMeasure[ℛ], RegionCentroid[ℛ]}

点の帰属判定：

Wolfram Language code: RegionMember[ℛ, {0, 0}]

最近点とその距離を求める：

Wolfram Language code: {RegionDistance[ℛ, {2, 2}], RegionNearest[ℛ, {2, 2}]}

点集合から3D凸包メッシュを作る：

Wolfram Language code: pts = RandomReal[{-1, 1}, {50, 3}];
Wolfram Language code: ℛ = ConvexHullMesh[pts]

基本的な特性：

Wolfram Language code: {RegionQ[ℛ], BoundaryMeshRegionQ[ℛ]}

凸包メッシュは有界である：

Wolfram Language code: {BoundedRegionQ[ℛ], RegionBounds[ℛ]}

凸包メッシュは全次元である：

Wolfram Language code: {RegionDimension[ℛ], RegionEmbeddingDimension[ℛ]}

その体積と重心を求める：

Wolfram Language code: {RegionMeasure[ℛ], RegionCentroid[ℛ]}

その表面積を求める：

Wolfram Language code: Area[RegionBoundary[ℛ]]
Wolfram Language code: RegionMember[ℛ, {0, 0, 0}]

最近点とその距離を求める：

Wolfram Language code: {RegionDistance[ℛ, {2, 2, 2}], RegionNearest[ℛ, {2, 2, 2}]}

オプション  (13)

MeshCellHighlight  (3)

MeshCellHighlightを使ってConvexHullMeshの各部分をハイライトすることができる：

Wolfram Language code: ConvexHullMesh[{{0, 0}, {1, 0}, {0, 1}, {1, 1}}, MeshCellHighlight -> {{1, All} -> Orange, {0, All} -> Green}]

面を透過的にすることで，3DConvexHullMeshの内部構造を見ることができる：

Wolfram Language code: ConvexHullMesh[{{0, 0, 0}, {1, 0, 0}, {0, 1, 0}, {0, 0, 1}, {1, 1, 0}}, MeshCellHighlight -> {{2, All} -> Opacity[0.5, Orange]}]

個々のセルはセル指標を使ってハイライトすることができる：

Wolfram Language code: ConvexHullMesh[{{0, 0}, {1, 0}, {0, 1}, {1, 1}}, MeshCellHighlight -> {{1, 1} -> {Thick, Orange}, {1, 2} -> {Dashed, Green}}]

セルそれ自体を使うこともできる：

Wolfram Language code: ConvexHullMesh[{{0, 0}, {1, 0}, {0, 1}, {1, 1}}, MeshCellHighlight -> {Line[{1, 2}] -> {Thick, Orange}, Line[{2, 4}] -> {Dashed, Green}}]

MeshCellLabel  (2)

MeshCellLabelを使ってConvexHullMeshの各部分にラベルを付けることができる：

Wolfram Language code: ConvexHullMesh[{{0, 0}, {1, 0}, {0, 1}, {1, 1}}, MeshCellLabel -> {0 -> "Index"}]

個々のセルにはセル指標を使ってラベルを付けることができる：

Wolfram Language code: ConvexHullMesh[{{0, 0}, {1, 0}, {0, 1}, {1, 1}}, MeshCellLabel -> {{1, 1} -> "x", {1, 2} -> "y"}]

セルそれ自体を使うこともできる：

Wolfram Language code: ConvexHullMesh[{{0, 0}, {1, 0}, {0, 1}, {1, 1}}, MeshCellLabel -> {Line[{1, 2}] -> "x", Line[{2, 4}] -> "y"}]

MeshCellMarker  (1)

MeshCellMarkerを使ってConvexHullMeshの各部分に値を割り当てることができる：

Wolfram Language code: ConvexHullMesh[{{0, 0}, {1, 0}, {0, 1}, {1, 1}}, MeshCellMarker -> {{0, 1} -> 1, {0, 2} -> 2, {0, 3} -> 3, {0, 4} -> 4}]

MeshCellLabelを使ってマーカーを示す：

Wolfram Language code: ConvexHullMesh[{{0, 0}, {1, 0}, {0, 1}, {1, 1}}, MeshCellMarker -> {{0, 1} -> 1, {0, 2} -> 2, {0, 3} -> 3, {0, 4} -> 4}, MeshCellLabel -> {0 -> "Marker"}]

MeshCellShapeFunction  (2)

MeshCellShapeFunctionを使ってConvexHullMeshの各部分についての関数を指定することができる：

Wolfram Language code: ConvexHullMesh[{{0, 0}, {1, 0}, {0, 1}, {1, 1}}, MeshCellShapeFunction -> {0 -> (Disk[#, .1]&)}]

個々のセルはセル指標を使って描くことができる：

Wolfram Language code: ConvexHullMesh[{{0, 0}, {1, 0}, {0, 1}, {1, 1}}, MeshCellShapeFunction -> {{0, 1} -> (Disk[#, .1]&), {0, 2} -> (Disk[#, {.1, .2}]&)}]

セルそれ自体を使うこともできる：

Wolfram Language code: ConvexHullMesh[{{0, 0}, {1, 0}, {0, 1}, {1, 1}}, MeshCellShapeFunction -> {Point[1] -> (Disk[#, .1]&), Point[2] -> (Disk[#, {.1, .2}]&)}]

MeshCellStyle  (3)

MeshCellStyleを使ってConvexHullMeshの各部分のスタイルを指定することができる：

Wolfram Language code: ConvexHullMesh[{{0, 0}, {1, 0}, {0, 1}, {1, 1}}, MeshCellStyle -> {{1, All} -> Orange, {0, All} -> Green}]

面を透過的にすることで，3D ConvexHullMeshの内部構造を見ることができる：

Wolfram Language code: ConvexHullMesh[{{0, 0, 0}, {1, 0, 0}, {0, 1, 0}, {0, 0, 1}, {1, 1, 0}}, MeshCellStyle -> {{2, All} -> Opacity[0.5, Orange]}]

個々のセルはセル指標を使ってハイライトすることができる：

Wolfram Language code: ConvexHullMesh[{{0, 0}, {1, 0}, {0, 1}, {1, 1}}, MeshCellStyle -> {{1, 1} -> {Thick, Orange}, {1, 2} -> {Dashed, Green}}]

セルそれ自体を使うこともできる：

Wolfram Language code: ConvexHullMesh[{{0, 0}, {1, 0}, {0, 1}, {1, 1}}, MeshCellStyle -> {Line[{1, 2}] -> {Thick, Orange}, Line[{2, 4}] -> {Dashed, Green}}]

PlotTheme  (2)

格子線と凡例のあるテーマを使う：

Wolfram Language code: ConvexHullMesh[ExampleData[{"Geometry3D", "UtahTeapot"}, "VertexData"], PlotTheme -> "Detailed"]

テーマを使ってワイヤーフレームを描く：

Wolfram Language code: ConvexHullMesh[ExampleData[{"Geometry3D", "UtahTeapot"}, "VertexData"], PlotTheme -> "Lines"]

アプリケーション  (2)

5つの四面体を組み合せた凸包は十二面体である：

Wolfram Language code: ℛ = DiscretizeGraphics[PolyhedronData["TetrahedronFiveCompound"]]
Wolfram Language code: ConvexHullMesh[MeshCoordinates[ℛ]]

牛の凸包を計算する：

Wolfram Language code: cowPoints = ExampleData[{"Geometry3D", "Cow"}, "VertexData"];
Wolfram Language code: cowvexHull = ConvexHullMesh[cowPoints];

牛と凸包を可視化する：

Wolfram Language code: cow = ExampleData[{"Geometry3D", "Cow"}, "Graphics3D"];
Wolfram Language code: Show[HighlightMesh[cowvexHull, {Style[1, {Brown}], Style[2, Opacity[0.3, Brown]]}], cow]

特性と関係  (3)

ConvexHullMeshは，事実上，DelaunayMeshのBoundaryMeshである：

Wolfram Language code: pts = RandomReal[1, {5, 2}];
Wolfram Language code: {BoundaryMesh[DelaunayMesh[pts]], ConvexHullMesh[pts]}

3Dで：

Wolfram Language code: pts = RandomReal[{-1, 1}, {50, 3}];
Wolfram Language code: {BoundaryMesh[DelaunayMesh[pts]], ConvexHullMesh[pts]}

DelaunayMeshを使って，凸包内部のドロネー(Delaunay) 三角形分割を得る：

Wolfram Language code: DelaunayMesh[RandomReal[1, {25, 2}]]

TriangulateMeshを使って内部の三角形分割を制御する：

Wolfram Language code: ℛ = ConvexHullMesh[RandomReal[1, {25, 2}]];
Wolfram Language code: {TriangulateMesh[ℛ], TriangulateMesh[ℛ, MaxCellMeasure -> ∞]}

考えられる問題  (1)

ConvexHullMeshは全次元のメッシュ領域しか返さない：

Wolfram Language code: ConvexHullMesh[{{0., 0.}, {1., 0.}}]

ConvexHullRegionを使って凸包を得る：

Wolfram Language code: ConvexHullRegion[{{0., 0.}, {1., 0.}}]
Wolfram Research (2014), ConvexHullMesh, Wolfram言語関数， https://reference.wolfram.com/language/ref/ConvexHullMesh.html （2020年に更新）.

テキスト

Wolfram Research (2014), ConvexHullMesh, Wolfram言語関数， https://reference.wolfram.com/language/ref/ConvexHullMesh.html （2020年に更新）.

CMS

Wolfram Language. 2014. "ConvexHullMesh." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2020. https://reference.wolfram.com/language/ref/ConvexHullMesh.html.

APA

Wolfram Language. (2014). ConvexHullMesh. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/ConvexHullMesh.html

BibTeX

@misc{reference.wolfram_2026_convexhullmesh, author="Wolfram Research", title="{ConvexHullMesh}", year="2020", howpublished="\url{https://reference.wolfram.com/language/ref/ConvexHullMesh.html}", note=[Accessed: 15-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_convexhullmesh, organization={Wolfram Research}, title={ConvexHullMesh}, year={2020}, url={https://reference.wolfram.com/language/ref/ConvexHullMesh.html}, note=[Accessed: 15-September-2026]}