WOLFRAM

Wolfram 语言与系统参考资料中心

CorrelationTest[{{x1,y1},{x2,y2},…}]

检验一个二元总体的相关系数是否为零.

CorrelationTest[{{x1,y1},{x2,y2},…},ρ0]

检验相关系数是否为 ρ0.

CorrelationTest[{{x1,y1},{x2,y2},…},{{u1,v1},{u2,v2},…}]

检验两个总体的相关系数是否相等.

CorrelationTest[…,"property"]

返回 "property" 的值.

更多信息和选项
Details and Options Details and Options
范例  
基本范例  
范围  
检验  
报告  
选项  
AlternativeHypothesis  
SignificanceLevel  
VerifyTestAssumptions  
属性和关系  
可能存在的问题  
参见
相关指南
历史
按以下格式引用：

CorrelationTest

CorrelationTest[{{x1,y1},{x2,y2},…}]

检验一个二元总体的相关系数是否为零.

CorrelationTest[{{x1,y1},{x2,y2},…},ρ0]

检验相关系数是否为 ρ0.

CorrelationTest[{{x1,y1},{x2,y2},…},{{u1,v1},{u2,v2},…}]

检验两个总体的相关系数是否相等.

CorrelationTest[…,"property"]

返回 "property" 的值.

更多信息和选项

  • CorrelationTest 检验零假设 与备择假设 ：
  • {{{x1,y1},{x2,y2},…},{{u1,v1},{u2,v2},…}}
  • 其中 rho_(x,y) 是 {{x1,y1},{x2,y2},…} 的总体相关系数.
  • 默认情况下，返回概率值或 -值.
  • 小的 -值表示 不可能为真.
  • 数据 {{x1,y1},…} 和 {{u1,v1},…} 可以为任意的实值二元矩阵.
  • 参数 ρ0 可以是任意满足 的实数.
  • CorrelationTest[{{x1,y1},{x2,y2},…},ρ0] 将选择适用于数据的最有功效的检验.
  • CorrelationTest[…,All] 将选择适用于数据的所有检验.
  • CorrelationTest[…,"test"] 根据 "test" 报告 -值.
  • 可以使用以下检验：
  • "PearsonCorrelation"根据皮尔逊积矩
    "SpearmanRank"根据斯皮尔曼
  • "PearsonCorrelation" 检验假定数据来自正态分布.
  • CorrelationTest[…,"HypothesisTestData"] 返回一个 HypothesisTestData 对象 htd，该对象可利用形式 htd["property"] 提取额外的检验结果和属性.
  • CorrelationTest[…,"property"] 可用于直接给出 "property" 的值.
  • 与检验结果报告相关的属性包括：
  • "AllTests"列出所有适用的检验列表
    "AutomaticTest"如果使用 Automatic 所选择的检验
    "PValue"-值列表
    "PValueTable"-值的格式化表格
    "ShortTestConclusion"检验结论的简短说明
    "TestConclusion"检验结论的说明
    "TestData"检验统计量和 -值对的列表
    "TestDataTable"-值和检验统计量的格式化表格
    "TestStatistic"检验统计量的列表
    "TestStatisticTable"检验统计量的格式化表格
  • 可以使用下列选项：
  • AlternativeHypothesis "Unequal"备择假设的不等性
    SignificanceLevel 0.05诊断和报告的截止值
    VerifyTestAssumptions Automatic需要验证的假设
  • 对于相关性检验，选择的截止值 使得 仅当 时被拒绝. 用于 "TestConclusion" 和 "ShortTestConclusion" 属性的 值由 SignificanceLevel 选项控制. 值 也用于正态性诊断检验. 默认时 的值为 0.05.
  • CorrelationTest 中用于 VerifyTestAssumptions 的命名设置包括：
  • "Normality"验证所有数据为正态分布

范例

打开所有单元 关闭所有单元

基本范例  (3)

检验总体相关系数是否为零：

Wolfram Language code: m = RandomVariate[BinormalDistribution[.05], 1000];
Wolfram Language code: ListPlot[m]
Wolfram Language code: CorrelationTest[m]

检验总体相关系数是否为 0.25：

Wolfram Language code: m = RandomVariate[BinormalDistribution[.05], 1000];
Wolfram Language code: CorrelationTest[m, .25]

比较两个相关系数：

Wolfram Language code: m1 = RandomVariate[BinormalDistribution[.5], 1000]; m2 = RandomVariate[BinormalDistribution[-.5], 850];
Wolfram Language code: ListPlot[{m1, m2}]
Wolfram Language code: CorrelationTest[m1, m2]

给出检验统计量和 -值的报告表：

Wolfram Language code: CorrelationTest[m1, m2, {"TestDataTable", All}]

范围  (13)

检验  (9)

检验总体相关系数是否为零：

Wolfram Language code: m1 = RandomVariate[BinormalDistribution[0], 1000]; m2 = RandomVariate[BinormalDistribution[-.8], 1000];

当真实的相关性接近于零时，-值通常较大：

Wolfram Language code: Correlation[BinormalDistribution[0]][[1, 2]]
Wolfram Language code: CorrelationTest[m1]

当真实的相关性不是零时，-值通常较小：

Wolfram Language code: Correlation[BinormalDistribution[-.8]][[1, 2]]
Wolfram Language code: CorrelationTest[m2]

检验总体相关系数是否为0.5：

Wolfram Language code: m1 = RandomVariate[BinormalDistribution[.5], 1000]; m2 = RandomVariate[BinormalDistribution[0], 1000];

当真实的相关性接近于假设值时，-值通常较大：

Wolfram Language code: Correlation[BinormalDistribution[.5]][[1, 2]]
Wolfram Language code: CorrelationTest[m1, .5]

当真实的相关性与假设值差别较大时，-值通常较小：

Wolfram Language code: Correlation[BinormalDistribution[-0]][[1, 2]]
Wolfram Language code: CorrelationTest[m2, .5]

比较两个样本的相关系数：

Wolfram Language code: m1 = RandomVariate[BinormalDistribution[-.5], 1000]; m2 = RandomVariate[BinormalDistribution[0], 185]; m3 = RandomVariate[BinormalDistribution[-.5], 200];

当相关性相似时，-值通常较大：

Wolfram Language code: CorrelationTest[m1, m3, "TestStatistic"]

当相关性不相似时，-值通常较小：

Wolfram Language code: CorrelationTest[m1, m2]

使用 Automatic 应用最有功效的适当检验：

Wolfram Language code: m = RandomVariate[BinormalDistribution[0], 100];
Wolfram Language code: CorrelationTest[m, 0, Automatic]

属性 "AutomaticTest" 可用于确定所选择的检验：

Wolfram Language code: CorrelationTest[m, 0, "AutomaticTest"]

执行一个特定的检验：

Wolfram Language code: m = RandomVariate[BinormalDistribution[0], 100];
Wolfram Language code: CorrelationTest[m, 0, "PearsonCorrelation"]

可以同时进行任意数目的检验：

Wolfram Language code: CorrelationTest[m, 0, {"PearsonCorrelation", "SpearmanRank"}]

同时执行适用于数据的所有测试：

Wolfram Language code: m = RandomVariate[BinormalDistribution[0], 100];
Wolfram Language code: CorrelationTest[m, 0, All]

使用属性 "AllTests" 识别所用的检验：

Wolfram Language code: CorrelationTest[m, 0, "AllTests"]

为重复的属性提取创建一个 HypothesisTestData 对象：

Wolfram Language code: m = RandomVariate[BinormalDistribution[0], 100];
Wolfram Language code: ℋ = CorrelationTest[m, 0, "HypothesisTestData"];

可用于提取的属性：

Wolfram Language code: ℋ["Properties"]

从 HypothesisTestData 对象中提取一些属性：

Wolfram Language code: m = RandomVariate[BinormalDistribution[0], 100];
Wolfram Language code: ℋ = CorrelationTest[m, 0, "HypothesisTestData"]

来自 "PearsonCorrelation" 检验的 -值和检验统计量：

Wolfram Language code: ℋ["PValue", "PearsonCorrelation"]
Wolfram Language code: ℋ["TestStatistic", "PearsonCorrelation"]

同时提取任意数目的属性：

Wolfram Language code: m = RandomVariate[BinormalDistribution[0], 100];
Wolfram Language code: ℋ = CorrelationTest[m, 0, "HypothesisTestData"];

来自 "SpearmanRank" 检验的 -值和检验统计量：

Wolfram Language code: ℋ[{"PValue", "SpearmanRank"}, {"TestStatistic", "SpearmanRank"}]

报告  (4)

对选取的一组检验的结果制表：

Wolfram Language code: m = RandomVariate[BinormalDistribution[0], 100];
Wolfram Language code: ℋ = CorrelationTest[m, 0, "HypothesisTestData"];

所有适当检验结果的完全表格：

Wolfram Language code: ℋ["TestDataTable", All]

取回检验表中的条目得到自定义报告：

Wolfram Language code: m = RandomVariate[BinormalDistribution[0], 100];
Wolfram Language code: ℋ = CorrelationTest[m, 0, "HypothesisTestData"];
Wolfram Language code: res = ℋ["TestData", All];
Wolfram Language code: tests = ℋ["AllTests"]

-值高于0.05，因此在该水平下拒绝 的证据不足：

Wolfram Language code: Show[BarChart[res[[All, 2]], ChartLabels -> Placed[tests, Center], BarOrigin -> Left], Graphics[{Dashed, InfiniteLine[{{.05, 0}, {.05, 1}}]}]]

对一个或一组检验的 -值制表：

Wolfram Language code: m = RandomVariate[BinormalDistribution[0], 100];
Wolfram Language code: ℋ = CorrelationTest[m, 0, "HypothesisTestData"];
Wolfram Language code: ℋ["PValueTable"]

表格中的 -值：

Wolfram Language code: ℋ["PValue"]

所用适当检验的 -值表：

Wolfram Language code: ℋ["PValueTable", All]

对一个或一组检验的检验统计量制表：

Wolfram Language code: m = RandomVariate[BinormalDistribution[0], 100];
Wolfram Language code: ℋ = CorrelationTest[m, 0, "HypothesisTestData"];
Wolfram Language code: ℋ["TestStatisticTable"]

来自表格的检验统计量：

Wolfram Language code: ℋ["TestStatistic"]

所有适当检验的检验统计量表格：

Wolfram Language code: ℋ["TestStatisticTable", All]

选项  (8)

AlternativeHypothesis  (2)

在默认情况下进行双边检验：

Wolfram Language code: m = RandomVariate[CopulaDistribution[{"Clayton", 1}, {NormalDistribution[], NormalDistribution[]}], 100];
Wolfram Language code: CorrelationTest[m, AlternativeHypothesis -> "Unequal"]
Wolfram Language code: CorrelationTest[m, AlternativeHypothesis -> Automatic]

进行双边检验或单边检验：

Wolfram Language code: m = RandomVariate[CopulaDistribution[{"Clayton", 3}, {NormalDistribution[], NormalDistribution[]}], 100];

双边检验：

Wolfram Language code: CorrelationTest[m, AlternativeHypothesis -> "Unequal"]

两个单边检验作为替代方法：

Wolfram Language code: CorrelationTest[m, AlternativeHypothesis -> "Less"]
Wolfram Language code: CorrelationTest[m, AlternativeHypothesis -> "Greater"]

SignificanceLevel  (3)

设置诊断检验的显著性水平：

Wolfram Language code: m = BlockRandom[SeedRandom[2];RandomVariate[CopulaDistribution[{"Clayton", 1}, {NormalDistribution[], NormalDistribution[]}], 100]];
Wolfram Language code: CorrelationTest[m, 0, "PearsonCorrelation", SignificanceLevel -> .0001]

默认时使用0.05. 消息显示0.025，这是因为进行了两个检验：

Wolfram Language code: CorrelationTest[m, 0, "PearsonCorrelation"]

显著性水平的设置可能会改变自动选择的检验：

Wolfram Language code: m = BlockRandom[SeedRandom[2];RandomVariate[CopulaDistribution[{"Clayton", 1}, {NormalDistribution[], NormalDistribution[]}], 100]];
Wolfram Language code: CorrelationTest[m, 0, "AutomaticTest", SignificanceLevel -> .0001]

默认情况下会选择非参数检验：

Wolfram Language code: CorrelationTest[m, 0, "AutomaticTest", SignificanceLevel -> .1]

该显著性水平也用于 "TestConclusion" 和 "ShortTestConclusion"：

Wolfram Language code: m = BlockRandom[SeedRandom[2];RandomVariate[CopulaDistribution[{"Clayton", 2}, {NormalDistribution[], NormalDistribution[]}], 100]];
Wolfram Language code: ℋ1 = CorrelationTest[m, 0, "HypothesisTestData", SignificanceLevel -> .05];
Wolfram Language code: ℋ2 = CorrelationTest[m, 0, "HypothesisTestData", SignificanceLevel -> .000005];
Wolfram Language code: ℋ1["TestConclusion"]//TraditionalForm
Wolfram Language code: ℋ2["TestConclusion"]//TraditionalForm
Wolfram Language code: ℋ1["ShortTestConclusion"]
Wolfram Language code: ℋ2["ShortTestConclusion"]

VerifyTestAssumptions  (3)

默认情况下，在适当的时候测试正态性：

Wolfram Language code: m = BlockRandom[SeedRandom[2];RandomVariate[CopulaDistribution[{"Clayton", 1}, {NormalDistribution[], NormalDistribution[]}], 100]];
Wolfram Language code: CorrelationTest[m, 0, "PearsonCorrelation", VerifyTestAssumptions -> Automatic]

诊断程序可以利用 All 或 None 作为一个组进行控制：

Wolfram Language code: m = BlockRandom[SeedRandom[2];RandomVariate[CopulaDistribution[{"Clayton", 1}, {NormalDistribution[], NormalDistribution[]}], 100]];

验证所有假设：

Wolfram Language code: CorrelationTest[m, 0, "PearsonCorrelation", VerifyTestAssumptions -> All]

不检查假设：

Wolfram Language code: CorrelationTest[m, 0, "PearsonCorrelation", VerifyTestAssumptions -> None]

可以独立地控制诊断程序：

Wolfram Language code: m = BlockRandom[SeedRandom[2];RandomVariate[CopulaDistribution[{"Clayton", 1}, {NormalDistribution[], NormalDistribution[]}], 100]];

检查正态性：

Wolfram Language code: CorrelationTest[m, 0, "PearsonCorrelation", VerifyTestAssumptions -> "Normality"]

显式设置诊断结果：

Wolfram Language code: CorrelationTest[m, 0, "PearsonCorrelation", VerifyTestAssumptions -> {"Normality" -> True}]
Wolfram Language code: CorrelationTest[m, 0, "PearsonCorrelation", VerifyTestAssumptions -> {"Normality" -> False}]

属性和关系  (5)

使用样本相关性 r 的费舍尔 转换计算 -值：

Wolfram Language code: fisherZTransform[r_, ρ0_, n_] := (ArcTanh[r] - ArcTanh[ρ0] - (ρ0/2 (n - 1))) Sqrt[n - 3]
Wolfram Language code: m = BlockRandom[SeedRandom[10];RandomVariate[BinormalDistribution[.5], 100]];

时的费舍尔 转换：

Wolfram Language code: z1 = fisherZTransform[Correlation[Sequence@@(m)], 0.25, 100]
Wolfram Language code: Probability[Abs[x] > Abs[z1], xNormalDistribution[]]
Wolfram Language code: CorrelationTest[m, .25, "PearsonCorrelation"]

相同的转换用于 "SpearmanRank"：

Wolfram Language code: m2 = BlockRandom[SeedRandom[10];RandomVariate[CauchyDistribution[0, 1], {100, 2}]];
Wolfram Language code: z2 = fisherZTransform[SpearmanRho[Sequence@@(m2)], 0.25, 100]
Wolfram Language code: Probability[Abs[x] > Abs[z2], xNormalDistribution[]]
Wolfram Language code: CorrelationTest[m2, .25, "SpearmanRank"]

类似的转变在比较相关性时用到：

Wolfram Language code: fisherZTransform[r1_, r2_, n1_, n2_] := (ArcTanh[r1] - ArcTanh[r2]) / Sqrt[(1/n1 - 3) + (1/n2 - 3)]
Wolfram Language code: m1 = BlockRandom[SeedRandom[1];RandomVariate[BinormalDistribution[.5], 100]];
Wolfram Language code: m2 = BlockRandom[SeedRandom[1];RandomVariate[BinormalDistribution[-.5], 35]];

统计量是等价的：

Wolfram Language code: z = fisherZTransform[Correlation[Sequence@@(m1)], Correlation[Sequence@@(m2)], 100, 35]
Wolfram Language code: Probability[Abs[x] > Abs[z], xNormalDistribution[]]
Wolfram Language code: CorrelationTest[m1, m2]

在 下，转换后的统计量有一个渐近标准正态分布：

Wolfram Language code: data = BlockRandom[SeedRandom[2];RandomVariate[BinormalDistribution[0], {1000, 50}]];
Wolfram Language code: fisherZTransform[r_, ρ0_, n_] := (ArcTanh[r] - ArcTanh[ρ0] - (ρ0/2 (n - 1))) Sqrt[n - 3]
Wolfram Language code: t = CorrelationTest[#, 0, "TestStatistic", VerifyTestAssumptions -> None]& /@ data;
Wolfram Language code: z = fisherZTransform[#, 0, 50]& /@ t;
Wolfram Language code: QuantilePlot[z]
Wolfram Language code: DistributionFitTest[z, NormalDistribution[0, 1]]

使用 IndependenceTest 来测试向量和矩阵之间的独立性：

Wolfram Language code: m = BlockRandom[SeedRandom[1];RandomVariate[BinormalDistribution[.5], 100]];
Wolfram Language code: IndependenceTest[Sequence@@(m), "TestDataTable"]

当输入为 TimeSeries 时，相关性检验适用于时间标记和值：

Wolfram Language code: ts = TemporalData[TimeSeries, {{{1.0081913025727498, 1.4304731751840027, -0.4125117157733782, -1.1413187519244148, -0.2664060220778645, -1.0365522431905356, 0.203588890642496, -0.12998044410791582, -0.5041339333806572, 0.6882189863641266, -0.0 ... 714166717388, 0.49655299069078945, 1.7174825766625412, 0.45095266624527885, 0.14798747430790704, 2.1461822155040498}}, {{0, 100, 1}}, 1, {"Continuous", 1}, {"Discrete", 1}, 1, {ValueDimensions -> 1, ResamplingMethod -> None}}, False, 10.1];
Wolfram Language code: ts["ValueDimensions"]
Wolfram Language code: CorrelationTest[ts]

这相当于：

Wolfram Language code: CorrelationTest[Transpose@{ts["Times"], ts["Values"]}]

可能存在的问题  (3)

CorrelationTest 不应该被用来测试因果关系：

Wolfram Language code: BlockRandom[ SeedRandom[1]; d1 = RandomVariate[NormalDistribution[], 100]; d2 = RandomVariate[NormalDistribution[], 100]; ]

由排序导致的高次相关性：

Wolfram Language code: CorrelationTest[Transpose[{Sort@d1, Sort@d2}], 0, "TestDataTable"]

因果关系并不一定意味着较高的相关性：

Wolfram Language code: d3 = d1 ^ 2;
Wolfram Language code: CorrelationTest[Transpose[{d1, d3}], 0, "TestDataTable"]

相关性检验不能识别多变量 TimeSeries：

Wolfram Language code: ts = TemporalData[TimeSeries, {{{{1.0081913025727498, 0.08141087155028082}, {1.4304731751840027, -0.056482126116319795}, {-0.4125117157733782, -2.64990770657697}, {-1.1413187519244148, 1.582933898719192}, {-0.2664060220778645, -0.9013658525565 ... 27885, -0.9820487653060537}, {0.14798747430790704, 0.8363549184013521}, {2.1461822155040498, 0.9726049961243627}}}, {{0, 100, 1}}, 1, {"Continuous", 1}, {"Discrete", 1}, 2, {ValueDimensions -> 2, ResamplingMethod -> None}}, False, 10.1];
Wolfram Language code: CorrelationTest[ts]

检验单独分量：

Wolfram Language code: CorrelationTest /@ ts["PathComponents"]

仅检验值：

Wolfram Language code: CorrelationTest /@ ts["ValueList"]

相关性检验不能线性作用于 TemporalData 的路径：

Wolfram Language code: td = TemporalData[Automatic, {{{{-0.5434667050992523, 0.46314064380741066}, {-1.6588644425631323, 0.47154247202353816}, {-2.34646934599704, 0.5039135236314848}, {0.5176089743195925, 0.5329787913867369}, {0.23294476670437064, -0.195915630443586 ... 275967729, 1.9512017274876106}, {-0.789601844933439, 0.3327695314775849}, {-1.4271973425082942, 1.3188336921085977}}}, {{0, 100, 1}}, 4, {"Continuous", 4}, {"Discrete", 1}, 2, {ValueDimensions -> 2, ResamplingMethod -> None}}, False, 10.1];
Wolfram Language code: CorrelationTest[td]

按路径检验每个分量与时间的关系：

Wolfram Language code: CorrelationTest[td["PathComponent", 1]]
Wolfram Language code: CorrelationTest[td["PathComponent", 2]]
Wolfram Research (2012)，CorrelationTest，Wolfram 语言函数，https://reference.wolfram.com/language/ref/CorrelationTest.html.

文本

Wolfram Research (2012)，CorrelationTest，Wolfram 语言函数，https://reference.wolfram.com/language/ref/CorrelationTest.html.

CMS

Wolfram 语言. 2012. "CorrelationTest." Wolfram 语言与系统参考资料中心. Wolfram Research. https://reference.wolfram.com/language/ref/CorrelationTest.html.

APA

Wolfram 语言. (2012). CorrelationTest. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/CorrelationTest.html 年

BibTeX

@misc{reference.wolfram_2026_correlationtest, author="Wolfram Research", title="{CorrelationTest}", year="2012", howpublished="\url{https://reference.wolfram.com/language/ref/CorrelationTest.html}", note=[Accessed: 16-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_correlationtest, organization={Wolfram Research}, title={CorrelationTest}, year={2012}, url={https://reference.wolfram.com/language/ref/CorrelationTest.html}, note=[Accessed: 16-September-2026]}