WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

CoxIngersollRossProcess[μ,σ,θ,x0]

長期平均μ，ボラティリティ σ，調整速度θ，初期条件 x0のCox–Ingersoll–Ross過程を表す．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
基本的な用法  
過程スライス特性  
特性と関係  
おもしろい例題  
関連項目
関連するガイド
履歴
引用書式

CoxIngersollRossProcess

CoxIngersollRossProcess[μ,σ,θ,x0]

長期平均μ，ボラティリティ σ，調整速度θ，初期条件 x0のCox–Ingersoll–Ross過程を表す．

詳細

例題

すべて開く すべて閉じる

例  (3)

Cox–Ingersoll–Ross過程のシミュレーションを行う：

Wolfram Language code: data = RandomFunction[CoxIngersollRossProcess[.3, .5, 1, 2], {0, 1, 0.01}]
Wolfram Language code: ListLinePlot[data, Filling -> Axis]

平均値関数と分散関数：

Wolfram Language code: Mean[CoxIngersollRossProcess[μ, σ, θ, Subscript[x, 0]][t]]
Wolfram Language code: Variance[CoxIngersollRossProcess[μ, σ, θ, Subscript[x, 0]][t]]

共分散関数：

Wolfram Language code: CovarianceFunction[CoxIngersollRossProcess[μ, σ, θ, Subscript[x, 0]], s, t]
Wolfram Language code: Plot3D[CovarianceFunction[CoxIngersollRossProcess[.3, .5, 1, 2], s, t], {s, 0, 5}, {t, 0, 5}, ColorFunction -> "Rainbow"]

スコープ  (14)

基本的な用法  (9)

Cox–Ingersoll–Ross過程のランダムな経路の集合のシミュレーションを行う：

Wolfram Language code: data = RandomFunction[CoxIngersollRossProcess[.3, .5, 1, 2], {0, 1, 0.01}, 3]
Wolfram Language code: ListLinePlot[data, Filling -> Axis]

任意の精度でシミュレーションを行う：

Wolfram Language code: RandomFunction[CoxIngersollRossProcess[1 / 10, 1 / 3, 1, 2], {0, 1, 1 / 4}, WorkingPrecision -> 20]["Path"]

さまざまなドリフト母数の値について経路を比較する：

Wolfram Language code: sample[μ_] := (SeedRandom[14];RandomFunction[CoxIngersollRossProcess[μ, .3, .4, 1], {0, 1, .01}])
Wolfram Language code: ListStepPlot[sample[#], Filling -> Axis, PlotLabel -> StringJoin["μ = ", ToString[#]]]& /@ {.3, 1, 2}

さまざまなボラティリティ母数の値について経路を比較する：

Wolfram Language code: sample[σ_] := (SeedRandom[1];RandomFunction[CoxIngersollRossProcess[.5, σ, .4, 1], {0, 1, .01}])
Wolfram Language code: ListStepPlot[sample[#], Filling -> Axis, PlotLabel -> StringJoin["σ = ", ToString[#]]]& /@ {-1, 0.2, 1}

さまざまな速度調節母数の値について経路を比較する：

Wolfram Language code: sample[θ_] := (SeedRandom[1];RandomFunction[CoxIngersollRossProcess[.5, 1, θ, 1], {0, 1, .01}])
Wolfram Language code: ListStepPlot[sample[#], Filling -> Axis, PlotLabel -> StringJoin["θ = ", ToString[#]]]& /@ {0.2, 1, 4}

さまざまな始点について，Cox–Ingersoll–Ross過程のシミュレーションを行う：

Wolfram Language code: proc[x_] := CoxIngersollRossProcess[1, .4, .3, x];
Wolfram Language code: pts = {.5, 1, 3};
Wolfram Language code: SeedRandom[2]; ListLinePlot[RandomFunction[proc[#], {0, 10, .01}]& /@ pts, Filling -> Axis, PlotLegends -> (StringJoin["x = ", ToString[#]]& /@ pts)]

過程母数推定：

Wolfram Language code: data = RandomFunction[CoxIngersollRossProcess[.3, .5, 1, 2], {0, 100, 0.01}];
Wolfram Language code: EstimatedProcess[data, CoxIngersollRossProcess[μ, σ, θ, Subscript[x, 0]]]

相関関数：

Wolfram Language code: CorrelationFunction[CoxIngersollRossProcess[μ, σ, θ, Subscript[x, 0]], s, t]

絶対相関関数：

Wolfram Language code: AbsoluteCorrelationFunction[CoxIngersollRossProcess[μ, σ, θ, Subscript[x, 0]], s, t]

過程スライス特性  (5)

スライス分布の一次確率密度関数：

Wolfram Language code: proc = CoxIngersollRossProcess[.3, .5, 1, 2];
Wolfram Language code: times = {.5, 1, 2};
Wolfram Language code: Plot[Evaluate@Table[PDF[proc[t], x], {t, times}], {x, 0, 3}, Filling -> Axis, PlotLegends -> {StringJoin["t = ", ToString[#]]& /@ times}]
Wolfram Language code: PDF[CoxIngersollRossProcess[μ, σ, θ, Subscript[x, 0]][t], x]

多変量スライス分布：

Wolfram Language code: Plot3D[PDF[CoxIngersollRossProcess[-.9, 1.2, -2.1, 3][{1, 2}], {x, y}], {x, 0, 10}, {y, 0, 15}]
Wolfram Language code: PDF[CoxIngersollRossProcess[μ, σ, θ, Subscript[x, 0]][{1, 2}], {x, y}]

式の期待値を計算する：

Wolfram Language code: Expectation[x[t] ^ 2, xCoxIngersollRossProcess[μ, σ, θ, Subscript[x, 0]]]

事象の確率を計算する：

Wolfram Language code: Probability[x[t] < 6, xCoxIngersollRossProcess[μ, σ, θ, Subscript[x, 0]]]

歪度と尖度：

Wolfram Language code: Skewness[CoxIngersollRossProcess[μ, σ, θ, Subscript[x, 0]][t]]//Simplify[#, σ > 0]&
Wolfram Language code: Kurtosis[CoxIngersollRossProcess[μ, σ, θ, Subscript[x, 0]][t]]//Simplify

次数rのモーメント：

Wolfram Language code: Moment[CoxIngersollRossProcess[μ, σ, θ, Subscript[x, 0]][t], r]

母関数：

Wolfram Language code: CharacteristicFunction[CoxIngersollRossProcess[μ, σ, θ, Subscript[x, 0]][t], w]
Wolfram Language code: MomentGeneratingFunction[CoxIngersollRossProcess[μ, σ, θ, Subscript[x, 0]][t], w]

CentralMomentおよびその母関数：

Wolfram Language code: CentralMoment[CoxIngersollRossProcess[μ, σ, θ, Subscript[x, 0]][t], 2]
Wolfram Language code: CentralMomentGeneratingFunction[CoxIngersollRossProcess[μ, σ, θ, Subscript[x, 0]][t], w]

FactorialMomentおよびその母関数：

Wolfram Language code: FactorialMoment[CoxIngersollRossProcess[μ, σ, θ, Subscript[x, 0]][t], 2]
Wolfram Language code: FactorialMomentGeneratingFunction[CoxIngersollRossProcess[μ, σ, θ, Subscript[x, 0]][t], w]

Cumulantおよびその母関数：

Wolfram Language code: Cumulant[CoxIngersollRossProcess[μ, σ, θ, Subscript[x, 0]][t], r]
Wolfram Language code: CumulantGeneratingFunction[CoxIngersollRossProcess[μ, σ, θ, Subscript[x, 0]][t], w]

特性と関係  (3)

Cox–ingersoll–Ross過程は弱定常ではない：

Wolfram Language code: WeakStationarity[CoxIngersollRossProcess[μ, σ, θ, Subscript[x, 0]]]

条件付き累積分布関数：

Wolfram Language code: Table[Plot[NProbability[(x[5] <= Subscript[x, 2])(x[2] == Subscript[x, 1]), xCoxIngersollRossProcess[.3, 1, .3, 1.2]], {Subscript[x, 2], 0, 6}, Filling -> Axis, PlotLabel -> Row[{"SubscriptBox[x, 1] = ", Subscript[x, 1]}]], {Subscript[x, 1], {.3, 1, 2.3, 3}}]

Cox–ingersoll–Ross過程は特殊なItoProcessである：

Wolfram Language code: ItoProcess[CoxIngersollRossProcess[μ, σ, θ, Subscript[x, 0]]]

StratonovichProcessでもある：

Wolfram Language code: StratonovichProcess[CoxIngersollRossProcess[μ, σ, θ, Subscript[x, 0]]]

おもしろい例題  (3)

Cox–Ingersoll–Ross過程のシミュレーションを二次元で行う：

Wolfram Language code: SeedRandom[103];sample = RandomFunction[CoxIngersollRossProcess[.3, .5, 1, 2], {0, 1, .001}, 2]["ValueList"];
Wolfram Language code: ListLinePlot[Transpose@sample, ColorFunction -> "FallColors"]

Cox–Ingersoll–Ross過程のシミュレーションを三次元で行う：

Wolfram Language code: proc = CoxIngersollRossProcess[-.4, .5, -1.3, 2]; SeedRandom[123]; sample = Table[RandomFunction[proc, {0, 1, 0.01}, 3]["ValueList"], {6}];
Wolfram Language code: Graphics3D@Table[{ColorData["SolarColors"][RandomReal[]], Tube@Line@sample[[i]]}, {i, 6}]

Cox–Ingersoll–Ross過程から500経路のシミュレーションを行う：

Wolfram Language code: data = RandomFunction[CoxIngersollRossProcess[.4, .5, .3, 2], {0, 1, .01}, 500];

1におけるスライスを取り，その分布を可視化する：

Wolfram Language code: sd = data["SliceData", 1];
Wolfram Language code: cf = ColorData["Rainbow"]; sliced = BarChart[Last[#], Axes -> False, BarOrigin -> Left, AspectRatio -> 4, ChartStyle -> (cf /@ Rescale[MovingAverage[First[#], 2], {Min[sd], Max[sd]}, {0, 1}]), ImageSize -> 62]&[HistogramList[sd, {Range[Min[sd], Max[sd], (Max[sd] - Min[sd]) / 20]}]];

1におけるスライス分布の経路とヒストグラム分布をプロットする：

Wolfram Language code: ListLinePlot[data, ImageSize -> 400, PlotRange -> All, AspectRatio -> 3 / 4, Epilog -> Inset[sliced, {1.01, 2}, {0, 10}], PlotStyle -> (cf /@ Rescale[sd]), BaseStyle -> Directive[Thin, Opacity[0.5]], PlotRangePadding -> {{0, .25}, {.5, .5}}]
Wolfram Research (2012), CoxIngersollRossProcess, Wolfram言語関数， https://reference.wolfram.com/language/ref/CoxIngersollRossProcess.html.

テキスト

Wolfram Research (2012), CoxIngersollRossProcess, Wolfram言語関数， https://reference.wolfram.com/language/ref/CoxIngersollRossProcess.html.

CMS

Wolfram Language. 2012. "CoxIngersollRossProcess." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/CoxIngersollRossProcess.html.

APA

Wolfram Language. (2012). CoxIngersollRossProcess. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/CoxIngersollRossProcess.html

BibTeX

@misc{reference.wolfram_2026_coxingersollrossprocess, author="Wolfram Research", title="{CoxIngersollRossProcess}", year="2012", howpublished="\url{https://reference.wolfram.com/language/ref/CoxIngersollRossProcess.html}", note=[Accessed: 06-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_coxingersollrossprocess, organization={Wolfram Research}, title={CoxIngersollRossProcess}, year={2012}, url={https://reference.wolfram.com/language/ref/CoxIngersollRossProcess.html}, note=[Accessed: 06-September-2026]}