WOLFRAM

Wolfram 语言与系统参考资料中心

CoxIngersollRossProcess[μ,σ,θ,x0]

表示 Cox–Ingersoll–Ross过程，其中长期均值为μ，波动率为 σ，调整速度为 θ，初始条件为 x0.

更多信息
Details and Options Details and Options
范例  
基本范例  
范围  
基本用法  
过程切片性质  
属性和关系  
巧妙范例  
参见
相关指南
历史
按以下格式引用：

CoxIngersollRossProcess

CoxIngersollRossProcess[μ,σ,θ,x0]

表示 Cox–Ingersoll–Ross过程，其中长期均值为μ，波动率为 σ，调整速度为 θ，初始条件为 x0.

更多信息

范例

打开所有单元 关闭所有单元

基本范例  (3)

模拟一个 Cox–Ingersoll–Ross 过程：

Wolfram Language code: data = RandomFunction[CoxIngersollRossProcess[.3, .5, 1, 2], {0, 1, 0.01}]
Wolfram Language code: ListLinePlot[data, Filling -> Axis]

均值和方差函数：

Wolfram Language code: Mean[CoxIngersollRossProcess[μ, σ, θ, Subscript[x, 0]][t]]
Wolfram Language code: Variance[CoxIngersollRossProcess[μ, σ, θ, Subscript[x, 0]][t]]

协方差函数：

Wolfram Language code: CovarianceFunction[CoxIngersollRossProcess[μ, σ, θ, Subscript[x, 0]], s, t]
Wolfram Language code: Plot3D[CovarianceFunction[CoxIngersollRossProcess[.3, .5, 1, 2], s, t], {s, 0, 5}, {t, 0, 5}, ColorFunction -> "Rainbow"]

范围  (14)

基本用法  (9)

模拟 Cox–Ingersoll–Ross 过程的随机路径集合：

Wolfram Language code: data = RandomFunction[CoxIngersollRossProcess[.3, .5, 1, 2], {0, 1, 0.01}, 3]
Wolfram Language code: ListLinePlot[data, Filling -> Axis]

以任意精度模拟：

Wolfram Language code: RandomFunction[CoxIngersollRossProcess[1 / 10, 1 / 3, 1, 2], {0, 1, 1 / 4}, WorkingPrecision -> 20]["Path"]

比较漂移参数取不同值时的路径：

Wolfram Language code: sample[μ_] := (SeedRandom[14];RandomFunction[CoxIngersollRossProcess[μ, .3, .4, 1], {0, 1, .01}])
Wolfram Language code: ListStepPlot[sample[#], Filling -> Axis, PlotLabel -> StringJoin["μ = ", ToString[#]]]& /@ {.3, 1, 2}

比较波动性参数取不同值时的路径：

Wolfram Language code: sample[σ_] := (SeedRandom[1];RandomFunction[CoxIngersollRossProcess[.5, σ, .4, 1], {0, 1, .01}])
Wolfram Language code: ListStepPlot[sample[#], Filling -> Axis, PlotLabel -> StringJoin["σ = ", ToString[#]]]& /@ {-1, 0.2, 1}

比较速度调整参数取不同值时的路径：

Wolfram Language code: sample[θ_] := (SeedRandom[1];RandomFunction[CoxIngersollRossProcess[.5, 1, θ, 1], {0, 1, .01}])
Wolfram Language code: ListStepPlot[sample[#], Filling -> Axis, PlotLabel -> StringJoin["θ = ", ToString[#]]]& /@ {0.2, 1, 4}

模拟不同起始点的 Cox–Ingersoll–Ross 过程：

Wolfram Language code: proc[x_] := CoxIngersollRossProcess[1, .4, .3, x];
Wolfram Language code: pts = {.5, 1, 3};
Wolfram Language code: SeedRandom[2]; ListLinePlot[RandomFunction[proc[#], {0, 10, .01}]& /@ pts, Filling -> Axis, PlotLegends -> (StringJoin["x = ", ToString[#]]& /@ pts)]

过程参数估计：

Wolfram Language code: data = RandomFunction[CoxIngersollRossProcess[.3, .5, 1, 2], {0, 100, 0.01}];
Wolfram Language code: EstimatedProcess[data, CoxIngersollRossProcess[μ, σ, θ, Subscript[x, 0]]]

相关函数：

Wolfram Language code: CorrelationFunction[CoxIngersollRossProcess[μ, σ, θ, Subscript[x, 0]], s, t]

绝对相关函数：

Wolfram Language code: AbsoluteCorrelationFunction[CoxIngersollRossProcess[μ, σ, θ, Subscript[x, 0]], s, t]

过程切片性质  (5)

切片分布的一阶概率密度函数：

Wolfram Language code: proc = CoxIngersollRossProcess[.3, .5, 1, 2];
Wolfram Language code: times = {.5, 1, 2};
Wolfram Language code: Plot[Evaluate@Table[PDF[proc[t], x], {t, times}], {x, 0, 3}, Filling -> Axis, PlotLegends -> {StringJoin["t = ", ToString[#]]& /@ times}]
Wolfram Language code: PDF[CoxIngersollRossProcess[μ, σ, θ, Subscript[x, 0]][t], x]

多变量切片分布：

Wolfram Language code: Plot3D[PDF[CoxIngersollRossProcess[-.9, 1.2, -2.1, 3][{1, 2}], {x, y}], {x, 0, 10}, {y, 0, 15}]
Wolfram Language code: PDF[CoxIngersollRossProcess[μ, σ, θ, Subscript[x, 0]][{1, 2}], {x, y}]

计算表达式的期望：

Wolfram Language code: Expectation[x[t] ^ 2, xCoxIngersollRossProcess[μ, σ, θ, Subscript[x, 0]]]

计算事件概率：

Wolfram Language code: Probability[x[t] < 6, xCoxIngersollRossProcess[μ, σ, θ, Subscript[x, 0]]]

偏度和峰度：

Wolfram Language code: Skewness[CoxIngersollRossProcess[μ, σ, θ, Subscript[x, 0]][t]]//Simplify[#, σ > 0]&
Wolfram Language code: Kurtosis[CoxIngersollRossProcess[μ, σ, θ, Subscript[x, 0]][t]]//Simplify

阶数 r 的矩：

Wolfram Language code: Moment[CoxIngersollRossProcess[μ, σ, θ, Subscript[x, 0]][t], r]

母函数：

Wolfram Language code: CharacteristicFunction[CoxIngersollRossProcess[μ, σ, θ, Subscript[x, 0]][t], w]
Wolfram Language code: MomentGeneratingFunction[CoxIngersollRossProcess[μ, σ, θ, Subscript[x, 0]][t], w]

CentralMoment 及其母函数：

Wolfram Language code: CentralMoment[CoxIngersollRossProcess[μ, σ, θ, Subscript[x, 0]][t], 2]
Wolfram Language code: CentralMomentGeneratingFunction[CoxIngersollRossProcess[μ, σ, θ, Subscript[x, 0]][t], w]

FactorialMoment 及其母函数：

Wolfram Language code: FactorialMoment[CoxIngersollRossProcess[μ, σ, θ, Subscript[x, 0]][t], 2]
Wolfram Language code: FactorialMomentGeneratingFunction[CoxIngersollRossProcess[μ, σ, θ, Subscript[x, 0]][t], w]

Cumulant 及其母函数：

Wolfram Language code: Cumulant[CoxIngersollRossProcess[μ, σ, θ, Subscript[x, 0]][t], r]
Wolfram Language code: CumulantGeneratingFunction[CoxIngersollRossProcess[μ, σ, θ, Subscript[x, 0]][t], w]

属性和关系  (3)

Cox–ingersoll–Ross 过程不是弱平稳的：

Wolfram Language code: WeakStationarity[CoxIngersollRossProcess[μ, σ, θ, Subscript[x, 0]]]

条件累积分布函数：

Wolfram Language code: Table[Plot[NProbability[(x[5] <= Subscript[x, 2])(x[2] == Subscript[x, 1]), xCoxIngersollRossProcess[.3, 1, .3, 1.2]], {Subscript[x, 2], 0, 6}, Filling -> Axis, PlotLabel -> Row[{"SubscriptBox[x, 1] = ", Subscript[x, 1]}]], {Subscript[x, 1], {.3, 1, 2.3, 3}}]

Cox–ingersoll–Ross 过程是一个特殊的 ItoProcess：

Wolfram Language code: ItoProcess[CoxIngersollRossProcess[μ, σ, θ, Subscript[x, 0]]]

StratonovichProcess 也是如此：

Wolfram Language code: StratonovichProcess[CoxIngersollRossProcess[μ, σ, θ, Subscript[x, 0]]]

巧妙范例  (3)

模拟二维 Cox–Ingersoll–Ross 过程：

Wolfram Language code: SeedRandom[103];sample = RandomFunction[CoxIngersollRossProcess[.3, .5, 1, 2], {0, 1, .001}, 2]["ValueList"];
Wolfram Language code: ListLinePlot[Transpose@sample, ColorFunction -> "FallColors"]

模拟三维 Cox–Ingersoll–Ross 过程：

Wolfram Language code: proc = CoxIngersollRossProcess[-.4, .5, -1.3, 2]; SeedRandom[123]; sample = Table[RandomFunction[proc, {0, 1, 0.01}, 3]["ValueList"], {6}];
Wolfram Language code: Graphics3D@Table[{ColorData["SolarColors"][RandomReal[]], Tube@Line@sample[[i]]}, {i, 6}]

模拟 Cox–Ingersoll–Ross 过程的500个路径：

Wolfram Language code: data = RandomFunction[CoxIngersollRossProcess[.4, .5, .3, 2], {0, 1, .01}, 500];

在1处取切片，并可视化其分布：

Wolfram Language code: sd = data["SliceData", 1];
Wolfram Language code: cf = ColorData["Rainbow"]; sliced = BarChart[Last[#], Axes -> False, BarOrigin -> Left, AspectRatio -> 4, ChartStyle -> (cf /@ Rescale[MovingAverage[First[#], 2], {Min[sd], Max[sd]}, {0, 1}]), ImageSize -> 62]&[HistogramList[sd, {Range[Min[sd], Max[sd], (Max[sd] - Min[sd]) / 20]}]];

绘制在1处切片分布的路径和直方图分布：

Wolfram Language code: ListLinePlot[data, ImageSize -> 400, PlotRange -> All, AspectRatio -> 3 / 4, Epilog -> Inset[sliced, {1.01, 2}, {0, 10}], PlotStyle -> (cf /@ Rescale[sd]), BaseStyle -> Directive[Thin, Opacity[0.5]], PlotRangePadding -> {{0, .25}, {.5, .5}}]
Wolfram Research (2012)，CoxIngersollRossProcess，Wolfram 语言函数，https://reference.wolfram.com/language/ref/CoxIngersollRossProcess.html.

文本

Wolfram Research (2012)，CoxIngersollRossProcess，Wolfram 语言函数，https://reference.wolfram.com/language/ref/CoxIngersollRossProcess.html.

CMS

Wolfram 语言. 2012. "CoxIngersollRossProcess." Wolfram 语言与系统参考资料中心. Wolfram Research. https://reference.wolfram.com/language/ref/CoxIngersollRossProcess.html.

APA

Wolfram 语言. (2012). CoxIngersollRossProcess. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/CoxIngersollRossProcess.html 年

BibTeX

@misc{reference.wolfram_2026_coxingersollrossprocess, author="Wolfram Research", title="{CoxIngersollRossProcess}", year="2012", howpublished="\url{https://reference.wolfram.com/language/ref/CoxIngersollRossProcess.html}", note=[Accessed: 12-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_coxingersollrossprocess, organization={Wolfram Research}, title={CoxIngersollRossProcess}, year={2012}, url={https://reference.wolfram.com/language/ref/CoxIngersollRossProcess.html}, note=[Accessed: 12-September-2026]}