WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

CoxModel[…]

CoxModelFitで得られる記号比例ハザードモデルを表す．

詳細とオプション
Details and Options Details and Options
例題  
例  
スコープ  
オプション  
ConfidenceLevel  
ConfidenceRange  
ConfidenceTransform  
関連項目
関連するガイド
履歴
引用書式

CoxModel

CoxModel[…]

CoxModelFitで得られる記号比例ハザードモデルを表す．

詳細とオプション

  • コックス(Cox)モデルの特性はCoxModel[…]["property"]で得られる．
  • CoxModel[…][{prop1,prop2,…}]は複数の特性を与える．
  • CoxModel[…][x0][t]は特定の点 t における共変量レベル x0についての最適フィット関数を与える．
  • NormalはCoxModelにおけるベースライン生存関数の式を与える．
  • CoxModel[…][prop,ann]は特性 prop に関連する注釈 ann を与える．
  • 指定タイプのフィットされたモデルで使用可能な特性が，そのモデルを生成するCoxModelFit等の関数ページにリストとして掲載されている．
  • CoxModelは，次のオプションを取る．
  • ConfidenceLevel パラメータと予測に使う信頼水準
    ConfidenceRange All同時信頼区間の範囲
    ConfidenceTransform "LogLog"使用する信頼変換

例題

すべて開く すべて閉じる

例  (1)

右側打切りデータからCoxModelを作成する：

Wolfram Language code: data = EventData[{1, 2, 3, 4}, {0, 0, 1, 0}];
Wolfram Language code: mod = CoxModelFit[data]

そのモデルから特性を抽出する：

Wolfram Language code: mod["EventTimes"]

3におけるベースライン生存関数を評価する：

Wolfram Language code: mod[3]

スコープ  (6)

CoxModelオブジェクトから特性を抽出する：

Wolfram Language code: mod = CoxModelFit[{1, 2, 3, 4}]

ベースライン生存関数の標準的な誤差：

Wolfram Language code: mod["StandardErrors"][]

複数の特性を抽出する：

Wolfram Language code: mod = CoxModelFit[{1, 2, 3, 4}]
Wolfram Language code: mod[{"MartingaleResiduals", "CoxSnellResiduals"}]

使用可能な特性のリストを入手する：

Wolfram Language code: mod = CoxModelFit[{1, 2, 3, 4}]
Wolfram Language code: mod["Properties"]

ある点でベースライン生存関数を評価する：

Wolfram Language code: mod = CoxModelFit[{1, 2, 3, 4}];
Wolfram Language code: mod[2]

いくつかの点にマップする：

Wolfram Language code: mod /@ {1, 2, 3, 4}

ベースライン生存関数の式を得るために，Normalを使用する：

Wolfram Language code: mod = CoxModelFit[{1, 2, 3, 4}];
Wolfram Language code: Normal[mod]

特性に注釈を付ける：

Wolfram Language code: mod = CoxModelFit[{1, 2, 3, 4}];
Wolfram Language code: Table[Row[{i, ": ", mod["BaselineList", i]}], {i, {"Description", "LongDescription"}}]//TableForm

オプション  (5)

ConfidenceLevel  (3)

信頼水準はフィットの後で変更できる：

Wolfram Language code: ξ = {{67, 1}, {11, 0}, {32, 0}, {50, 1}, {65, 1}, {44, 1}, {20, 1}, {26, 0}, {69, 1}, {50, 1}, {25, 1}, {18, 0}, {63, 1}, {41, 0}, {30, 0}, {32, 1}, {46, 1}, {35, 0}, {33, 0}, {22, 0}}; e = EventData[Automatic, {{8, 22, 6, 4, 12, 11, 2, 34, 25, 15, 8, 6, 34, 6, 32, 1, 15, 9, 9, 6}, {0, 0, 0, 0, 0, 0, 0, 1, 1, 0, 0, 0, 1, 1, 1, 0, 0, 1, 1, 0}, None}];
Wolfram Language code: model = CoxModelFit[{ξ, e}, {Subscript[x, 1], Subscript[x, 2]}, {Subscript[x, 1], Subscript[x, 2]}]

点ごとの信頼区間を伴うベースライン生存率のプロット：

Wolfram Language code: Table[Plot[Evaluate@{model["SF"][][t], model["PointwiseBands", "SF", ConfidenceLevel -> i][][t]}, {t, 0, 35}, PlotLabel -> i], {i, {.9, .95, .99}}]

パラメータの信頼区間について信頼水準を変える：

Wolfram Language code: ξ = {{67, 1}, {11, 0}, {32, 0}, {50, 1}, {65, 1}, {44, 1}, {20, 1}, {26, 0}, {69, 1}, {50, 1}, {25, 1}, {18, 0}, {63, 1}, {41, 0}, {30, 0}, {32, 1}, {46, 1}, {35, 0}, {33, 0}, {22, 0}}; e = EventData[Automatic, {{8, 22, 6, 4, 12, 11, 2, 34, 25, 15, 8, 6, 34, 6, 32, 1, 15, 9, 9, 6}, {0, 0, 0, 0, 0, 0, 0, 1, 1, 0, 0, 0, 1, 1, 1, 0, 0, 1, 1, 0}, None}];

デフォルトの信頼水準を使う：

Wolfram Language code: model = CoxModelFit[{ξ, e}, {Subscript[x, 1], Subscript[x, 2]}, {Subscript[x, 1], Subscript[x, 2]}];
Wolfram Language code: model["ParameterConfidenceIntervals"]

信頼水準はフィットの後で変えられる：

Wolfram Language code: Table[model["ParameterConfidenceIntervals", ConfidenceLevel -> i], {i, {.85, .9, .95}}]

要約表の信頼水準を指定する：

Wolfram Language code: ξ = {{67, 1}, {11, 0}, {32, 0}, {50, 1}, {65, 1}, {44, 1}, {20, 1}, {26, 0}, {69, 1}, {50, 1}, {25, 1}, {18, 0}, {63, 1}, {41, 0}, {30, 0}, {32, 1}, {46, 1}, {35, 0}, {33, 0}, {22, 0}};
Wolfram Language code: model = CoxModelFit[{ξ, EventData[Automatic, {{8, 22, 6, 4, 12, 11, 2, 34, 25, 15, 8, 6, 34, 6, 32, 1, 15, 9, 9, 6}, {0, 0, 0, 0, 0, 0, 0, 1, 1, 0, 0, 0, 1, 1, 1, 0, 0, 1, 1, 0}, None}]}, {Subscript[x, 1], Subscript[x, 2]}, {Subscript[x, 1], Subscript[x, 2]}]

累積ハザード関数を90%の信頼限界で要約する：

Wolfram Language code: model["EventTable", "CHF", ConfidenceLevel -> .90][{50, 1}]

ConfidenceRange  (1)

同時区間と帯の信頼範囲を設定する：

Wolfram Language code: model = CoxModelFit[EventData[Automatic, {{{2081, Infinity}, {1602, Infinity}, {1496, Infinity}, {1462, Infinity}, {1433, Infinity}, {1377, Infinity}, {1330, Infinity}, {996, Infinity}, {226, Infinity}, {1199, Infinity}, {1111, Infinity}, {530, Infinity}, {1182, Infinity}, {1167, Infinity}, 418, 383, 276, 104, 609, 172, 487, 662, 194, 230, 526, 122, 129, 74, 122, 86, 466, 192, 109, 55, 1, 107, 110, 332}, None, None}]]

帯は信頼範囲上でしか定義されない：

Wolfram Language code: Plot[Evaluate@{model["SF"][][x], model["EqualPrecisionBands", ConfidenceRange -> {172, 383}][][x]}, {x, 100, 500}, PlotRange -> {0, 1}]

デフォルトで，範囲はAllに設定される：

Wolfram Language code: Plot[Evaluate@{model["SF"][][x], model["EqualPrecisionBands", ConfidenceRange -> All][][x]}, {x, 0, 2081}, PlotRange -> {0, 1}]

範囲をFullに設定する：

Wolfram Language code: Plot[Evaluate@{model["SF"][][x], model["EqualPrecisionBands", ConfidenceRange -> Full][][x]}, {x, 0, 2081}, PlotRange -> {0, 1}]

ConfidenceTransform  (1)

信頼区間と信頼帯に変換を適用する：

Wolfram Language code: ξ = {1, 0, 0, 1, 1, 1, 1, 0, 0, 1, 1, 0, 0, 0, 0, 1, 1, 0, 0, 0};
Wolfram Language code: model = CoxModelFit[{ξ, EventData[Automatic, {{8, 22, 6, 4, 12, 11, 2, 34, 25, 15, 8, 6, 34, 6, 32, 1, 15, 9, 9, 6}, {0, 0, 0, 0, 0, 0, 0, 1, 1, 0, 0, 0, 1, 1, 1, 0, 0, 1, 1, 0}, None}]}, x, x]

使用可能な変換のコレクション：

Wolfram Language code: tr = {"Linear", "LogLog", "ArcSinSqrt", "Log", "Logit"};

時点15における生存関数の帯：

Wolfram Language code: Table[{i, model["PointwiseBands", "SF", ConfidenceTransform -> i][][15]}, {i, tr}]//Grid

帯を可視化する：

Wolfram Language code: Table[Plot[Evaluate@{model["SF"][][t], model["PointwiseBands", "SF", ConfidenceTransform -> i][][t]}, {t, 0, 35}, PlotLabel -> i], {i, tr}]

デフォルトで，"LogLog"の帯と区間が使われる：

Wolfram Language code: model["PointwiseBands", ConfidenceTransform -> "LogLog"][{0}][15]
Wolfram Language code: model["PointwiseBands"][{0}][15]
Wolfram Research (2012), CoxModel, Wolfram言語関数， https://reference.wolfram.com/language/ref/CoxModel.html.

テキスト

Wolfram Research (2012), CoxModel, Wolfram言語関数， https://reference.wolfram.com/language/ref/CoxModel.html.

CMS

Wolfram Language. 2012. "CoxModel." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/CoxModel.html.

APA

Wolfram Language. (2012). CoxModel. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/CoxModel.html

BibTeX

@misc{reference.wolfram_2026_coxmodel, author="Wolfram Research", title="{CoxModel}", year="2012", howpublished="\url{https://reference.wolfram.com/language/ref/CoxModel.html}", note=[Accessed: 08-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_coxmodel, organization={Wolfram Research}, title={CoxModel}, year={2012}, url={https://reference.wolfram.com/language/ref/CoxModel.html}, note=[Accessed: 08-September-2026]}